Geolocation

Paket	flash.sensors
Klass	public class Geolocation
Arv	Geolocation EventDispatcher Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

Klassen Geolocation skickar händelser som svar på enhetens platssensor.

Om en enhet har stöd för geolocation-funktionen kan du använda den här klassen för att hämta enhetens aktuella geografiska plats. Den geografiska platsen visas på enheten i latitud- och longitudkoordinater (i WGS-84-standardformat). När enhetens plats förändras kan du ta emot uppdateringar om ändringarna. Om enheten har stöd för den här funktionen kan du få information om höjd, precision, riktning, hastighet och tidsstämpel för den senaste förändringen på platsen.

Stöd för AIR-profiler: Den här funktionen stöds bara på mobilenheter. Den stöds inte på klientdatorer eller enheter med AIR for TV. Du kan testa stödet vid körning med egenskapen Geolocation.isSupported. På sidan om stöd för AIR-profiler hittar du mer information om API-stöd för flera profiler.

Obs: Kom ihåg att lägga till ett nyckelvärdepar i elementet infoAdditions i programmets xml-fil om du vill aktivera Geolocation i iOS. Se iOS-inställningar för mer information om elementet infoAdditions.

Visa exemplen

Lär dig mer

Cristophe Coenraets: Multi-User Google Maps Collaboration (Samarbete i Google Maps mellan flera användare)

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		isSupported : Boolean [statisk] [skrivskyddad] Om det finns en platssensor på enheten (true), i annat fall false.	Geolocation
		locationAlwaysUsePermission : Boolean Den här egenskapen avgör hur typen av åtkomstbehörighet används för geolokalisering.	Geolocation
		muted : Boolean [skrivskyddad] Anger om användaren har nekat åtkomst till geolocation (true) eller tillåtit åtkomst (false).	Geolocation
		permissionStatus : String [statisk] [skrivskyddad]	Geolocation

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		Geolocation() Skapar en ny Geolocation-instans.	Geolocation
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registrerar ett händelseavlyssnarobjekt för ett EventDispatcher-objekt så att avlyssnaren får meddelanden om händelser.	EventDispatcher
		dispatchEvent(event:Event):Boolean Skickar en händelse till händelseflödet.	EventDispatcher
		hasEventListener(type:String):Boolean Kontrollerar om EventDispatcher-objektet har några avlyssnare registrerade för en viss typ av händelse.	EventDispatcher
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Tar bort en avlyssnare från EventDispatcher-objektet.	EventDispatcher
		requestPermission():void	Geolocation
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		setRequestedUpdateInterval(interval:Number):void Används för att ange tidsintervall (i millisekunder) för uppdateringar.	Geolocation
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object
		willTrigger(type:String):Boolean Kontrollerar om en händelseavlyssnare är registrerad för det här EventDispatcher-objektet eller något av dess överordnade objekt för den angivna händelsetypen.	EventDispatcher

Händelser

Klicka för mer information om händelser

Dölj ärvda händelser

Visa ärvda händelser

	Sammanfattning	Definieras med
activate	[utsändningshändelse] Skickas när Flash Player eller AIR får operativsystemfokus och blir aktivt.	EventDispatcher
deactivate	[utsändningshändelse] Skickas när Flash Player eller AIR förlorar operativsystemfokus och blir inaktivt.	EventDispatcher
permissionStatus		Geolocation
status	Geolocation-objektet skickar statushändelser när användaren ändrar åtkomst till platssensorn.	Geolocation
update	Uppdateringshändelsen skickas som svar på uppdateringar från platssensorn.	Geolocation

Egenskapsdetaljer

isSupported

egenskap

isSupported:Boolean [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

Om det finns en platssensor på enheten (true), i annat fall false.

Implementering
public static function get isSupported():Boolean

locationAlwaysUsePermission

egenskap

locationAlwaysUsePermission:Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 29

Den här egenskapen avgör hur typen av åtkomstbehörighet används för geolokalisering. Behörighetstypen kan vara Alltid eller När den används. Om egenskapen ställs in på false, begärs behörigheten När den används, annars begärs behörigheten Alltid. Ställ in egenskapen innan du anropar requestPermission(). Standardvärdet för --egenskapen är false.

Implementering
public function get locationAlwaysUsePermission():Boolean
public function set locationAlwaysUsePermission(value:Boolean):void

muted

egenskap

muted:Boolean [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Anger om användaren har nekat åtkomst till geolocation (true) eller tillåtit åtkomst (false). Om det här värdet ändras skickas en status-händelse.

Implementering
public function get muted():Boolean

Relaterade API-element

status

permissionStatus

egenskap

permissionStatus:String [skrivskyddad]

Implementering
public static function get permissionStatus():String

Konstruktordetaljer

()

Konstruktor

public function Geolocation()

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

Skapar en ny Geolocation-instans.

Metoddetaljer

requestPermission

()

metod

public function requestPermission():void

setRequestedUpdateInterval

()

metod

public function setRequestedUpdateInterval(interval:Number):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

Används för att ange tidsintervall (i millisekunder) för uppdateringar. Uppdateringsintervallet används bara som ett tips för att spara på batteriet. Den faktiska tiden mellan platsuppdateringar kan vara längre eller kortare än det här värdet. Alla förändringar av uppdateringsintervallet som utförs med den här metoden påverkar alla registrerade update-händelseavlyssnare. Klassen Geolocation kan användas utan att metoden setRequestedUpdateInterval behöver anropas. I det här fallet returnerar plattformen uppdateringar baserat på dess standardintervall.

Obs! Första generationens iPhone, de som inte har någon GPS-enhet, skickar endast sporadiskt update-händelser. På dessa enheter skickar ett Geolocation-objekt initialt en eller två update-händelser. Därefter skickas update-händelser när märkbara informationsändringar sker.

Parametrar

interval:Number — begärt uppdateringsintervall. Om interval <= 0 har anrop till den här metoden ingen effekt.

Utlöser

ArgumentError — Angivet interval är mindre än noll.

Händelsedetaljer

permissionStatus

Händelse

Typ av händelseobjekt: flash.events.PermissionEvent

status

Händelse

Typ av händelseobjekt: flash.events.StatusEvent
egenskap StatusEvent.type = flash.events.StatusEvent.STATUS

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

Objektet Geolocation skickar status-händelser när användaren ändrar åtkomst till platssensorn. Om användaren t.ex. förhindrar programmet från att hämta platsdata som svar på en enhetsprompt, skickar Geolocation-objektet en status-händelse. När statusen ändras till ett läge där platssensorn inte är tillgänglig ställs egenskapen muted för Geolocation-instansen in på true.

Definierar värdet för ett status-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Egenskap	Värde
`bubbles`	`false`
`cancelable`	`false`; det finns inget standardbeteende att avbryta.
`kod`	En beskrivning av objektets status.
`currentTarget`	Det objekt som aktivt behandlar Event-objektet med en händelseavlyssnare.
`nivå`	Meddelandets kategori, till exempel `"status"`, `"warning"` eller `"error"`.
`target`	Objektet rapporterar status.

Relaterade API-element

muted

update

Händelse

Typ av händelseobjekt: flash.events.GeolocationEvent
egenskap GeolocationEvent.type = flash.events.GeolocationEvent.UPDATE

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2, Flash Lite 4

update-händelsen skickas som svar på uppdateringar från platssensorn. Händelsen skickas under följande förhållanden:

När en ny avlyssnarfunktion kopplas via addEventListener() levereras den här händelsen en gång till alla registrerade avlyssnare med det aktuella värdet för platsen. Obs! AIR skickar den första händelsen omedelbart om enheten har en senast känd plats. Koden måste ta hänsyn till att den initialt skickade händelsen kanske inte innehåller den aktuella platsen.
Så fort någon platsuppdatering tas emot från plattformen med de intervall som enheten anger.
När programmet missar en förändring av platsen (till exempel om programmet aktiveras igen efter inaktivitet).

Definierar värdet på type-egenskapen i ett GeolocationEvent-händelseobjekt.

Den här händelsen har följande egenskaper:

Egenskap	Värde
`bubbles`	`false`
`cancelable`	`false`; det finns inget standardbeteende att avbryta.
`currentTarget`	Det objekt som aktivt behandlar event-objektet med en händelseavlyssnare.
`target`	Geolocation-objektet som tar emot data.

Exempel Så här använder du exemplet

GeolocationExample.as

I följande exempel visar programmet latitud, longitud och vågrät precision för update-händelser för geolocation efterhand som de tas emot.

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.GeolocationEvent;
    import flash.events.MouseEvent;
    import flash.events.StatusEvent;
    import flash.sensors.Geolocation;
    import flash.text.TextField;
    import flash.text.TextFormat;
    
    public class GeolocationTest extends Sprite
    {
        
        private var geo:Geolocation; 
        private var log:TextField;
        
        public function GeolocationTest()
        {            
            super();
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            setUpTextField();
            
            if (Geolocation.isSupported) 
            { 
                geo = new Geolocation(); 
                if (!geo.muted) 
                { 
                    geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler); 
                } 
                geo.addEventListener(StatusEvent.STATUS, geoStatusHandler);
            } 
            else 
            { 
                log.text = "Geolocation not supported"; 
            } 
        }
        
        public function geoUpdateHandler(event:GeolocationEvent):void 
        { 
            log.text = "latitude : " + event.latitude.toString() + "\n"; 
            log.appendText("longitude : " + event.longitude.toString() + "\n");
        } 
        
        public function geoStatusHandler(event:StatusEvent):void 
        { 
            if (geo.muted)
                geo.removeEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
            else
                geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
        }
        
        private function setUpTextField():void
        {
            log = new TextField();
            var format:TextFormat = new TextFormat("_sans", 24);
            log.defaultTextFormat = format;
            log.border = true;
            log.wordWrap = true;
            log.multiline = true;
            log.x = 10;
            log.y = 10;
            log.height = stage.stageHeight - 20;
            log.width = stage.stageWidth - 20;
            log.addEventListener(MouseEvent.CLICK, clearLog);
            addChild(log);
        }
        private function clearLog(event:MouseEvent):void
        {
            log.text = "";
        }
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

Geolocation - AS3

Klasser x

isSupported

locationAlwaysUsePermission

muted

permissionStatus

Geolocation

requestPermission

setRequestedUpdateInterval

permissionStatus

status

update