RadioButtonGroup

Paket	fl.controls
Klass	public class RadioButtonGroup
Arv	RadioButtonGroup EventDispatcher Object

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

RadioButtonGroup-klassen definierar en grupp med RadioButton-komponenter som ska fungera som en enda komponent. När en alternativknapp har aktiverats kan inga andra alternativknappar från samma grupp aktiveras.

Visa exemplen

Relaterade API-element

RadioButton
RadioButton.group

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		name : String [skrivskyddad] Hämtar instansnamnet för alternativknappen.	RadioButtonGroup
		numRadioButtons : int [skrivskyddad] Hämtar antalet alternativknappar i den här alternativknappsgruppen.	RadioButtonGroup
		selectedData : Object Hämtar eller ställer in den aktiverade alternativknappens value-egenskap.	RadioButtonGroup
		selection : RadioButton Hämtar eller ställer in en referens till den alternativknapp som för tillfället är markerad i alternativknappsgruppen.	RadioButtonGroup

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		RadioButtonGroup(name:String) Skapar en ny RadioButtonGroup-instans.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registrerar ett händelseavlyssnarobjekt för ett EventDispatcher-objekt så att avlyssnaren får meddelanden om händelser.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Lägger till en alternativknapp i den interna alternativknappsarrayen som kan användas med alternativknappsgruppindex, vilket innebär att du kan markera en enda alternativknapp i en grupp med alternativknappar.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Skickar en händelse till händelseflödet.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statisk] Hämtar en referens till den angivna alternativknappsgruppen.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Hämtar RadioButton-komponenten vid den angivna indexplatsen.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Returnerar indexvärdet för den angivna RadioButton-instansen.	RadioButtonGroup
		hasEventListener(type:String):Boolean Kontrollerar om EventDispatcher-objektet har några avlyssnare registrerade för en viss typ av händelse.	EventDispatcher
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Tar bort en avlyssnare från EventDispatcher-objektet.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Tar bort RadioButton-instansen från den interna alternativknappslistan.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object
		willTrigger(type:String):Boolean Kontrollerar om en händelseavlyssnare är registrerad för det här EventDispatcher-objektet eller något av dess överordnade objekt för den angivna händelsetypen.	EventDispatcher

Händelser

Klicka för mer information om händelser

Dölj ärvda händelser

Visa ärvda händelser

	Sammanfattning	Definieras med
activate	[utsändningshändelse] Skickas när Flash Player eller AIR får operativsystemfokus och blir aktivt.	EventDispatcher
change	Skickas när den markerade RadioButton-instansen i en grupp ändras.	RadioButtonGroup
click	Skickas när du klickar på en RadioButton-instans.	RadioButtonGroup
deactivate	[utsändningshändelse] Skickas när Flash Player eller AIR förlorar operativsystemfokus och blir inaktivt.	EventDispatcher

Egenskapsdetaljer

name

egenskap

name:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar instansnamnet för alternativknappen.

Standardvärdet är "RadioButtonGroup".

Implementering
public function get name():String

numRadioButtons

egenskap

numRadioButtons:int [skrivskyddad]

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar antalet alternativknappar i den här alternativknappsgruppen.

Standardvärdet är 0.

Implementering
public function get numRadioButtons():int

selectedData

egenskap

selectedData:Object

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar eller ställer in den aktiverade alternativknappens value-egenskap. Om ingen alternativknapp är aktiverad är den här egenskapen null.

Implementering
public function get selectedData():Object
public function set selectedData(value:Object):void

Exempel ( Så här använder du exemplet )

I följande exempel skapas en ny RadioButtonGroup och dess change-händelse avlyssnas:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

egenskap

selection:RadioButton

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar eller ställer in en referens till den alternativknapp som för tillfället är markerad i alternativknappsgruppen.

Implementering
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Exempel ( Så här använder du exemplet )

I följande exempel skapas en ny alternativknappsgrupp som innehåller två alternativknappar. Om den alternativknapp som är markerad för tillfället ändras spåras den markerade alternativknappens etikett och värde:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Konstruktordetaljer

()

Konstruktor

public function RadioButtonGroup(name:String)

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Skapar en ny RadioButtonGroup-instans. Detta görs oftast automatiskt när en alternativknapp instansieras.

Parametrar

name:String — Namnet på alternativknappsgruppen.

Metoddetaljer

addRadioButton

()

metod

public function addRadioButton(radioButton:RadioButton):void

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Lägger till en alternativknapp i den interna alternativknappsarrayen som kan användas med alternativknappsgruppindex, vilket innebär att du kan markera en enda alternativknapp i en grupp med alternativknappar. Den här metoden används automatiskt av alternativknappar, men kan även användas manuellt för att explicit lägga till en alternativknapp i en grupp.

Parametrar

radioButton:RadioButton — RadioButton-instansen som ska läggas till i den aktuella alternativknappsgruppen.

getGroup

()

metod

public static function getGroup(name:String):RadioButtonGroup

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar en referens till den angivna alternativknappsgruppen.

Parametrar

name:String — Namnet på gruppen för vilken en referens ska hämtas.

Returnerar

RadioButtonGroup — En referens till den angivna RadioButtonGroup.

Exempel ( Så här använder du exemplet )

I följande exempel visas hur du bestämmer vilken alternativknapp i en grupp som ska markeras:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

metod

public function getRadioButtonAt(index:int):RadioButton

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Hämtar RadioButton-komponenten vid den angivna indexplatsen.

Parametrar

index:int — Indexvärde för RadioButton-komponenten i RadioButtonGroup-komponenten där indexvärdet för den första komponenten är 0.

Returnerar

RadioButton — Den angivna RadioButton-komponenten.

Utlöser

RangeError — Om angivet indexvärde är mindre än 0 eller om indexvärdet är större än eller lika med längden för DataProvider.

getRadioButtonIndex

()

metod

public function getRadioButtonIndex(radioButton:RadioButton):int

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Returnerar indexvärdet för den angivna RadioButton-instansen.

Parametrar

radioButton:RadioButton — RadioButton-instansen som används för att hitta i aktuell RadioButtonGroup.

Returnerar

int — Indexvärde för angiven RadioButton-komponent, eller -1 om det inte går att hitta angiven RadioButton.

removeRadioButton

()

metod

public function removeRadioButton(radioButton:RadioButton):void

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Tar bort RadioButton-instansen från den interna alternativknappslistan.

Parametrar

radioButton:RadioButton — RadioButton-instansen som ska tas bort.

Händelsedetaljer

change

Händelse

Typ av händelseobjekt: flash.events.Event
egenskap Event.type = flash.events.Event.CHANGE

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Skickas när den markerade RadioButton-instansen i en grupp ändras.

Event.CHANGE-konstanten definierar värdet på type-egenskapen i ett change-händelseobjekt.

Den här händelsen har följande egenskaper:

Egenskap	Värde
`bubbles`	`true`
`cancelable`	`false`; det finns inget standardbeteende att avbryta.
`currentTarget`	Det objekt som aktivt behandlar Event-objektet med en händelseavlyssnare.
`target`	Objektet vars värde har modifierats. `target` är inte alltid det objekt i visningslistan som har registrerat händelseavlyssnaren. Använd egenskapen `currentTarget` om du vill komma åt det objekt i visningslistan som bearbetar händelsen.

Exempel ( Så här använder du exemplet )

I följande exempel skapas tre alternativknappar och en händelseavlyssnare läggs till för en alternativknappsgrupps change-händelse:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Händelse

Typ av händelseobjekt: flash.events.MouseEvent
egenskap MouseEvent.type = flash.events.MouseEvent.CLICK

Språkversion:

ActionScript 3.0

Produktversion:

Flash CS3

Körningsmiljöversioner:

Flash Player 9.0.28.0, AIR 1.0

Skickas när du klickar på en RadioButton-instans.

Definierar värdet för ett click-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Egenskap	Värde
`altKey`	`true` om Alt-tangenten är aktiv (Windows).
`bubbles`	`true`
`buttonDown`	För click-händelser är det här värdet alltid `false`.
`cancelable`	`false`; det finns inget standardbeteende att avbryta.
`commandKey`	`true` om Kommando-tangenten är aktiv i Mac och `false` om den är inaktiv. Alltid `false` i Windows.
`controlKey`	`true` om Ctrl-tangenten är aktiv och `false` om den är inaktiv.
`ctrlKey`	`true` i Windows eller Linux om Ctrl-tangenten är aktiv. `true` om antingen Ctrl-tangenten eller Kommando-tangenten är aktiv i Macintosh. Annars `false`.
`currentTarget`	Det objekt som aktivt behandlar Event-objektet med en händelseavlyssnare.
`localX`	Den vågräta koordinat som händelsen inträffade vid i förhållande till behållar-spriten, om låsning av musen är inaktiverat.
`localY`	Den lodräta koordinat som händelsen inträffade vid i förhållande till behållar-spriten, om låsning av musen är inaktiverat.
`movementX`	Förändringen av de vågräta koordinaterna för musens position sedan den senaste mushändelsen, om låsning av musen är aktiverat.
`movementY`	Förändringen av de lodräta koordinaterna för musens position sedan den senaste mushändelsen, om låsning av musen är aktiverat.
`shiftKey`	`true` om skifttangenten är aktiverad eller `false` om den är inaktiverad.
`stageX`	Den vågräta koordinat som händelsen inträffade vid i globala scenkoordinater.
`stageY`	Den lodräta koordinat som händelsen inträffade vid i globala scenkoordinater.
`target`	InteractiveObject-instansen under pekdonet. `target` är inte alltid det objekt i visningslistan som har registrerat händelseavlyssnaren. Använd egenskapen `currentTarget` om du vill komma åt det objekt i visningslistan som bearbetar händelsen.

Exempel Så här använder du exemplet

RadioButtonGroupExample.as

I det här exemplet visas hur du hanterar många RadioButton-objekt i flera grupper

Lägg till RadioButton- och Label-komponenterna i ditt bibliotek.
Spara koden som RadioButtonGroupExample.as i samma katalog som din FLA-fil.
Ställ in RadioButtonGroupExample som DocumentClass i FLA-filen.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

RadioButtonGroup - AS3 Flash

Klasser x

name

numRadioButtons

selectedData

selection