DisplacementMapFilter  - AS3

Задает значение альфа-прозрачности, применяемое для замещения «вне пределов». Указывается в виде нормализованного значения от 0,0 до 1,0. Например, при 0,25 устанавливается 25-процентная прозрачность. Значением по умолчанию является 0. Это свойство используется, если свойство mode принимает значение DisplacementMapFilterMode.COLOR.

Задает цвет, используемый при смещениях, выходящих за пределы границ. Допустимый диапазон смещений – от 0,0 до 1,0. Значения приводятся в шестнадцатеричном формате. Значение color по умолчанию равно 0. Это свойство используется, если свойство mode принимает значение DisplacementMapFilterMode.COLOR.

Указывает цветовой канал, который следует использовать в изображении карты для замещения результата x. Возможные значения являются константами BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Связанные элементы API

Указывает цветовой канал, который следует использовать в изображении схемы для замещения результата y. Возможные значения являются константами BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Связанные элементы API

Объект BitmapData, содержащий данные карты замещения.

Связанные элементы API

Значение, содержащее смещение левого верхнего угла целевого экранного объекта из левого верхнего угла изображения карты.

Связанные элементы API

Режим для фильтра. Возможные значения являются константами DisplacementMapFilterMode:

• DisplacementMapFilterMode.WRAP — переносит значение замещения на другую сторону исходного изображения.
• DisplacementMapFilterMode.CLAMP — фиксирует значение замещения по краю исходного изображения.
• DisplacementMapFilterMode.IGNORE — если значение замещения находится вне диапазона, игнорирует замещение и использует исходный пиксель.
• DisplacementMapFilterMode.COLOR — если значение замещения находится вне изображения, заменяет значения свойств color и alpha.

Связанные элементы API

Множитель, с помощью которого масштабируется результат замещения x, полученного в ходе вычисления схемы.

Множитель, с помощью которого масштабируется результат y замещения, полученного в ходе вычисления карты.

Инициализирует экземпляр DisplacementMapFilter с заданными параметрами.

Связанные элементы API

Возвращает копию данного объекта фильтра.

1. Класс определяет переменные цвета фона, отметки текстового поля, размера и смещения, которые будут использоваться в различных функциях.
2. Функция конструктора вызывает метод draw(), использующий класс Graphics для отрисовки квадрата с радиальной градиентной заливкой. Следует помнить, что graphics — это свойство объекта DisplacementMapFilterExample, являющегося расширением класса Sprite.
3. Функция конструктора вызывает метод createLabel(), который создает текстовое поле со значением labelText и добавляет его к списку отображения.
4. Функция конструктора вызывает метод createFilter(), который выполняет следующие действия:
   • Создает переменную с именем filter для объекта filter.
   • Вызывает метод getDisplacementMapFilter() и назначает возвращаемое им значение переменной filter.
   • Передает filter свойству filters объекта DisplacementFilterExample (основной класс).
5. Метод getBitmapFilter() создает объект BitmapData с именем mapBitmap и назначает его результатам метода createBitmapData(). Объект mapBitmap, как и другие переменные, определяет новый фильтр смещения изображения карты.
6. Метод createBitmapData() создает новый объект BitmapData, основанный на текущем содержимом объекта DisplacementMapFilterExample. Он создает новое растровое изображение на основе bitmapData и добавляет его к сцене.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}