ContextMenu  - AS3

Экземпляр класса ContextMenuBuiltInItems со следующими свойствами: forwardAndBack, loop, play, print, quality, rewind, save и zoom. Если этим свойствам задано значение false, из объекта ContextMenu удаляются соответствующие элементы меню. Это перечисляемые свойства, которым по умолчанию задается значение true.

Примечание. В AIR контекстные меню не имеют встроенных пунктов.

Связанные элементы API

Экземпляр класса ContextMenuClipboardItems со следующими свойствами: cut, copy, paste, delete, selectAll. Если задать одному из этих свойств значение false, отключается соответствующий пункт в меню буфера обмена.

Связанные элементы API

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Определяет, должно ли использоваться меню буфера обмена. При значении true свойство clipboardItems будет определять, какие пункты меню буфера обмена будут включены, а какие — нет.

Если link имеет значение, отличное от null, свойство clipBoardMenu игнорируется.

Массив объектов ContextMenuItem. Каждый объект в массиве представляет определенный вами элемент контекстного меню. С помощью данного свойства можно добавлять, удалять или модифицировать эти пользовательские элементы меню.

Чтобы добавить новые элементы меню, нужно создать объект ContextMenuItem и затем добавить его в массив customItems (например, с помощью метода Array.push()). Дополнительные сведения о создании элементов меню см. в описании класса ContextMenuItem.

Связанные элементы API

Свойству isSupported задается значение true, если текущая платформа поддерживает класс ContextMenu, в противном случае задается значение false.

Массив пользовательских пунктов данного меню.

Использование этого свойства равнозначно использованию свойства customItems. Массив сортируется в порядке отображения.

Объект URLRequest ссылки. Если это свойство имеет значение null, отображается обычное контекстное меню. Если это свойство имеет значение, отличное от null, отображается контекстное меню ссылки для указанного URL-адреса.

Если задано свойство link, свойство clipboardMenu игнорируется.

По умолчанию используется null.

Количество пунктов в данном меню.

Создает объект ContextMenu.

Связанные элементы API

Добавляет элемент в конец меню.

При создании контекстного меню можно добавлять объекты NativeMenuItem или ContextMenuItem. Однако рекомендуется использовать только один тип объектов в контекстном меню, чтобы все элементы меню имели одинаковые свойства.

Параметры

Создает копию указанного объекта ContextMenu. Копия наследует все свойства исходного объекта меню.

Сообщает, содержит ли меню указанный элемент.

Параметры

Добавляет раскрывающееся меню в заданном положении.

Примечание. В Flash Player этот метод не поддерживается.

Параметры

Определяет элемент меню, расположенный по заданному индексу.

Параметры

Определяет положение заданного элемента.

Параметры

Скрывает все встроенные элементы меню (кроме пункта меню «Параметры») в заданном объекте ContextMenu. Если работает отладочная версия проигрывателя Flash Player, отображается элемент меню «Отладка», даже если он неактивен для SWF-файлов с выключенной функцией удаленной отладки.

Этот метод использует только те элементы, которые появляются в стандартном меню, он не затрагивает элементы в меню правки или ошибки.

Этот метод работает, задавая всем логическим элементам в my_cm.builtInItems значение false. Можно сделать встроенный элемент меню видимым в выборочном порядке, задав для соответствующего ему элемента в my_cm.builtInItems значение true.

Примечание. В AIR контекстные меню не имеют встроенных пунктов. Вызов этого метода не будет работать.

Связанные элементы API

Удаляет все пункты меню.

Удаляет и возвращает элемент меню в заданный индекс.

Параметры

Отправляется после создания пользователем контекстного меню, но перед отображением содержимого этого меню. Это позволяет программе модифицировать набор элементов контекстного меню перед его отображением. Пользователь создает контекстное меню щелчком правой кнопки указывающего устройства.

Это событие имеет следующие свойства:

1. Объявляются свойства myContextMenu (которое затем назначается новому объекту ContextMenu) и redRectangle (типа Sprite).
2. Вызывается метод removeDefaultItems(), который удаляет все встроенные элементы контекстного меню, кроме «Печать».
3. Вызывается метод addCustomMenuItems(), который помещает элемент меню Red to Black в массив defaultItems с помощью метода push() объекта Array. Для объекта ContextMenuItem добавляется прослушиватель событий menuItemSelect и вызывается соответствующий метод menuItemSelectHandler(). Этот метод печатает строки с помощью метода trace() при вызове контекстного меню и выборе элемента Red to Black. Кроме того, красный квадрат удаляется и заменяется черным.
4. Добавляются прослушиватель событий menuSelect и связанный с ним метод menuSelectHandler, который при каждом выборе элемента контекстного меню просто печатает три статуса с помощью метода trace().
5. Затем метод addChildren() рисует красный квадрат и добавляет его в список отображения, после чего он сразу появляется на экране.
6. В завершение, myContextMenu назначается контекстному меню спрайта redRectangle, чтобы пользовательское контекстное меню отображалось, только когда указатель мыши находится над квадратом.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}