XMLSocket  - AS3

Bu XMLSocket nesnesinin halen bağlı olup olmadığını gösterir. Ayrıca connect olayı ve ioError olayı için kaydolarak bağlantının başarılı olup olmadığını kontrol edebilirsiniz.

İlgili API Öğeleri

Bağlantı için beklenilecek milisaniye sayısını belirtir.

Belirtilen süre içinde bağlantı başarılı olmazsa, bağlantı gerçekleşmez. Varsayılan değer 20.000'dir (yirmi saniye).

Yeni bir XMLSocket nesnesi oluşturur. Hiçbir parametre belirtilmemişse, belirtilen bir ana bilgisayara veya bağlantı noktasına bir bağlantı yapılmaya çalışılır. Parametreler belirtilmişse, belirtilen ana bilgisayara ve bağlantı noktasına bir bağlantı yapılmaya çalışılır.

Not: Parametreler olmadan yapıcı formunu kullanmanız, daha sonra olay dinleyicilerini eklemeniz ve ardından host ve port parametreleriyle connect yöntemini çağırmanız kesinlikle önerilir. Böylece tüm olay dinleyicilerinin düzgün şekilde çalışması güvence altına alınır.

İlgili API Öğeleri

XMLSocket nesnesi tarafından belirtilen bağlantıyı kapatır. close olayı yalnızca sunucu bağlantıyı kapattığında gönderilir; close() yöntemini çağırdığınızda gönderilmez.

İlgili API Öğeleri

Belirtilen İnternet ana bilgisayarına, belirtilen TCP bağlantı noktasını kullanarak bağlantı kurar.

host parametresi için null değerini belirtirseniz, temas kurulan ana bilgisayar, XMLSocket.connect() öğesini çağıran dosyasının bulunduğu ana bilgisayardır. Örneğin, çağıran dosya www.adobe.com adresinden indirildiyse, host parametresi için null değerinin belirtilmesi, www.adobe.com adresine bağlandığınızı gösterir.

SWF içeriğini kapsayan HTML sayfasındaki object ve embed etiketlerinin allowNetworking parametresini ayarlayarak bir SWF dosyasının bu yöntemi kullanmasını önleyebilirsiniz.

Daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Parametreler

İlgili API Öğeleri

object parametresinde belirtilen XML nesnesini veya verilerini bir dizeye dönüştürür ve bu öğeyi, ardına sıfır (0) baytı ekleyerek bir sunucuya gönderir. object öğesi bir XML nesnesiyse, dize XML nesnesinin XML metin temsilidir. Gönderme işlemi eşzamanlı değildir; hemen döndürülür ancak veriler daha sonra iletilebilir. XMLSocket.send() yöntemi, verilerin başarıyla iletilip iletilmediğini gösteren bir değer döndürmez.

XMLSocket nesnesini, XMLSocket.connect()) öğesini kullanarak sunucuya bağlamazsanız, XMLSocket.send() işlemi başarısız olur.

Parametreler

İlgili API Öğeleri

Sunucu, soket bağlantısını kapattığında gönderilir. close olayı yalnızca sunucu bağlantıyı kapattığında gönderilir; XMLSocket.close() yöntemini çağırdığınızda gönderilmez.

Bu olay şu özelliklere sahiptir:

XMLSocket.connect() yöntemine yapılan başarılı bir çağrıdan sonra gönderilir.

Bu olay şu özelliklere sahiptir:

Ham veriler gönderildikten veya alındıktan sonra gönderilir.

Bu olay şu özelliklere sahiptir:

Bir gönderme veya alma işleminin başarısız olmasına neden olan bir girdi/çıktı hatası ortaya çıktığında gönderilir.

Bu olay şu özelliklere sahiptir:

XMLSocket.connect() yöntemine yapılan çağrı, çağıranın güvenlik sanal alanının dışındaki bir sunucuya veya 1024'ten daha düşük bir bağlantı numarasına bağlanmaya çalıştığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

1. XMLSocketExample yapıcısı socket adlı bir XMLSocket örneği oluşturur ve socket öğesini ConfigureListeners() öğesine ilettikten sonra (aşağıda açıklanmıştır) "localhost" ana bilgisayar adını ve 8080 bağlantı noktası numarasını kullanarak XMLSocket öğesinin connect() yöntemini çağırır.
2. Daha sonra configureListeners() yöntemi çağrılır ve desteklenen XMLSocket olaylarının her birine dinleyiciler ekler:
   • closeHandler(): ağ bağlantısı kapatıldıktan sonra gönderilen close olayını dinler.
   • connectHandler(): ağ bağlantısı kurulduğunda gönderilen connect olayını dinler.
   • dataHandler(): XMLSocket öğesi yeni verileri her aldığında gönderilen data olaylarını dinler.
   • progressHandler(): send() öğesine bir çağrı yapıldığında ve gönderme işlemi devam ederken gönderilen progress olaylarını dinler.
   • securityErrorHandler(): XMLSocket öğesine yanlış oynatma güvenlik ayarıyla veya 1024'ten düşük bir bağlantı noktası kullanılarak erişmek için bir deneme yapıldığında gönderilen securityError olaylarını dinler.
   • ioErrorHandler(): bir veri gönderme veya alma işlemi başarısız olduğunda meydana gelen ioError olaylarını dinler.

Notlar:

• SWF dosyasını “Yerel oynatma güvenliği“ ayarı “Yalnızca ağa erişim“ olacak şekilde derlemeniz gerekir.
• Bu örneğin çalışması için etki alanınız üzerinde 8080 bağlantı noktasını kullanarak çalışan bir sunucuya ihtiyacınız vardır.
• Flash Player 9.0.124.0 veya sonraki bir sürümü çalıştırıyorsanız, etki alanınızdan bağlantı noktası 8080'e soket bağlantısına izin veren bir soket ilke dosyasını sunucunuza yerleştirmeniz gerekir. Soket ilke dosyaları sunma hakkında bilgi için bkz. Flash Player Developer Center Konusu: Soket ilke dosyası sunucusu kurma.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            if (hostName && port) {
                socket.connect(hostName, port);
            }
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}