SQLConnection  - AS3

Geçerli veritabanı başlangıçta oluşturulurken, otomatik sıkışık hale getirmenin etkinleştirilmiş olup olmadığını belirtir (veritabanını oluşturan open() veya openAsync() çağrısında autoCompact parametresi için belirtilmiş değer). Bu özellik true olursa, her yazma işleminden sonra kullanılmayan alan veritabanı dosyasından otomatik olarak kaldırılarak veritabanı dosyasının boyutu küçük tutulur. Özellik false olursa, kaldırılan verinin önceden kapladığı alan veritabanı dosyasında bırakılır ve gerektiğinde kullanılır. autoCompact öğesi false olduğunda da compact() yöntemini çağırarak veritabanını kullanılmayan alanı geri kazanmaya zorlayabilirsiniz.

connected özelliği false olursa, bu özellik false değerine ayarlanır.

İlgili API Öğeleri

Bir defada bellekte tutulan veritabanı disk sayfalarının maksimum sayısını temsil eden, bu bağlantının önbellek boyutuna erişilmesini sağlar. Her sayfa yaklaşık 1,5 KB bellek kullanır (veritabanını oluşturan open() veya openAsync() yönteminin pageSize parametresi için belirtilen değere bağlı olarak). Varsayılan önbellek boyutu 2000'dir. Bir uygulama, veritabanının birçok satırını değiştiren UPDATE veya DELETE işlemlerini çalıştırıyorsa, önbellek boyutunun artırılması, yüksek bellek tüketimi pahasına hızı artırabilir.

İlgili API Öğeleri

SELECT ifadesinin sonucunda sütun adlarının nasıl bildirildiğini belirtir.

SQLColumnNameStyle sınıfında tanımlanan sabitler, bu özellik için olası değerleri temsil eder:

• SQLColumnNameStyle.LONG, sütun adlarının [tablo-adı]_[sütun-adı] biçiminde döndürüldüğünü belirtir.
• SQLColumnNameStyle.SHORT, sütun adlarının [sütun-adı] biçiminde verildiğini belirtir. Aynı ada sahip birden çok sütun varsa, yalnızca o ada sahip bir özellik sonuç nesnesine eklenir.
• SQLColumnNameStyle.DEFAULT, varsayılan değerdir. Bu değer kullanıldığında, sonuç sütun adları, benzer sütun adlarına sahip SELECT ifadesindeki tablo sayısına göre biçimlendirilir. SELECT ifadesi yalnızca bir tablo içeriyorsa, [column-name] kısa ad biçimi kullanılır ve SELECT ifadesi birleştirilmiş birden çok tablo içeriyorsa, iki sütun adı aynı olduğundan her adlandırma çatışması olduğunda, tamamen aynı adlı sütunlar için [table-name]_[column-name] uzun ad biçimi kullanılır.

İlgili API Öğeleri

SQLConnection örneğinin, veritabanı dosyasına açık bir bağlantısı olup olmadığını belirtir.

İlgili API Öğeleri

Bu bağlantının bir işlemde geçerli olarak yer alıp almadığını belirtir.

İlgili API Öğeleri

SQLConnection sınıfının geçerli platformda desteklenip desteklenmediğini belirtir.

Bir SQL INSERT ifadesi tarafından en son oluşturulan satır kimliği. Satır kimliği, veritabanındaki bir tabloda yer alan satırı benzersiz şekilde tanımlamak için kullanılır. Bu değer genellikle veritabanı tarafından oluşturulur.

Herhangi bir veritabanı bağlı değilse veya bir INSERT ifadesi çalıştırılmamışsa değer sıfır olur.

Tek bir SQL INSERT ifadesi çalıştırmaya yönelik satır kimliği, SQLStatement nesnesinin getResult() yönteminin döndürdüğü (SQLStatement result olayını gönderdikten sonra çağrıldığında) SQLResult nesnesinin lastInsertRowID özelliğiyle alınabilir.

Ana anahtarlar ve oluşturulan satır kimlikleri için “Yerel veritabanlarında SQL desteği” ekinde “TABLO OLULTUR” ve “İfadeler” bölümlerine bakın.

İlgili API Öğeleri

Geçerli veritabanı başlangıçta oluşturulurken belirtilen veritabanı sayfa boyutunu (bayt cinsinden) belirtir (veritabanını oluşturan open() veya openAsync() çağrısında pageSize parametresi için belirtilmiş değer).

connected özelliği false olursa, bu özelliğin değeri 0'dır.

Veritabanında birinci tablo oluşturuluncaya kadar veritabanının sayfa boyutu değiştirilebilir (open() veya openAsync() yöntemleri kullanılarak).

İlgili API Öğeleri

Veritabanına bağlantı açıldığından beri yapılan veri değişikliklerinin toplam sayısını içerir. INSERT, DELETE ve UPDATE deyimleri tarafından yapılan değişiklikleri izlemenin yanı sıra bu değer, tetikleyicilerin neden olduğu değişiklikleri içerir.

Veritabanı bağlantısı kapandığında, değer 0 değerine sıfırlanır. SQLConnection örneği bir veritabanına bağlanmadığında, değer 0 olur.

İlgili API Öğeleri

SQLConnection örneği oluşturur.

EventDispatcher nesnesi olan bir olay dinleyici nesnesini, dinleyicinin bir olayın bildirimini alması için kaydeder. Belirli türde bir olay, aşama ve öncelik için görüntüleme listesindeki tüm düğümlere olay dinleyicilerini kaydedebilirsiniz.

Bir olay dinleyicisini başarıyla kaydettikten sonra, addEventListener() öğesine ek çağrılar yaparak önceliğini değiştiremezsiniz. Bir dinleyicinin önceliğini değiştirmek için, ilk olarak removeListener() öğesini çağırmanız gerekir. Daha sonra dinleyiciyi yeni öncelik seviyesiyle kaydedebilirsiniz.

Dinleyici kaydedildikten sonra, farklı bir type veya useCapture değeriyle addEventListener() öğesine yapılan çağrılar, ayrı bir dinleyici kaydının oluşturulmasıyla sonuçlanır. Örneğin, ilk olarak useCapture true değerine ayarlanmış durumdayken bir dinleyiciyi kaydederseniz, dinleyici yalnızca yakalama aşaması boyunca dinleme işlemi yapar. Aynı dinleyici nesnesini kullanarak, ancak useCapture false değerine ayarlanmış durumdayken tekrar addEventListener() öğesini çağırırsanız, iki ayrı dinleyiciniz olur: bunlardan biri yakalama aşamasında dinleme işlemi yapar, diğeri ise hedef ve köpürme aşamasında dinleme işlemi yapar.

Yalnızca hedef aşaması veya köpürme aşaması için bir olay dinleyicisini kaydedemezsiniz. Köpürme yalnızca hedef düğümün alt öğeleri için geçerli olduğundan, bu aşamalar kayıt sırasında birleştirilir.

Artık bir olay dinleyicisine ihtiyacınız olmadığında, removeEventListener() öğesini çağırarak olay dinleyicisini kaldırın, aksi takdirde bellek sorunları oluşabilir. Çöp toplayıcısı, gönderen nesne var olduğu sürece dinleyiciyi kaldırmadığından, (useWeakReference parametresi true olarak ayarlı değilse) olay dinleyicileri otomatik olarak bellekten kaldırılmaz.

Bir EventDispatcher örneği kopyalandığında, o örneğe ekli olan olay dinleyicileri kopyalanmaz. (Yeni oluşturulmuş düğümünüz için bir olay dinleyicisi gerekiyorsa, düğümü oluşturduktan sonra dinleyiciyi eklemeniz gerekir.) Ancak bir EventDispatcher örneğini taşırsanız, örneğe ekli olan olay dinleyicileri de onunla birlikte taşınır.

Bir olay düğümde işlenirken olay dinleyicisi o düğüme kaydediliyorsa, geçerli aşama sırasında olay dinleyicisi tetiklenmez ancak olay akışındaki köpürme aşaması gibi sonraki bir aşamada tetiklenebilir.

Bir olay düğümde işlenirken olay dinleyicisi o düğümden kaldırılırsa, geçerli eylemler tetiklenmeye devam eder. Olay dinleyicisi kaldırıldıktan sonra asla tekrar çağrılmaz (ileride işlenmek üzere tekrar kaydedilmediği sürece).

Parametreler

function(evt:Event):void

Veritabanı dizinleri hakkında istatistik toplar ve bunları veritabanında saklar. Bu istatistikler daha sonra sorgu en iyileştirme aracı (veritabanı motorunun her bir ifadeyi en etkili biçimde çalıştırmanın yolunu belirleyen kısmı) tarafından kullanılabilir. İstatistikler, sorgu en iyileştirme aracının, belirli bir sorguyu çalıştırırken hangi dizinin veya dizinlerin kullanılacağı hakkında daha iyi kararlar almasına yardımcı olur.

Bir veritabanında tanımlı dizinler bulunuyorsa, ancak analyze() yöntemi çağrılmamışsa, çalışma zamanı, ifadeleri çalıştırmak için bu dizinleri kullanmaya devam eder. Ancak analyze() yöntemi tarafından oluşturulan ek istatistiksel bilgilerin yokluğunda, çalıştırma süresi, belirli bir sorgu için en etkili dizini seçemeyebilir.

Bir tablonun verileri (INSERT, UPDATE veya DELETE ifadelerinin sonucu olarak) değiştiğinde, söz konusu tabloyla ilişkili dizinler de değişir. analyze() tarafından oluşturulan istatistiksel bilgiler, otomatik olarak güncellenmez. Dolayısıyla, çok sayıda veri değişikliği gerçekleştirdikten sonra analyze() yönteminin yeniden çağrılması faydalı olabilir. Ancak, analyze() yönteminin yeniden çağrılmasından sağlanacak fayda, bir tabloda tanımlanan dizinlerin sayısı, değiştirilen satırların sayısıyla tablodaki toplam satır sayısı arasındaki ilişki, tablonun dizin halindeki verilerinin ne ölçüde değişkenlik gösterdiği ve değişen verilerin, değişim öncesindeki verilerden ne kadar farklı olduğu gibi çeşitli faktörlere bağlıdır.

resourceName parametresi, işlemin, eklenmiş tüm veritabanlarının dizinlerinde mi, belirli bir veritabanında mı, yoksa belirli bir tabloda mı gerçekleştirildiğini gösterir.

Bu yöntem her çağrıldığında, daha önce oluşturulan tüm veriler temizlenir ve resourceName parametresinde belirtilen veritabanı veya tablo için (veya resourceName null olduğu takdirde bağlantılı tüm veritabanlarındaki tüm tablolar için) yeniden oluşturulur. Bir veritabanı bağlantısı açık olduğu sürece, bu yöntem her zaman çağrılabilir. analyze() işlemi ve bu işlemin istatistiksel verileri bir işleme dahil edilmez; ancak, veritabanında geçerli bir işlem bulunuyorsa (inTransaction özelliği true olduğunda), en iyisi analyze() yöntemini çağırmamaktır. Bunun nedeni, işlemde çalıştırılan ancak henüz teslim edilmeyen herhangi bir şema, tablo şeması veya dizin değişikliğinin, analyze() çağrısı tarafından dikkate alınmaması ve işlem teslim edilir edilmez analyze() verilerinin geçerliliğini kaybetmesidir.

analyze() yöntemiyle oluşturulan istatistiksel verileri kaldırmak için, deanalyze() yöntemini kullanın.

Parametreler

İlgili API Öğeleri

SQLConnection örneğine başka bir veritabanı ekler ve yeni veritabanına belirtilen adı verir. Veritabanı eklenmesi, o veritabanının bu SQLConnection örneğine karşı çalıştırılan SQL ifadelerinde kullanılmasını sağlar.

Bir veritabanı zaten belirtilen ad kullanılarak önceden eklenmişse, attach() öğesinin çağrılması bir hata döndürür. Ancak benzersiz adlar kullanılarak aynı veritabanı birçok defa eklenebilir. Tek bir SQLConnection örneğine yalnızca on veritabanı eklenebilir.

Ana veritabanında (open() veya openAsync() kullanılarak bağlanmış veritabanı) çalıştırılabilen attach() öğesi kullanılarak bağlanmış bir veritabanında herhangi bir SQL ifadesi çalıştırılabilir. Bir SQL ifadesi, tek bir ifadede bulunan birden çok veritabanındaki tablolara erişim dahil olmak üzere, ifadenin ilişkilendirilmiş SQLConnection örneğine eklenen veritabanlarının herhangi birindeki tablolara erişebilir. Çalışma zamanı bir ifadedeki tablo adlarını çözerken, open() veya openAsync() yöntemi kullanılarak bağlanmış veritabanından başlayıp veritabanlarının eklendiği sıraya göre, SQLConnection örneğinin veritabanlarında arama yapar. Bir tablo adını açıkça nitelendirmek için ifadedeki veritabanı adını (attach() yönteminin name parametresinde belirtildiği gibi) kullanın.

attach() yöntemi kullanılarak eklenmiş bir veritabanını kaldırmak için, detach() yöntemini kullanın. SQLConnection örneği kapatıldığında (close() yöntemi çağrılarak), tüm eklenen veritabanları kaldırılır.

Eklenen veritabanı, ana veritabanın open() yöntemi mi yoksa openAsync() yöntemi mi kullanılarak bağlandığına göre ana veritabanıyla aynı çalıştırma modunu (eşzamanlı veya eşzamansız) kullanır.

Parametreler

İlgili API Öğeleri

Bağlantının veritabanına veya veritabanlarına karşı çalıştırıldığı tüm SQL ifadelerinin gruplandığı bir işlemi başlatır.

Varsayılan olarak her SQL ifadesi kendi işlemi içinde çalıştırılır ve ifadenin çalışması başarılı veya başarısız olduğunda sona erer. begin() yöntemi kullanılarak bir işlem oluşturulması, yeni ve elle bir işlemin oluşturulmasına neden olur. Bu noktada, SQLConnection örneğine karşı çalıştırılan tüm SQL ifadeleri işlem içinde yer alır ve ifadelerin gerçekleştirdiği tüm eylemler veya değişiklikler bir grup olarak teslim edilir (kalıcı hale getirilir) ya da geri alınır.

Bir işlemi sonlandırmak için, işlemin deyimleri tarafından yapılan değişikliklerin kalıcı hale mi getirilmiş veya geri alınmış olmasına bağlı olarak commit() ya da rollback() yöntemini çağırın.

begin() öğesine yapılan yuvalanmış çağrılar yok sayılır. setSavepoint() yöntemini çağırarak, bir işlemdeki yer işaretleri gibi kayıt noktaları oluşturabilirsiniz. Daha sonra, releaseSavepoint() veya rollbackToSavepoint() yöntemlerini çağırarak SQL deyimlerini kısmen teslim edebilir veya geri alabilirsiniz. Ancak, bir işlem begin() çağrılarak başlatılırsa, commit() yöntemi çağrılıncaya kadar değişiklikler kalıcı olarak veritabanına teslim edilmez.

İşlem açıkken veritabanı bağlantısı kapatıldığında, AIR işlemi otomatik olarak geri döndürür. (Not: AIR 1.1 ve daha önceki sürümler için, bağlantı kapatıldığında açık bir işlem otomatik olarak tamamlanır.)

İşlem, tek bir veritabanındaki ifade çalıştırma ile sınırlı değildir; eklenen farklı veritabanlarında çalıştırılan ifadeleri de içerebilir.

Parametreler

İlgili API Öğeleri

package
{
    import flash.data.SQLConnection;
    import flash.data.SQLResult;
    import flash.data.SQLStatement;
    import flash.display.Sprite;
    import flash.events.SQLErrorEvent;
    import flash.events.SQLEvent;
    import flash.filesystem.File;
    
    public class MultiInsertTransactionExample extends Sprite
    {
        private var conn:SQLConnection;
        private var insertEmployee:SQLStatement;
        private var insertPhoneNumber:SQLStatement;
        
        public function MultiInsertTransactionExample():void
        {
            // define where to find the database file
            var appStorage:File = File.applicationStorageDirectory;
            var dbFile:File = appStorage.resolvePath("ExampleDatabase.db");
            
            // open the database connection
            conn = new SQLConnection();
            conn.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            conn.addEventListener(SQLEvent.OPEN, openHandler);
            conn.openAsync(dbFile);
        }
        
        // Called when the database is connected
        private function openHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.OPEN, openHandler);
            
            // start a transaction
            conn.addEventListener(SQLEvent.BEGIN, beginHandler);
            conn.begin();
        }
        
        // Called when the transaction begins
        private function beginHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.BEGIN, beginHandler);
            
            // create and execute the first SQL statement:
            // insert an employee record
            insertEmployee = new SQLStatement();
            insertEmployee.sqlConnection = conn;
            insertEmployee.text = 
                "INSERT INTO employees (lastName, firstName, email) " + 
                "VALUES (:lastName, :firstName, :email, :birthday)";
            insertEmployee.parameters[":lastName"] = "Smith";
            insertEmployee.parameters[":firstName"] = "Bob";
            insertEmployee.parameters[":email"] = "bsmith@example.com";
            insertEmployee.parameters[":birthday"] = new Date(1971, 8, 12);
            
            insertEmployee.addEventListener(SQLEvent.RESULT, insertEmployeeHandler);
            insertEmployee.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            insertEmployee.execute();
        }
        
        // Called after the employee record is inserted
        private function insertEmployeeHandler(event:SQLEvent):void
        {
            insertEmployee.removeEventListener(SQLEvent.RESULT, insertEmployeeHandler);
            insertEmployee.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // Get the employee id of the newly created employee row
            var result:SQLResult = insertEmployee.getResult();
            var employeeId:Number = result.lastInsertRowID;
            
            // Add a phone number to the related phoneNumbers table
            insertPhoneNumber = new SQLStatement();
            insertPhoneNumber.sqlConnection = conn;
            insertPhoneNumber.text =
                "INSERT INTO phoneNumbers (employeeId, type, number) " +
                "VALUES (:employeeId, :type, :number)";
            insertPhoneNumber.parameters[":employeeId"] = employeeId;
            insertPhoneNumber.parameters[":type"] = "Home";
            insertPhoneNumber.parameters[":number"] = "(555) 555-1234";
            
            insertPhoneNumber.addEventListener(SQLEvent.RESULT, insertPhoneNumberHandler);
            insertPhoneNumber.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            insertPhoneNumber.execute();
        }
        
        // Called after the phone number record is inserted
        private function insertPhoneNumberHandler(event:SQLEvent):void
        {
            insertPhoneNumber.removeEventListener(SQLEvent.RESULT, insertPhoneNumberHandler);
            insertPhoneNumber.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // No errors so far, so commit the transaction
            conn.addEventListener(SQLEvent.COMMIT, commitHandler);
            conn.commit();
        }
        
        // Called after the transaction is committed
        private function commitHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.COMMIT, commitHandler);
            
            trace("Transaction complete");
        }
        
        // Called whenever an error occurs
        private function errorHandler(event:SQLErrorEvent):void
        {
            // If a transaction is happening, roll it back
            if (conn.inTransaction)
            {
                conn.addEventListener(SQLEvent.ROLLBACK, rollbackHandler);
                conn.rollback();
            }
            
            trace(event.error.message);
            trace(event.error.details);
        }
        
        // Called when the transaction is rolled back
        private function rollbackHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.ROLLBACK, rollbackHandler);
            
            // add additional error handling, close the database, etc.
        }
    }
}

package
{
    import flash.data.SQLConnection;
    import flash.data.SQLResult;
    import flash.data.SQLStatement;
    import flash.display.Sprite;
    import flash.events.SQLErrorEvent;
    import flash.events.SQLEvent;
    import flash.filesystem.File;
    
    public class MultiDeleteTransactionExample extends Sprite
    {
        private var conn:SQLConnection;
        private var deleteEmployee:SQLStatement;
        private var deletePhoneNumbers:SQLStatement;
        
        private var employeeIdToDelete:Number = 25;
        
        public function MultiDeleteTransactionExample():void
        {
            // define where to find the database file
            var appStorage:File = File.applicationStorageDirectory;
            var dbFile:File = appStorage.resolvePath("ExampleDatabase.db");
            
            // open the database connection
            conn = new SQLConnection();
            conn.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            conn.addEventListener(SQLEvent.OPEN, openHandler);
            conn.openAsync(dbFile);
        }
        
        // Called when the database is connected
        private function openHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.OPEN, openHandler);
            
            // start a transaction
            conn.addEventListener(SQLEvent.BEGIN, beginHandler);
            conn.begin();
        }
        
        // Called when the transaction begins
        private function beginHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.BEGIN, beginHandler);
            
            // Create and execute the first SQL statement:
            // Delete an employee's phone number records
            deletePhoneNumbers = new SQLStatement();
            deletePhoneNumbers.sqlConnection = conn;
            deletePhoneNumbers.text =
                "DELETE FROM phoneNumbers " +
                "WHERE employeeId = :employeeId";
            deletePhoneNumbers.parameters[":employeeId"] = employeeIdToDelete;
            
            deletePhoneNumbers.addEventListener(SQLEvent.RESULT, deletePhoneNumbersHandler);
            deletePhoneNumbers.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deletePhoneNumbers.execute();
        }
        
        // Called after the phone number records are deleted
        private function deletePhoneNumbersHandler(event:SQLEvent):void
        {
            deletePhoneNumbers.removeEventListener(SQLEvent.RESULT, deletePhoneNumbersHandler);
            deletePhoneNumbers.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deleteEmployee = new SQLStatement();
            deleteEmployee.sqlConnection = conn;
            deleteEmployee.text = 
                "DELETE FROM employees " + 
                "WHERE employeeId = :employeeId";
            deleteEmployee.parameters[":employeeId"] = employeeIdToDelete;
            
            deleteEmployee.addEventListener(SQLEvent.RESULT, deleteEmployeeHandler);
            deleteEmployee.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deleteEmployee.execute();
        }
        
        // Called after the employee record is deleted
        private function deleteEmployeeHandler(event:SQLEvent):void
        {
            deleteEmployee.removeEventListener(SQLEvent.RESULT, deleteEmployeeHandler);
            deleteEmployee.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // No errors so far, so commit the transaction
            conn.addEventListener(SQLEvent.COMMIT, commitHandler);
            conn.commit();
        }
        
        // Called after the transaction is committed
        private function commitHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.COMMIT, commitHandler);
            
            trace("Transaction complete");
        }
        
        // Called whenever an error occurs
        private function errorHandler(event:SQLErrorEvent):void
        {
            // If a transaction is happening, roll it back
            if (conn.inTransaction)
            {
                conn.addEventListener(SQLEvent.ROLLBACK, rollbackHandler);
                conn.rollback();
            }
            
            trace(event.error.message);
            trace(event.error.details);
        }
        
        // Called when the transaction is rolled back
        private function rollbackHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.ROLLBACK, rollbackHandler);
            
            // add additional error handling, close the database, etc.
        }
    }
}

SQLConnection örneğine bağlı veritabanlarında geçerli olarak çalıştırılan tüm SQL ifadelerini durdurur. Bu yöntem, uzun süredir çalışan veya art arda yapılan sorguları durdurmak için kullanılabilir.

cancel() yöntemi çağrıldığında çalıştırılan ifadeler varsa, bu yöntem ifadenin işlemlerini durdurur ve tamamlanmamış güncellemeler veya işlemler geri alınır. Geçerli olarak çalıştırılan ifadeler yoksa, bu yöntemin çağrılması açık bir işlemi geri alır, aksi takdirde herhangi bir şey yapmaz.

Parametreler

İlgili API Öğeleri

Geçerli veritabanı bağlantısını kapatır. Eklenen veritabanları da kaldırılır.

close() çağrıldığında açık bir işlem varsa, işlem geri alınır. Bir SQLConnection örneği çöp toplama işlemine tabi tutulduğunda, SQLConnection bir veritabanına bağlıyken AIR uygulamasının kapalı olması durumu dahil olmak üzere, çalışma zamanı otomatik olarak close() öğesini çağırır.

Parametreler

Mevcut bir işlemi teslim ederek, işlemin ifadeleri tarafından gerçekleştirilen eylemlerin kalıcı olarak veritabanına uygulanmasına neden olur.

setSavepoint() yöntemi çağrılarak, bir işlemdeki yer işaretleri gibi ara kayıt noktaları oluşturulabilir. Kayıt noktalarını kullanarak, releaseSavepoint() yöntemini çağırıp bir işlemin bölümlerini teslim edebilir veya rollbackToSavepoint() yöntemini çağırıp bir işlemin bölümlerini geri alabilirsiniz. Ancak, begin() yöntemi kullanılarak bir işlem açılırsa, commit() yöntemi çağrılarak işlemin tamamı teslim edilinceye kadar değişiklikler kalıcı olarak veritabanına teslim edilmez.

Kayıt noktalarını kullanan bir işlem için, işlemin tamamı teslim edildiğinde rollbackToSavepoint() yöntemi kullanılarak geri alınan hiçbir deyim teslim edilmez. releaseSavepoint() kullanılarak teslim edilen deyimler veya kayıt noktaları yayınlanmayan ya da geri alınmayan deyimler veritabanına teslim edilir.

Parametreler

İlgili API Öğeleri

Veritabanındaki tüm kullanılmamış alanı geri kazanır. Bir nesne (tablo, dizin veya tetikleyici) veritabanından bırakılırsa, ardında boş bir alan kalır. Bu, veritabanı dosyasını olması gerekenden daha büyük hale getirir ancak INSERT işlemlerini hızlandırabilir. Zamanla, INSERT ve DELETE işlemleri, veritabanı dosyası yapısını bölümlenmiş olarak bırakabilir, bu da diskin veritabanı içeriklerine erişimini yavaşlatır. Bu yöntem, boş sayfaları kaldırıp tablo verilerini sıkışık şekilde hizalayarak veritabanı dosyasını sıkışık hale getirir, aksi takdirde veritabanı dosyası yapısını temizler.

compact() işlemi, eklenen bir veritabanında gerçekleştirilemez; yalnızca SQLConnection örneği tarafından açılan ana (orijinal) veritabanı dosyasında gerçekleştirilebilir. Etkin bir işlem varsa ve bu işlemin bellek içi veritabanında bir etkisi yoksa bu işlem başarısız olur.

Parametreler

analyze() yöntemine yapılan bir çağrı tarafından oluşturulan tüm istatistiksel bilgileri kaldırır.

analyze() yöntemi tarafından oluşturulan istatistikler veritabanında yer tuttuğundan, deanalyze() öğesinin çağrılması, örneğin birçok dizin veya tablo bıraktıktan sonra bu yeri geri kazanmanızı sağlar.

Bu işlem, etkin bir işleme dahil değildir.

Parametreler

İlgili API Öğeleri

attach() yöntemi kullanılarak SQLConnection örneğine önceden eklenmiş bir ek veritabanını kaldırır. Aynı veritabanının farklı adlar kullanılarak birçok kez eklenmiş olması mümkündür ve bir bağlantı kaldırıldığında diğerleri olduğu gibi kalır. Bağlantının açık bir işlemi varsa (inTransaction özelliği true olursa) veritabanı kaldırılamaz.

Parametreler

İlgili API Öğeleri

loadSchema() yöntemine yapılan bir çağrının sonucuna erişilmesini sağlar. getSchemaResult() yöntemi, sonuçların ilk giren ilk çıkar kaidesiyle oluşturulmuş bir sırası gibi hareket eder. loadSchema() yöntemi çağrısı her tamamlandığında (eşzamansız çalıştırma modunda her schema olayı gönderildiğinde), sıraya yeni bir SQLSchemaResult nesnesi eklenir. getSchemaResult() yöntemi her çağrıldığında, en eski sonuç (kuyruğa ilk eklenen) döndürülür ve kuyruktan kaldırılır. Kuyrukta başka nesne kalmadığında, getSchemaResult() yöntemi null değerini döndürür.

Veritabanı bağlantısı kapandığında, yöntem null değerini döndürür.

İlgili API Öğeleri

Bağlı veritabanından veya herhangi bir eklenen veritabanından şema bilgilerini yükler. Şema, veritabanı tablolarının, sütunlarının, dizinlerinin ve tetikleyicilerinin yapısını belirtir.

Yüklenen şemaya erişmek için SQLConnection.getSchemaResult() yöntemini kullanın.

Eşzamansız çalıştırma modunda, işlem başarılı olursa bir schema olayı veya işlem başarısız olursa bir error olayı gönderilir.

type ve name parametresi değerlerinin birleşimi, loadSchema() yöntemi tarafından oluşturulan şema verilerinin türünü ve dolayısıyla da oluşturulan SQLSchemaResult örneğinin özelliklerinin değerlerini belirler. Şu tabloda geçerli type ve name çiftleri ve sonucunda oluşturulan şema verileri listelenmektedir:

type ve name argümanlarının birleşimi, belirtilen birleşimlerden birine karşılık gelmezse, eşzamansız çalıştırma modunda bir error olayı gönderilir ve eşzamanlı çalıştırma modunda bir istisna atılır. Örneğin, type argümanı SQLViewSchema ise ve name argümanı da bir tablonun adıysa (görünüm adı yerine), bir hata verilerek veritabanının belirtilen adla belirtilen türdeki bir nesneyi içermediğini belirtir.

Veritabanı boşsa (herhangi bir tablo, görünüm, tetikleyici veya dizin içermiyorsa), loadSchema() yönteminin çağrılması hatayla sonuçlanır.

Parametreler

İlgili API Öğeleri

Dosya sisteminde belirtilen konumdaki veritabanı dosyasına eşzamanlı bir bağlantı açar veya o konumda yeni bir veritabanı dosyası oluşturup açar ya da bir bellek içi veritabanı oluşturup açar. Veritabanı bu yöntem kullanılarak açıldığında, veritabanı oluşturma ve açma işlemlerinin yanı sıra bu SQLConnection örneği kullanılarak gerçekleştirilen diğer tüm işlemler de (ifade çalıştırma ve bu SQLConnection örneğiyle ilişkilendirilmiş bir SQLStatement örneği tarafından gerçekleştirilen diğer işlemler dahil) eşzamanlı olarak gerçekleştirilir. İşlemleri eşzamansız olarak gerçekleştirmek için, bunun yerine openAsync() yöntemini kullanarak veritabanı bağlantısını açın.

Veritabanı bağlandıktan sonra, SQL komutlarını çalıştırmak için bir SQLStatement örneği kullanın. İşlem başlatma veya sonlandırma, şema bilgilerini yükleme gibi veritabanı düzeyindeki işlemler ve diğer işlemler, SQLConnection örneği kullanılarak gerçekleştirilir.

open() yöntemi kullanılarak bağlanan bir veritabanına otomatik olarak "main" veritabanı adı atanır. Bu ad [veritabanı-adı] biçimini kullanan SQL deyimlerinde tablo adlarını açıkça nitelendirmek için kullanılabilir.[table-name].

Parametreler

İlgili API Öğeleri

Dosya sisteminde belirtilen konumdaki veritabanı dosyasına eşzamansız bir bağlantı açar veya o konumda yeni bir veritabanı dosyası oluşturup açar ya da bir bellek içi veritabanı oluşturup açar. Veritabanı bu yöntem kullanılarak açıldığında, veritabanı oluşturma ve açma işlemlerinin yanı sıra bu SQLConnection örneği kullanılarak gerçekleştirilen diğer tüm işlemler de (ifade çalıştırma ve bu SQLConnection örneğiyle ilişkilendirilmiş bir SQLStatement örneği tarafından gerçekleştirilen diğer işlemler dahil) eşzamansız olarak gerçekleştirilir. İşlemleri eşzamanlı olarak gerçekleştirmek için, bunun yerine open() yöntemini kullanarak veritabanı bağlantısını açın.

Veritabanı bağlandıktan sonra, SQL komutlarını çalıştırmak için bir SQLStatement örneği kullanın. İşlem başlatma veya sonlandırma, şema bilgilerini yükleme gibi veritabanı düzeyindeki işlemler ve diğer işlemler, SQLConnection örneği kullanılarak gerçekleştirilir.

openAsync() yöntemi kullanılarak bağlanan bir veritabanına otomatik olarak "main" veritabanı adı atanır; bu ad [veritabanı-adı] biçimini kullanan SQL ifadelerinde tablo adlarını açıkça nitelendirmek için kullanılabilir.[table-name].

Parametreler

İlgili API Öğeleri

Şifreli veritabanının şifreleme anahtarını değiştirir. Bu yöntem yalnızca ana veritabanının şifreleme anahtarını etkiler (open() veya openAsync() yöntemi kullanılarak bağlanılan veritabanı). reencrypt() yöntemini yalnızca oluşturulduğunda şifreli olan bir veritabanında çağırabilirsiniz. Veritabanı bir kez şifreli veritabanı olarak oluşturulduğunda, şifresiz duruma getirilemez. Benzer şekilde, şifreleme olmadan oluşturulan bir veritabanı daha sonradan şifrelenemez.

Yeniden şifreleme işlemi, kendi işlemi içinde çalışır. Yeniden şifreleme işlemi kesintiye uğradığında, veritabanı işlemi geri alır ve şifreleme anahtarı değiştirilmez.

Parametreler

İlgili API Öğeleri

Bu yöntem, en son kayıt noktasından veya bir ad belirtilmişse adlandırılmış kayıt noktasından itibaren yapılan SQL işlemlerini teslim eder.

İşlemin tamamı teslim edilinceye kadar hiçbir değişikliğin kalıcı olarak veritabanına kaydedilmediğini unutmayın. begin() yöntemi kullanılarak işlem başlatılırsa, işlemin tamamını teslim etmek için commit() yöntemini çağırmanız gerekir. inTransaction öğesi false iken setSavepoint() çağrılarak işlem başlatılırsa, işlemin ilk kayıt noktası için commit() yöntemini çağırarak veya releaseSavepoint() ya da rollbackToSavepoint() öğesini çağırarak işlemin tamamını bitirebilirsiniz.

Kod, rollback() yöntemini çağırırsa, releaseSavepoint() öğesinin işlem geri alındıktan önce çağrılıp çağrılmadığına bakılmaksızın, işlemdeki tüm değişiklikleri kalıcı olarak atar.

Bu yöntem herhangi bir parametre olmadan (veya name parametresi için null değeri ayarlıyken) çağrılırsa, en son adlandırılmamış kayıt noktasından itibaren (herhangi bir name parametresi olmadan setSavepoint() çağrılarak oluşturulan en son kayıt noktası) yapılan tüm veritabanı değişikliklerini teslim eder. Örneğin, setSavepoint() yöntemi üç defa çağrıldıysa, üç kayıt noktası ayarlanır. Bu noktada releaseSavepoint() öğesi çağrıldığında, üçüncü (en yeni) kayıt noktasından itibaren gerçekleştirilen SQL işlemleri teslim edilir.

name parametresi için bir değer sağlanırsa, bu yöntem belirtilen ada sahip kayıt noktasından itibaren gerçekleştirilen tüm SQL işlemlerini teslim eder. Diğer kayıt noktaları, belirtilen kayıt noktasından sonra oluşturulduysa, bu kayıt noktalarından sonra gerçekleştirilen işlemler de teslim edilir.

Bir kayıt noktası yayınlandıktan veya geri alındıktan sonra, o kayıt noktası ve daha sonraki kayıt noktaları kaldırılır. releaseSavepoint() veya rollbackToSavepoint() çağrısı bir kayıt noktasını kaldırdıktan sonra kod ek SQL işlemleri çalıştırırsa, bu işlemler kalan en son kayıt noktasına ait olur. (Başka bir deyişle, kaldırılan kayıt noktasından önce en son oluşturulan kayıt noktasına ait olur.) Herhangi bir kayıt noktası kalmazsa, işlemler ana işleme ait olur.

Parametreler

İlgili API Öğeleri

EventDispatcher nesnesinden bir dinleyiciyi kaldırır. EventDispatcher nesnesiyle kayıtlı eşlenen bir dinleyici yoksa, bu yönteme yapılan çağrının herhangi bir etkisi yoktur.

Parametreler

begin() yöntemi kullanılarak oluşturulan mevcut bir işlemi geri alır, başka bir deyişle, işlemdeki, SQL ifadeleri tarafından yapılan değişikliklerin tümü atılır.

setSavepoint() yöntemi çağrılarak bir işlem içinde ara kayıt noktaları işaretlenebilir. Kayıt noktalarını kullanarak, releaseSavepoint() yöntemini çağırıp bir işlemin bölümlerini teslim edebilir veya rollbackToSavepoint() yöntemini çağırıp bir işlemin bölümlerini geri alabilirsiniz. Ancak, rollback() yöntemi çağrıldığında, tek tek kayıt noktalarının işlem geri alınmadan önce yayınlanmış (teslim edilmiş) olup olmadığına bakılmaksızın bir işlemde gerçekleştirilen tüm değişiklikler kalıcı olarak atılır.

Parametreler

İlgili API Öğeleri

En son kayıt noktasından veya bir ad belirtilmişse adlandırılmış kayıt noktasından itibaren yapılan SQL işlemlerini geri alır.

İşlemin tamamı, commit() yöntemi çağrılarak teslim edilirse, işlemdeki rollbackToSavepoint() yöntemi kullanılarak önceden geri alınmayan değişiklikler kalıcı olarak veritabanına kaydedilir. Ayrıca, rollback() yöntemi çağrıldığında, tek tek kayıt noktalarının işlem geri alınmadan önce yayınlanmış (teslim edilmiş) olup olmadığına bakılmaksızın tüm değişiklikler kalıcı olarak atılır.

Bu yöntem herhangi bir parametre olmadan (veya name parametresi için null değeri ayarlıyken) çağrılırsa, en son adlandırılmamış kayıt noktasından itibaren (herhangi bir name parametresi değeri olmadan setSavepoint() öğesine yapılan en son çağrı) yapılan tüm veritabanı değişikliklerini teslim eder.

name parametresi için bir değer sağlanırsa, bu yöntem belirtilen ada sahip kayıt noktasından itibaren gerçekleştirilen tüm SQL işlemlerini geri alır. Diğer kayıt noktaları, belirtilen kayıt noktasından sonra oluşturulduysa, bu kayıt noktalarından itibaren gerçekleştirilen işlemler de geri alınır.

Bir kayıt noktası yayınlandıktan veya geri alındıktan sonra, o kayıt noktası ve daha sonraki kayıt noktaları kaldırılır. releaseSavepoint() veya rollbackToSavepoint() çağrısı bir kayıt noktasını kaldırdıktan sonra kod ek SQL işlemleri çalıştırırsa, bu işlemler kalan en son kayıt noktasına ait olur. (Başka bir deyişle, kaldırılan kayıt noktasından önce en son oluşturulan kayıt noktasına ait olur.) Herhangi bir kayıt noktası kalmazsa, işlemler ana işleme ait olur.

Parametreler

İlgili API Öğeleri

Veritabanı işlemindeki bir yer işareti gibi bir kayıt noktası oluşturur. Kayıt noktası, işlem içindeki bir noktayı temsil eder. Kayıt noktaları arasında gerçekleştirilen SQL işlemleri kümesi, releaseSavepoint() ve rollbackToSavepoint() yöntemleri kullanılarak diğer işlemlerden ayrı şekilde teslim edilebilir veya geri alınabilir. Bu şekilde, kayıt noktası kullanmanız, SQL işlemleri kümesini yuvalanmış bir işlem olarak değerlendirmenize olanak sağlar.

setSavepoint() yöntemi çağrıldığında, bir işlem önceden açılmadıysa (begin() yöntemi çağrılarak), bu yöntem çağrıldığında işlem başlatılır ve işlemin başında bir kayıt noktası oluşturulur. Bir işlem önceden açıldıysa, setSavepoint() öğesi çağrıldığında işlem içinde bir kayıt noktası oluşturulur.

İşlemin tamamı teslim edilinceye kadar hiçbir değişikliğin kalıcı olarak veritabanına kaydedilmediğini unutmayın. begin() yöntemi kullanılarak işlem başlatılırsa, işlemin tamamını teslim etmek için commit() yöntemini çağırmanız gerekir. inTransaction öğesi false iken setSavepoint() öğesi çağrılarak işlem başlatılırsa, commit() yöntemini çağırarak işlemin tamamını bitirebilirsiniz. Ayrıca işlemi başlatan kayıt noktası için releaseSavepoint() veya rollbackToSavepoint() öğesini çağırdığınızda işlem otomatik olarak biter.

name parametresi için bir değer sağlayarak kayıt noktası için bir ad belirtebilirsiniz. Böylece, o belirli kayıt noktasından itibaren yapılan tüm değişiklikleri geri alabilir veya teslim edebilirsiniz. Herhangi bir ad belirtilmezse (varsayılan), adlandırılmamış bir kayıt noktası oluşturulur.

Bir kayıt noktası yayınlandıktan veya geri alındıktan sonra, o kayıt noktası ve daha sonraki kayıt noktaları kaldırılır. releaseSavepoint() veya rollbackToSavepoint() çağrısı bir kayıt noktasını kaldırdıktan sonra kod ek SQL işlemleri çalıştırırsa, bu işlemler kalan en son kayıt noktasına ait olur. (Başka bir deyişle, kaldırılan kayıt noktasından önce en son oluşturulan kayıt noktasına ait olur.) Herhangi bir kayıt noktası kalmazsa, işlemler ana işleme ait olur.

Parametreler

İlgili API Öğeleri

Bir analyze() işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir attach() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir begin() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir cancel() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir close() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir commit() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir compact() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir deanalyze() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

SQL DELETE komutunun sonucunda, bağlantılı veritabanlarının herhangi birindeki herhangi bir tablodaki veriler değiştirildiğinde gönderilir. Veri değişikliği, SQLStatement örneği aracılığıyla çalıştırılan bir DELETE ifadesinin doğrudan sonucu veya bir ifadenin çalıştırılmasına yanıt olarak bir tetikleyicinin ateşlemesinin dolaylı sonucu olabilir.

İlgili API Öğeleri

Bir detach() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

SQLConnection nesnesinin eşzamansız işlemlerinden herhangi biri hatayla sonuçlandığında gönderilir. Olay nesnesinde, gerçekleştirilmeye çalışılan işlem ve işlemin başarısız olma nedeni hakkında bilgi içeren error özelliği bulunduğunda gönderilen SQLErrorEvent örneği.

SQL INSERT komutunun sonucunda, bağlantılı veritabanlarının herhangi birindeki herhangi bir tablodaki veriler değiştirildiğinde gönderilir. Veri değişikliği, SQLStatement örneği aracılığıyla çalıştırılan bir INSERT ifadesinin doğrudan sonucu veya bir ifadenin çalıştırılmasına yanıt olarak bir tetikleyicinin ateşlemesinin dolaylı sonucu olabilir.

İlgili API Öğeleri

Bir openAsync() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

reencrypt() yöntemi çağrı işlemi başarıyla tamamlandığında gönderilir.

İlgili API Öğeleri

Bir releaseSavepoint() yöntemi çağrısının işlemi başarıyla tamamlandığında gönderilir.

İlgili API Öğeleri

Bir rollback yöntemi çağrısının işlemi başarılı biçimde tamamlandığında gönderilir.

İlgili API Öğeleri

Bir rollbackToSavepoint() yöntemi çağrısının işlemi başarıyla tamamlandığında gönderilir.

İlgili API Öğeleri

loadSchema() yöntemi çağrısının işlemi başarılı biçimde tamamlandığında ve şema sonuçları hazır olduğunda gönderilir.

İlgili API Öğeleri

Bir setSavepoint() yöntemi çağrısının işlemi başarıyla tamamlandığında gönderilir.

İlgili API Öğeleri

SQL UPDATE komutunun sonucunda, bağlantılı veritabanlarının herhangi birindeki herhangi bir tablodaki veriler değiştirildiğinde gönderilir. Veri değişikliği, SQLStatement örneği aracılığıyla çalıştırılan bir UPDATE ifadesinin doğrudan sonucu veya bir ifadenin çalıştırılmasına yanıt olarak bir tetikleyicinin ateşlemesinin dolaylı sonucu olabilir.

update olayı şu özelliklere sahiptir:

İlgili API Öğeleri