DataGridEvent  - AS3 Flash

Sütunla ilişkilendirilen verilerdeki alanın veya özelliğin adını alır veya ayarlar.

Düzenlenmekte olan olay için öğe oluşturucuyu veya tıklatılan ya da yeniden boyutlandırılan üstbilgi oluşturucuyu alır.

itemEditEnd olayının gönderilme nedenini alır. Bu özellik yalnızca DataGridEvent.ITEM_EDIT_END türünde olaylar için geçerlidir.

Olası değerler DataGridEventReason sınıfında tanımlanır.

İlgili API Öğeleri

Belirtilen parametreler ile bir DataGridEvent nesnesi oluşturur.

İlgili API Öğeleri

DataGridEvent nesnesinin bir kopyasını oluşturur ve her özelliğin değerini, orijinalinki ile aynı olacak şekilde ayarlar.

DataGridEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[DataGridEvent type=value bubbles=value cancelable=value columnIndex=value rowIndex=value itemRenderer=value dataField=value reason=value]

DataGridEvent.COLUMN_STRETCH sabiti bir columnStretch olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

DataGridEvent.HEADER_RELEASE sabiti bir headerRelease olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

DataGridEvent.ITEM_EDIT_BEGIN sabiti bir itemEditBegin olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

DataGridEvent.ITEM__EDIT_BEGINNING sabiti bir itemEditBeginning olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

DataGridEvent.ITEM_EDIT_END sabiti bir itemEditEnd olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

DataGridEvent.ITEM_FOCUS_IN sabiti bir itemFocusIn olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

DataGridEvent.ITEM_FOCUS_OUT sabiti bir itemFocusOut olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Örneği çalıştırmak için şu adımları izleyin:

1. DataGrid bileşenini kütüphaneye ekleyin.
2. Bu kodu FLA dosyanızla aynı dizine DataGridEventExample.as olarak kaydedin.
3. FLA dosyasındaki Document sınıfını DataGridEventExample olarak ayarlayın.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}