Paket flash.utils 

Avbryter ett angivet setInterval()-anrop.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Avbryter ett visst setTimeout()-anrop.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Skapar ett XML-objekt som beskriver ActionScript-objektet som anges som parameter för metoden. Den här metoden implementerar programmeringsbegreppet reflection som används i ActionScript-språket.

Om parametern value är en typinstans omfattar det returnerade XML-objektet alla instansegenskaper för den typen, men inga statiska egenskaper. Du kan undersöka det här villkoret när du tolkar XML-objektet genom att analysera värdet för <type>-taggens isStatic-attribut, som är false när parametern value är en typinstans.

De statiska egenskaperna för en typ får du om du skickar själva typen för value-parametern. Det returnerade XML-objektet omfattar inte bara typens statiska egenskaper utan också alla dess instansegenskaper. Instansegenskaperna kapslas in i en tagg med namnet <factory> och åtskiljs därmed från de statiska egenskaperna. I detta fall är isStatic-attributet för <type>-taggen true.

Obs! Om du bara behöver gå igenom ett objekts arvshierarki och inte behöver den andra informationen från describeType(), använder du i stället getQualifiedClassName() och getQualifiedSuperclassName()-funktionerna.

I följande tabell beskrivs några av taggarna och attributen i XML-objektet som genereras av describeType() (alla klass- och gränssnittsnamn som returneras är i fullt kvalificerat format):

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Returnerar en escape-konverterad kopia av indatasträngen, kodad som UTF-8 eller med plattformens teckentabell, beroende på värdet för System.useCodePage. Om System.useCodePage används kan miljön öppna äldre innehåll som är kodat med en lokal teckentabell, men bara på plattformar där den äldre teckentabellen används. Japanska data som kodats som Shift-JIS kan bara escape-konverteras och unescape-konverteras korrekt på ett operativsystem där japansk standardteckentabell används.

Parametrar

Returnerar en referens till klassobjektet för klassen som anges av parametern name.

Parametrar

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Returnerar det fullständigt kvalificerade klassnamnet för ett objekt.

Parametrar

Relaterade API-element

Returnerar det fullständigt kvalificerade klassnamnet för basklassen för objektet som anges av parametern value. Den här funktionen är ett snabbare sätt att hämta basklassnamn än describeType() men den ger inte all information som describeType() gör.

När du har hämtat namnet på en klass med den här funktionen kan du konvertera klassnamnet till en klassreferens med funktionen getDefinitionByName().

Obs! Funktionen är begränsad till instanshierarkier, medan funktionen describeType() använder klassobjekthierarkier om parametern value är en datatyp. Om describeType() anropas på en datatyp returneras den överordnade klassen utifrån klassobjektshierarkin, där alla klassobjekt ärver från Class. Däremot ignorerar funktionen getQualifiedSuperclassName() klassobjektshierarkin och returnerar den överordnade klassen utifrån den vanligare instanshierarkin. Ett anrop på exempelvis getQualifiedSuperclassName(String) returnerar Object även om String-klassobjektet tekniskt sett ärver från Class. Det betyder att resultaten är desamma oavsett om du använder en instans av en typ eller själva typen.

Parametrar

Relaterade API-element

Används för att beräkna relativ tid. För en Flash-miljö som bearbetar ActionScript 3.0 returnerar den här metoden det antal millisekunder som har förflutit sedan Flash-miljöns virtuella dator för ActionScript 3.0 (AVM2) startades. För en Flash-miljö som bearbetar ActionScript 2.0 returnerar den här metoden det antal millisekunder som har förflutit sedan Flash-miljön initierades. Flash-miljöer använder två virtuella datorer för att bearbeta ActionScript-kod. AVM1 är den virtuella ActionScript-dator som används för att köra ActionScript 1.0 och 2.0. AVM2 är den virtuella ActionScript-dator som används för att köra ActionScript 3.0. Metoden getTimer() fungerar på olika sätt för AVM1 och AVM2.

Avsnittet om Date-objektet innehåller mer information om kalenderdatum (tidsstämpel).

Relaterade API-element

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Kör en funktion med ett angivet intervall (i millisekunder).

I stället för att använda metoden setInterval() kan det vara bra att skapa ett Timer-objekt med det angivna intervallet och använda 0 som repeatCount-parameter (timern ställs in på att upprepas i all oändlighet).

Om du tänker använda metoden clearInterval() för att avbryta setInterval()-anropet bör du se till att koppla setInterval()-anropet till en variabel (som metoden clearInterval() senare refererar till). Om du inte anropar funktionen clearInterval() för att avbryta setInterval()-anropet skräpsamlas inte objektet som innehåller det tidsbestämda funktionsslutet.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Kör en angiven funktion efter en angiven fördröjning (i millisekunder).

I stället för att använda den här metoden kan det vara bra att skapa ett Timer-objekt med det angivna intervallet och använda 1 som repeatCount-parameter (timern ställs in på att bara köras en gång).

Om du tänker använda metoden clearTimeout() för att avbryta setTimeout()-anropet bör du se till att koppla setTimeout()-anropet till en variabel (som clearTimeout()-funktionen senare refererar till). Om du inte anropar funktionen clearTimeout() för att avbryta setTimeout()-anropet skräpsamlas inte objektet som innehåller det tidsbestämda funktionsslutet.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Returnerar en unescape-konverterad kopia av indatasträngen, som avkodas från antingen plattformens teckentabell eller UTF-8, beroende på värdet för System.useCodePage. Om System.useCodePage används kan miljön öppna äldre innehåll som är kodat med en lokal teckentabell, men bara på plattformar där den äldre teckentabellen används. Japanska data som kodats som Shift-JIS kan bara escape-konverteras och unescape-konverteras korrekt på ett operativsystem där japansk standardteckentabell används.

Parametrar