MouseEvent  - AS3

Anger om Alt-tangenten är aktiv (true) eller inaktiv (false). Stöds endast för Windows. I andra operativsystem är den här egenskapen alltid false.

Anger om den primära musknappen är nedtryckt (true) eller inte (false).

Anger om mus ned-händelsen är en del i sekvensen med flera klick. Den här parametern är noll för alla mushändelser utom MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown och MouseEvent.rightMouseUp. Att avlyssna enkelklick, dubbelklick eller sekvenser av flera klick är möjligt med clickCount-parametern. Den första MouseEvent.mouseDown och MouseEvent.mouseUp har till exempel en clickCount på 1 och den andra MouseEvent.mouseDown och MouseEvent.mouseUp har en clickCount på 2 i en dubbelklick-sekvens. Om musen rörs tillräckligt mycket eller om sekvensen med flera klick avbryts av någon anledning, kommer nästa MouseEvent.mouseDown att ha en clickCount på 1. DoubleClick-händelsen kommer att fortsätta som förväntat.

Anger om kommandotangenten är aktiverad (endast Macintosh.)

Värdet på egenskapen commandKey kommer att ha samma värde som egenskapen ctrlKey i Macintosh. Alltid false i Windows och Linux.

Anger om Ctrl-tangenten är aktiv i Macintosh, Windows eller Linux.

Anger om Ctrl-tangenten är aktiv (true) eller inaktiv (false) i Windows eller Linux. Anger om Ctrl-tangenten eller Kommando-tangenten är aktiv i Macintosh.

Anger hur många rader fönstret ska rullas för varje enhet användaren vrider mushjulet. Ett positivt delta-värde innebär rullning uppåt. Ett negativt värde innebär rullning nedåt. Vanliga värden är från 1 till 3. Snabbare rotation kan ge högre värden. Den här inställningen beror på vilken enhet och vilket operativsystem du använder. Den kan oftast konfigureras av användaren själv. Den här egenskapen gäller bara MouseEvent.mouseWheel-händelser.

Om true, är egenskapen relatedObject satt till null av orsaker som är relaterade till säkerhetssandlådor. Om det nominella värdet för relatedObject är en referens till ett DisplayObject i en annan sandlåda, är relatedObject satt till null om det inte finns behörighet i båda riktningar över den här sandlådegränsen. Behörighet etableras genom att anropa Security.allowDomain() från en SWF-fil, eller genom att tillhandahålla en principfil för en server för en bildfil och ställa in egenskapen LoaderContext.checkPolicyFile under inläsning av bilden.

Relaterade API-element

Den vågräta koordinat som händelsen inträffade vid i förhållande till behållar-spriten, om låsning av musen är inaktiverat. Inaktivera låsning av musen genom att ange Stage.mouseLock som false.

Om låsning av musen är aktiverat är localX och localY lika med 0. Använd movementX och movementY för att fastställa förändringar av musens position när låsning av musen är aktiverat.

Relaterade API-element

Den lodräta koordinat som händelsen inträffade vid i förhållande till behållar-spriten, om låsning av musen är inaktiverat. Inaktivera låsning av musen genom att ange Stage.mouseLock som false.

Om låsning av musen är aktiverat är localX och localY lika med 0. Använd movementX och movementY för att fastställa förändringar av musens position när låsning av musen är aktiverat.

Relaterade API-element

Förändringen av musens position i X-riktning sedan den senaste mushändelsen, om låsning av musen är aktiverat. Aktivera låsning av musen genom att ange Stage.mouseLock som true.

När låsning av musen är aktiverat:

• innehåller localX och localY 0.
• innehåller movementX och movementY deltavärden.
• omformas movementX och movementY aldrig baserat på scenens omformning. Det innebär att de alltid anges i skärmkoordinater.

är movementX och movementY lika med 0 när Stage.mouseLock är false.

Relaterade API-element

Förändringen av musens position i Y-riktning sedan den senaste mushändelsen, om låsning av musen är aktiverat. Aktivera låsning av musen genom att ange Stage.mouseLock som true.

När låsning av musen är aktiverat:

• innehåller localX och localY 0.
• innehåller movementX och movementY deltavärden.
• omformas movementX och movementY aldrig baserat på scenens omformning. Det innebär att de alltid anges i skärmkoordinater.

är movementX och movementY lika med 0 när Stage.mouseLock är false.

Relaterade API-element

En referens till ett visningslisteobjekt som är relaterat till händelsen. När exempelvis en mouseOut-händelse inträffar motsvarar relatedObject det objekt i visningslistan som pekaren pekar på. Egenskapen gäller för mouseOut-, mouseOver-, rollOut- och rollOver-händelserna.

Värdet för den här egenskapen kan vara null under två förhållanden: om det inte finns något relaterat objekt, eller om det finns ett relaterat objekt, men i en säkerhetssandlåda som du inte har tillgång till. Använd egenskapen isRelatedObjectInaccessible() för att avgöra vilken av dessa orsaker det är som gäller.

Relaterade API-element

Anger om skifttangenten är aktiv (true) eller inaktiv (false).

Den vågräta koordinat som händelsen inträffade vid i globala scenkoordinater. Den här egenskapen beräknas när egenskapen för localX har ställts in.

Den lodräta koordinat som händelsen inträffade vid i globala scenkoordinater. Den här egenskapen beräknas när egenskapen för localY har ställts in.

Skapar ett nytt Event-objekt som innehåller information om mushändelser. Event-objekt skickas som parametrar till händelseavlyssnare.

Skapar en kopia av MouseEvent-objektet och ställer in värdet för alla egenskaper så att de matchar originalets egenskaper.

Returnerar en sträng som innehåller alla egenskaper i MouseEvent-objektet. Strängen är i följande format:

[MouseEvent type=värde bubbles=värde cancelable=värde ... delta=värde ]

Instruerar Flash Player eller Adobe AIR att göra en rendering när den här händelsen har behandlats, om visningslistan har ändrats.

Definierar värdet för ett click-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

MouseEvent.CONTEXT_MENU-konstanten definierar värdet på type-egenskapen i ett contextMenu-händelseobjekt.

Den här händelsen har följande egenskaper:

Definierar värdet för ett doubleClick-händelseobjekts type-egenskap. Egenskapen doubleClickEnabled måste vara true för att objektet ska skapa doubleClick-händelsen.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett middleClick-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett middleMouseDown-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett middleMouseUp-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseDown-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseMov-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Definierar värdet för ett mouseOut-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseOver-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseUp-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseWheel-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett releaseOutside-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i rightClick-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett rightMouseDown-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett rightMouseUp-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett rollOut-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett rollOver-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

1. Exemplet deklarerar egenskaper för storlek (100 × 100 pixlar) och bakgrundsfärg (orange) för senare användning när fyrkanten ska ritas.
2. Konstruktorn skapar ett nytt ChildSprite child-objekt. Dess konstruktor ritar först en orange fyrkant med 100 × 100 pixlar med koordinaterna (0,0) genom att anropa dess draw()-metod. Den lägger sedan till sju händelseavlyssnare/mottagare.
   • click/clickHandler(): Skickas när användaren klickar en gång med vänster musknapp på fyrkanten.
   • doubleClick/doubleClickHandler(): Skickas när användaren dubbelklickar med vänster musknapp på fyrkanten.
   • mouseDown/mouseDownHandler(): När användaren klickar på ChildSprite-objektet (den orangea fyrkanten) skrivs ett trace()-meddelande till skärmen och sedan anropas ChildSprite.draw(). Då ritas en mörkgul fyrkant istället för den ljusblåa som ritats i mouseOverHandler(). Med mouseDownHandler()-metod läggs också en mouseMove-händelseavlyssnare till och en mouseMoveHandler()-mottagare (beskrivs nedan) som behandlar musrörelserna. startDrag()-metoden anropas så att Sprite-objektet kan dras.
   • mouseOut/mouseOutHandler(): Skickas varje gång pekaren lämnar fyrkantsområdet. draw()-metoden anropas så att fyrkanten återgår till vanlig storlek och färg.
   • mouseOver/mouseOverHandler(): Skickas när muspekaren är över fyrkanten. Med den här metoden ritas fyrkanten om så att den blir större och bakgrundsfärgen blir mörkgul.
   • mouseUp/mouseUpHandler(): När användaren släpper musknappen tas mouseMove-händelseavlyssnaren bort och stopDrag anropas. Därmed frysas fyrkanten.
   • mouseMove/mouseMoveHandler(): Anropas som en del av mouseDownHandler()-funktionen och skickas när användaren trycker ned den vänstra musknappen och drar fyrkanten.
   • mouseWheel/mouseWheelHandler(): Skickas när användaren roterar mushjulet över fyrkanten.
3. En ChildSprite child-instans läggs sedan till i visningslistan med hjälp av addChild(), och den orange fyrkanten ritas omedelbart.

Anteckningar:

• Klassen MouseEventExample ska vara dokumentrot.
• Några av de händelsemetoder som är listade ovan deklarerar sprite som en lokal variabel, som tilldelas datatypsbyte för event.target till typen Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}