RadioButtonGroup

Paket	fl.controls
Sınıf	public class RadioButtonGroup
Miras Alma	RadioButtonGroup EventDispatcher Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

RadioButtonGroup sınıfı, tek bir bileşen olarak kullanılabilen RadioButton bileşenleri grubunu tanımlar. Bir radyo düğmesi seçildiğinde, aynı grupta bulunan hiçbir radyo düğmesi seçilemez.

Örnekleri görüntüle

İlgili API Öğeleri

RadioButton
RadioButton.group

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		name : String [salt okunur] Radyo düğmesinin örnek adını alır.	RadioButtonGroup
		numRadioButtons : int [salt okunur] Bu radyo düğmesi grubundaki radyo düğmesi sayısını alır.	RadioButtonGroup
		selectedData : Object Seçili radyo düğmesinin value özelliğini alır veya ayarlar.	RadioButtonGroup
		selection : RadioButton Radyo düğmesi grubunda geçerli olarak seçilmiş olan radyo düğmesine bir başvuru alır veya ayarlar.	RadioButtonGroup

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		RadioButtonGroup(name:String) Yeni bir RadioButtonGroup örneği oluşturur.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void EventDispatcher nesnesi olan bir olay dinleyici nesnesini, dinleyicinin bir olayın bildirimini alması için kaydeder.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Bir radyo düğmesi grubundan tek bir radyo düğmesi seçimine olanak tanıyan radyo düğmesi grubu dizinlemesiyle birlikte kullanmak üzere dahili radyo düğmesi dizisine bir radyo düğmesi ekler.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Olay akışına bir olay gönderir.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statik] Belirtilen radyo düğmesine grubuna bir başvuru alır.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton RadioButton bileşenini belirtilen dizin konumunda alır.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Belirtilen RadioButton örneğinin dizinini döndürür.	RadioButtonGroup
		hasEventListener(type:String):Boolean EventDispatcher nesnesinin belirli bir olay türü için kayıtlı dinleyicisi olup olmadığını kontrol eder.	EventDispatcher
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void EventDispatcher nesnesinden bir dinleyiciyi kaldırır.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void RadioButton örneğini, dahili radyo düğmesi listesinden temizler.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object
		willTrigger(type:String):Boolean Bir olay dinleyicisinin bu EventDispatcher nesnesiyle mi, yoksa onun belirtilen olay türüne yönelik üst öğelerinden biriyle mi kayıtlı olduğunu kontrol eder.	EventDispatcher

Olaylar

Olaylarla ilgili daha fazla bilgi için tıklatın

Miras Alınan Olayları Gizle

Miras Alınan Olayları Göster

	Özet	Tanımlayan:
activate	[broadcast olayı] Flash Player veya AIR uygulaması işletim sistemi odağına gelip etkin olduğunda gönderilir.	EventDispatcher
change	Bir gruptaki seçili RadioButton örneği değiştiğinde gönderilir.	RadioButtonGroup
click	Bir RadioButton örneği tıklatıldığında gönderilir.	RadioButtonGroup
deactivate	[broadcast olayı] Çalışan Flash Player veya AIR uygulaması sistem odağını kaybettiğinde ve etkin olmayan duruma geldiğinde gönderilir.	EventDispatcher

Özellik Ayrıntısı

name

özellik

name:String [salt okunur]

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Radyo düğmesinin örnek adını alır.

Varsayılan değer şudur "RadioButtonGroup".

Uygulama
public function get name():String

numRadioButtons

özellik

numRadioButtons:int [salt okunur]

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bu radyo düğmesi grubundaki radyo düğmesi sayısını alır.

Varsayılan değer şudur 0.

Uygulama
public function get numRadioButtons():int

selectedData

özellik

selectedData:Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Seçili radyo düğmesinin value özelliğini alır veya ayarlar. Geçerli olarak seçilen bir radyo düğmesi yoksa bu özellik null olur.

Uygulama
public function get selectedData():Object
public function set selectedData(value:Object):void

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki örnek, bir RadioButtonGroup bileşeni oluşturur ve bu bileşenin change olayını dinler:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

özellik

selection:RadioButton

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Radyo düğmesi grubunda geçerli olarak seçilmiş olan radyo düğmesine bir başvuru alır veya ayarlar.

Uygulama
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, iki radyo düğmesi içeren yeni bir radyo düğmesi grubu oluşturur: Geçerli olarak seçili olan radyo düğmesi değiştiğinde, seçili radyo düğmesinin etiketi ve değeri izlenir:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Yapıcı Ayrıntı

()

Yapıcı

public function RadioButtonGroup(name:String)

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Yeni bir RadioButtonGroup örneği oluşturur. Bu, genellikle bir radyo düğmesi başlatıldığında otomatik olarak yapılır.

Parametreler

name:String — Radyo düğmesi grubunun adı.

Yöntem Ayrıntısı

addRadioButton

()

yöntem

public function addRadioButton(radioButton:RadioButton):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir radyo düğmesi grubundan tek bir radyo düğmesi seçimine olanak tanıyan radyo düğmesi grubu dizinlemesiyle birlikte kullanmak üzere dahili radyo düğmesi dizisine bir radyo düğmesi ekler. Bu yöntem, radyo düğmeleri tarafından otomatik olarak kullanılabilir, bunun yanı sıra bir radyo düğmesinin bir gruba açıkça eklenmesi için elle de kullanılabilir.

Parametreler

radioButton:RadioButton — Geçerli radyo düğmesi grubuna eklenecek olan RadioButton örneği.

getGroup

()

yöntem

public static function getGroup(name:String):RadioButtonGroup

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Belirtilen radyo düğmesine grubuna bir başvuru alır.

Parametreler

name:String — Başvuru alacak olan grubun adı.

Döndürür

RadioButtonGroup — Belirtilen RadioButtonGroup örneğine yapılan başvuru.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir gruptaki hangi radyo düğmesinin seçildiğinin nasıl belirleneceğini gösterir:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

yöntem

public function getRadioButtonAt(index:int):RadioButton

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

RadioButton bileşenini belirtilen dizin konumunda alır.

Parametreler

index:int — RadioButtonGroup bileşenindeki, ilk bileşen dizininin 0 olduğu RadioButton bileşeni dizini.

Döndürür

RadioButton — Belirtilen RadioButton bileşeni.

Atar

RangeError — Belirtilen dizin 0'dan küçük veya veri sağlayıcı uzunluğuna eşit ya da veri sağlayıcı uzunluğundan büyüktür.

getRadioButtonIndex

()

yöntem

public function getRadioButtonIndex(radioButton:RadioButton):int

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Belirtilen RadioButton örneğinin dizinini döndürür.

Parametreler

radioButton:RadioButton — Geçerli RadioButtonGroup içinde konumlandırılacak olan RadioButton örneği.

Döndürür

int — Belirtilen RadioButton bileşeninin dizini veya belirtilen RadioButton bulunamazsa -1.

removeRadioButton

()

yöntem

public function removeRadioButton(radioButton:RadioButton):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

RadioButton örneğini, dahili radyo düğmesi listesinden temizler.

Parametreler

radioButton:RadioButton — Kaldırılacak RadioButton örneği.

Olay Ayrıntısı

change

Olay

Olay Nesne Türü: flash.events.Event
özellik Event.type = flash.events.Event.CHANGE

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir gruptaki seçili RadioButton örneği değiştiğinde gönderilir.

Event.CHANGE sabiti, change olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`true`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Bu Event nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Değerleri değiştirilen nesne. `target` her zaman olay dinleyicisini kaydeden görüntüleme listesindeki nesne değildir. Geçerli olarak olayı işleyen görüntüleme listesindeki nesneye erişmek için `currentTarget` özelliğini kullanın.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, üç radyo düğmesi oluşturur ve bir radyo düğmesi grubunun change olayına bir olay dinleyici ekler:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Olay

Olay Nesne Türü: flash.events.MouseEvent
özellik MouseEvent.type = flash.events.MouseEvent.CLICK

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir RadioButton örneği tıklatıldığında gönderilir.

click olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`altKey`	Alt tuşu etkin olduğunda `true` (Windows).
`bubbles`	`true`
`buttonDown`	Click olayları için, bu değer her zaman `false` olur.
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`commandKey`	Command tuşu etkin olduğunda Mac'te `true`; etkin olmadığında `false`. Windows'ta her zaman `false`.
`controlKey`	Ctrl tuşu etkin olduğunda `true`; etkin olmadığında `false`.
`ctrlKey`	Ctrl tuşu etkin olduğunda Windows veya Linux'ta `true`. Ctrl veya Command tuşu etkin olduğunda Mac'te `true`. Aksi takdirde, `false`.
`currentTarget`	Bu Event nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`localX`	Fare kilidinin devre dışı olduğu durumda, olayın içerilen hareketli grafiğe göre meydana geldiği yatay koordinat.
`localY`	Fare kilidinin devre dışı olduğu durumda, olayın içerilen hareketli grafiğe göre meydana geldiği dikey koordinat.
`movementX`	Fare kilidinin etkin olduğu durumda, son fare hareketinden itibaren fare konumunun yatay koordinatlarında meydana gelen değişiklik.
`movementY`	Fare kilidinin etkin olduğu durumda, son fare hareketinden itibaren fare konumunun dikey koordinatlarında meydana gelen değişiklik.
`shiftKey`	Shift tuşu etkinse `true`; etkin değilse `false`.
`stageX`	Olayın global stage koordinatlarında gerçekleştiği yatay koordinat.
`stageY`	Olayın global stage koordinatlarında gerçekleştiği dikey koordinat.
`target`	İşaretleme aygıtının altındaki InteractiveObject örneği. `target` her zaman olay dinleyicisini kaydeden görüntüleme listesindeki nesne değildir. Geçerli olarak olayı işleyen görüntüleme listesindeki nesneye erişmek için `currentTarget` özelliğini kullanın.

Örnekler Bu örnek nasıl kullanılır?

RadioButtonGroupExample.as

Bu örnek, birçok RadioButton nesnesinin birkaç grup üzerinden nasıl yönetileceğini gösterir.

RadioButton ve Label bileşenlerini kütüphanenize ekleyin.
Bu kodu FLA dosyanızla aynı dizine RadioButtonGroupExample.as olarak kaydedin.
FLA dosyasındaki DocumentClass öğesini RadioButtonGroupExample olarak ayarlayın.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

RadioButtonGroup - AS3 Flash

Paketlerx

Dil Öğeleri

Ekler

Paket fl.controls

name

numRadioButtons

selectedData

selection