Geolocation

Paket	flash.sensors
Sınıf	public class Geolocation
Miras Alma	Geolocation EventDispatcher Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Geolocation sınıfı aygıtın konum alıcısına yanıt olarak olaylar gönderir.

Bir aygıt coğrafi konumu destekliyorsa, bu sınıfı aygıtın geçerli coğrafi konumunu almak için kullanabilirsiniz. Coğrafi konum aygıtta enlemsel ve boylamsal koordinatların formunda görüntülenir (WGS-84 standart biçimde). Aygıtın konumu değiştiğinde, değişikliklerle ilgili güncellemeler alabilirsiniz. Aygıt bu özelliği destekliyorsa, konumdaki son değişikliğin yükseklik, doğruluk, başlık, hız ve zaman damgasıyla ilgili bilgi alabilirsiniz.

AIR profili desteği: Bu özellik yalnızca mobil aygıtlarda desteklenir. Masaüstü işletim sistemlerinde veya AIR for TV aygıtlarında desteklenmez. Desteği çalışma zamanında Geolocation.isSupported özelliğini kullanarak test edebilirsiniz. Birden fazla profilde API desteği ile ilgili daha fazla bilgi için bkz. AIR Profil Desteği.

Not: iOS'ta Coğrafi Konumu etkinleştirmek için uygulama xml dosyasındaki infoAdditions öğesine bir anahtar-değer çifti eklediğinizden emin olun. infoAdditions öğesi hakkında daha fazla bilgi için bkz. iOS Ayarları.

Örnekleri görüntüle

Daha fazla bilgi

Cristophe Coenraets: Mulit-user Google Maps Collaboration (Çok Kullanıcılı Google Maps İşbirliği)

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		isSupported : Boolean [statik] [salt okunur] Aygıtta bir konum alıcısının mevcut olup (true) olmadığı (false).	Geolocation
		locationAlwaysUsePermission : Boolean Bu özellik, coğrafi konumun erişim izni türünü belirler.	Geolocation
		muted : Boolean [salt okunur] Kullanıcının coğrafi konum (true) erişimine izin verip vermediğini (false) belirtir.	Geolocation
		permissionStatus : String [statik] [salt okunur]	Geolocation

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		Geolocation() Yeni bir Geolocation örneği oluşturur.	Geolocation
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void EventDispatcher nesnesi olan bir olay dinleyici nesnesini, dinleyicinin bir olayın bildirimini alması için kaydeder.	EventDispatcher
		dispatchEvent(event:Event):Boolean Olay akışına bir olay gönderir.	EventDispatcher
		hasEventListener(type:String):Boolean EventDispatcher nesnesinin belirli bir olay türü için kayıtlı dinleyicisi olup olmadığını kontrol eder.	EventDispatcher
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void EventDispatcher nesnesinden bir dinleyiciyi kaldırır.	EventDispatcher
		requestPermission():void	Geolocation
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		setRequestedUpdateInterval(interval:Number):void Güncellemelere ilişkin zaman aralığını milisaniye cinsinden ayarlamak için kullanılır.	Geolocation
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object
		willTrigger(type:String):Boolean Bir olay dinleyicisinin bu EventDispatcher nesnesiyle mi, yoksa onun belirtilen olay türüne yönelik üst öğelerinden biriyle mi kayıtlı olduğunu kontrol eder.	EventDispatcher

Olaylar

Olaylarla ilgili daha fazla bilgi için tıklatın

Miras Alınan Olayları Gizle

Miras Alınan Olayları Göster

	Özet	Tanımlayan:
activate	[broadcast olayı] Flash Player veya AIR uygulaması işletim sistemi odağına gelip etkin olduğunda gönderilir.	EventDispatcher
deactivate	[broadcast olayı] Çalışan Flash Player veya AIR uygulaması sistem odağını kaybettiğinde ve etkin olmayan duruma geldiğinde gönderilir.	EventDispatcher
permissionStatus		Geolocation
status	Kullanıcı konum sensörünün erişimini değiştirdiğinde Geolocation nesnesi durum olayları gönderir.	Geolocation
update	Güncelleme olayı, konum alıcısının güncellemelerine yanıt olarak gönderilir.	Geolocation

Özellik Ayrıntısı

isSupported

özellik

isSupported:Boolean [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Aygıtta bir konum alıcısının mevcut olup (true) olmadığı (false).

Uygulama
public static function get isSupported():Boolean

locationAlwaysUsePermission

özellik

locationAlwaysUsePermission:Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 29

Bu özellik, coğrafi konumun erişim izni türünü belirler. İzin türü Her Zaman ve Kullanımda Olduğunda olabilir. Özellik false değerine ayarlanırsa Kullanımda Olduğunda iznini ister, aksi takdirde Her zaman kullan iznini ister. requestPermission() çağırmadan önce özelliği ayarlayın. Özelliğin varsayılan değeri false olur.

Uygulama
public function get locationAlwaysUsePermission():Boolean
public function set locationAlwaysUsePermission(value:Boolean):void

muted

özellik

muted:Boolean [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Kullanıcının coğrafi konum (true) erişimine izin verip vermediğini (false) belirtir.. Bu değer değiştiğinde, bir status olayı gönderilir.

Uygulama
public function get muted():Boolean

İlgili API Öğeleri

status

permissionStatus

özellik

permissionStatus:String [salt okunur]

Uygulama
public static function get permissionStatus():String

Yapıcı Ayrıntı

()

Yapıcı

public function Geolocation()

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Yeni bir Geolocation örneği oluşturur.

Yöntem Ayrıntısı

requestPermission

()

yöntem

public function requestPermission():void

setRequestedUpdateInterval

()

yöntem

public function setRequestedUpdateInterval(interval:Number):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Güncellemelere ilişkin zaman aralığını milisaniye cinsinden ayarlamak için kullanılır. Güncelleme aralığı yalnızca pil gücünü korumak için bir ipucu olarak kullanılır. Konum güncellemeleri arasındaki asıl süre bu değerden daha fazla veya daha az olabilir. Bu yöntem kullanılarak güncelleme aralığında yapılan herhangi bir değişiklik tüm kayıtlı update olay dinleyicilerini etkiler. Geolocation sınıfı setRequestedUpdateInterval() yöntemini kullanmadan kullanılabilir. Bu durumda, platform güncellemeleri kendi varsayılan aralığını temel alarak döndürür.

Not: Bir GPS birimine sahip olmayan ilk jenerasyon iPhone'lar, update olaylarını yalnızca zaman zaman dağıtır. Bu cihazlarda ilk olarak bir Geolocation nesnesi bir veya iki update olayı dağıtır. Daha sonra bilgi önemli ölçüde değiştiğinde, update olaylarını dağıtır.

Parametreler

interval:Number — istenen güncelleme aralığı. interval <= 0 ise, bu yönteme yapılan herhangi bir çağrı etkisizdir.

Atar

ArgumentError — Belirtilen aralık sıfırdan azdır.

Olay Ayrıntısı

permissionStatus

Olay

Olay Nesne Türü: flash.events.PermissionEvent

status

Olay

Olay Nesne Türü: flash.events.StatusEvent
özellik StatusEvent.type = flash.events.StatusEvent.STATUS

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Kullanıcı konum sensörünün erişimini değiştirdiğinde Geolocation nesnesi durum olayları gönderir. Örneğin, bir aygıt istemine yanıt olarak, kullanıcı uygulamanın konum verilerine erişmesini önlerse, Geolocation nesnesi bir status olayı gönderir. Durum, konum sensörünün kullanılamadığı bir durum olarak değiştiğinde, Geolocation örneğinin muted özelliği true olur.

status olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`code`	Nesne durumunun bir açıklaması.
`currentTarget`	Bu Event nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`düzey`	Mesajın kategorisi; örneğin, `"status"`, `"warning"` veya `"error"`.
`target`	Durumunu bildiren nesne.

İlgili API Öğeleri

muted

update

Olay

Olay Nesne Türü: flash.events.GeolocationEvent
özellik GeolocationEvent.type = flash.events.GeolocationEvent.UPDATE

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2, Flash Lite 4

Güncelleme olayı, konum alıcısının güncellemelerine yanıt olarak gönderilir. Olay aşağıdaki durumlarda gönderilir:

addEventListener() öğesi üzerinden yeni bir dinleyici işlevi eklendiğinde, bu olay konumun geçerli değerinin sağlanması için bir seferde tüm kayıtlı dinleyicilere gönderilir. Not: AIR, cihaz bilinen son bir konuma sahipse ilk olayı hemen gönderir; kodunuz ilk gönderilen olayın geçerli konuma sahip olmayabileceğinin farkında olmalıdır.
Konum güncellemeleri platformdan aygıt tarafından belirlenen aralıklarla her alındığında.
Uygulama, konumla ilgili bir değişikliği her kaçırdığında (örneğin, uygulama uyuduktan sonra uyanıyor)

BirGeolocationEvent olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Verileri alan Geolocation nesnesi.

Örnekler Bu örnek nasıl kullanılır?

GeolocationExample.as

Aşağıdaki örnekte uygulama, coğrafi konum update olayları alındıkça onların enlem, boylam ve yatay doğruluğunu görüntüler.

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.GeolocationEvent;
    import flash.events.MouseEvent;
    import flash.events.StatusEvent;
    import flash.sensors.Geolocation;
    import flash.text.TextField;
    import flash.text.TextFormat;
    
    public class GeolocationTest extends Sprite
    {
        
        private var geo:Geolocation; 
        private var log:TextField;
        
        public function GeolocationTest()
        {            
            super();
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            setUpTextField();
            
            if (Geolocation.isSupported) 
            { 
                geo = new Geolocation(); 
                if (!geo.muted) 
                { 
                    geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler); 
                } 
                geo.addEventListener(StatusEvent.STATUS, geoStatusHandler);
            } 
            else 
            { 
                log.text = "Geolocation not supported"; 
            } 
        }
        
        public function geoUpdateHandler(event:GeolocationEvent):void 
        { 
            log.text = "latitude : " + event.latitude.toString() + "\n"; 
            log.appendText("longitude : " + event.longitude.toString() + "\n");
        } 
        
        public function geoStatusHandler(event:StatusEvent):void 
        { 
            if (geo.muted)
                geo.removeEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
            else
                geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
        }
        
        private function setUpTextField():void
        {
            log = new TextField();
            var format:TextFormat = new TextFormat("_sans", 24);
            log.defaultTextFormat = format;
            log.border = true;
            log.wordWrap = true;
            log.multiline = true;
            log.x = 10;
            log.y = 10;
            log.height = stage.stageHeight - 20;
            log.width = stage.stageWidth - 20;
            log.addEventListener(MouseEvent.CLICK, clearLog);
            addChild(log);
        }
        private function clearLog(event:MouseEvent):void
        {
            log.text = "";
        }
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

Geolocation - AS3

Sınıflar x

isSupported

locationAlwaysUsePermission

muted

permissionStatus

Geolocation

requestPermission

setRequestedUpdateInterval

permissionStatus

status

update