MouseEvent  - AS3

Показывает активность клавиши Alt: true — активна, false — неактивна. Поддерживается только для ОС Windows. В других операционных системах это свойство всегда имеет значение false.

Показывает, нажата ли основная кнопка мыши: true — да, false — нет.

Указывает на то, является ли событие для нажатого положения мыши частью последовательности нажатий мышью. Этот параметр будет нулевым для всех событий мыши, кроме MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown и MouseEvent.rightMouseUp. С помощью параметра clickCount можно прослушивать единичные, двойные и множественные нажатия мышью. Например, для первоначального события MouseEvent.mouseDown и MouseEvent.mouseUp свойство clickCount будет иметь значение 1, а для второго события MouseEvent.mouseDown и MouseEvent.mouseUp в последовательности двойного нажатия свойство clickCount будет иметь значение 2. При значительном движении мыши или если последовательность множественных нажатий мышью прервана по каким-либо причинам, следующее событие MouseEvent.mouseDown будет иметь значение свойства clickCount равное 1. Событие doubleClick будет отправляться, как обычно.

Указывает, активирована ли клавиша Command (только для Mac).

Свойство commandKey будет иметь то же значение, что и свойство ctrlKey в Mac. Всегда значение false в Windows или Linux.

Указывает, активирована ли клавиша Control в Mac или клавиша Ctrl в Windows или Linux.

В Windows или Linux указывает на то, активирована ли клавиша Ctrl (true) или нет (false). В Macintosh указывает на то, активирована ли клавиша Control или Command.

Указывает количество строк, подлежащих прокрутке в каждом случае вращения пользователем колесика мыши. Положительное значение delta показывает прокручивание вверх, отрицательное значение показывает прокрутку вниз. Как правило, используются значения в пределах 1-3, но при более быстром прокручивании это число увеличивается. Этот параметр зависит от устройства и операционной системы, как правило, его может настраивать пользователь. Это свойство применяется только к событию MouseEvent.mouseWheel.

Если принимает значение true, свойство relatedObject принимает значение null по причинам, связанным с изолированными средами безопасности. Если номинальным значением свойства relatedObject является ссылка на объект DisplayObject в другой изолированной среде, свойство relatedObject принимает значение null, пока не будут заданы двусторонние права в границах данной изолированной среды. Права задаются путем вызова метода Security.allowDomain() из SWF-файла или указания файла политик на сервере файла изображений и задания свойства LoaderContext.checkPolicyFile при загрузке изображения.

Связанные элементы API

Если блокировка мыши отключена, горизонтальная координата, в которой произошло событие, относительно контейнера-спрайта. Отключите блокировку мыши, установив для Stage.mouseLock значение false.

Если блокировка мыши включена, localX и localY равны 0. Используйте movementX и movementY, чтобы определить изменение положения мыши, когда блокировка мыши включена.

Связанные элементы API

Если блокировка мыши отключена, вертикальная координата, в которой произошло событие, относительно контейнера-спрайта. Отключите блокировку мыши, установив для Stage.mouseLock значение false.

Если блокировка мыши включена, localX и localY равны 0. Используйте movementX и movementY, чтобы определить изменение положения мыши, когда блокировка мыши включена.

Связанные элементы API

Когда блокировка мыши включена, изменение положения мыши в направлении X с последнего события мыши. Включите блокировку мыши, установив для Stage.mouseLock значение true.

Когда блокировка мыши включена:

• localX и localY содержат 0.
• movementX и movementY содержат значения дельты.
• movementX и movementY никогда не преобразовываются на основании преобразований рабочей области. Это означает, что они всегда остаются в экранных координатах.

movementX и movementY равны 0, когда для Stage.mouseLock установлено значение false.

Связанные элементы API

Когда блокировка мыши включена, изменение положения мыши в направлении Y с последнего события мыши. Включите блокировку мыши, установив для Stage.mouseLock значение true.

Когда блокировка мыши включена:

• localX и localY содержат 0.
• movementX и movementY содержат значения дельты.
• movementX и movementY никогда не преобразовываются на основании преобразований рабочей области. Это означает, что они всегда остаются в экранных координатах.

movementX и movementY равны 0, когда для Stage.mouseLock установлено значение false.

Связанные элементы API

Ссылка на объект списка отображения, связанный с событием. Например, когда происходит событие mouseOut, relatedObject представляет объект списка отображения, на который теперь показывает указатель. Это свойство применяется к событиям mouseOut, mouseOver, rollOut и rollOver.

Это свойство может принимать значение null по двум причинам: связанный объект отсутствует или связанный объект существует, но находится в изолированной программной среде безопасности, доступ к которой запрещен. Используйте свойство isRelatedObjectInaccessible() для определения причины.

Связанные элементы API

Показывает активность клавиши Shift: true — активна, false — неактивна.

Горизонтальная координата события в глобальных координатах рабочей области. Это свойство вычисляется, когда задано свойство localX.

Вертикальная координата события в глобальных координатах рабочей области. Это свойство вычисляется, когда задано свойство localY.

Создает объект Event, содержащий данные о событиях мыши. Объекты Event передаются прослушивателям событий в качестве параметров.

Создает копию объекта MouseEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта MouseEvent. Строка имеет следующий формат:

[MouseEvent type=value bubbles=value cancelable=value ... delta=value]

Предписывает проигрывателю Flash Player или Adobe AIR выполнить визуализацию после обработки данного события, если список отображения был изменен.

Задает значение свойства type для объекта события click.

Это событие имеет следующие свойства:

Связанные элементы API

Константа MouseEvent.CONTEXT_MENU определяет значение свойства type объекта события contextMenu.

Это событие имеет следующие свойства:

Задает значение свойства type для объекта события doubleClick. Свойство doubleClickEnabled должно иметь значение true, чтобы объект мог генерировать событие doubleClick.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события middleClick.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события middleMouseDown.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события middleMouseUp.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события mouseDown.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события mouseMove.

Это событие имеет следующие свойства:

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Задает значение свойства type для объекта события mouseOut.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события mouseOver.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type объекта события mouseUp.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события mouseWheel.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события releaseOutside.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события rightClick.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события rightMouseDown.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события rightMouseUp.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события rollOut.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события rollOver.

Это событие имеет следующие свойства:

Связанные элементы API

1. Заявляются свойства для размера (100 x 100 пикселей) и фонового цвета (оранжевый) для последующего использования при рисовании квадрата.
2. Конструктор создает новый объект ChildSprite с именем child. Его конструктор сначала рисует оранжевый квадрат 100 x 100 пикселей в точке с координатами (0,0) путем вызова метода draw(), а затем добавляет семь прослушивателей событий с подписчиками.
   • click/clickHandler(): отправляется, когда пользователь один раз щелкает квадрат левой кнопкой мыши.
   • doubleClick/doubleClickHandler(): отправляется, когда пользователь дважды щелкает квадрат левой кнопкой мыши.
   • mouseDown/mouseDownHandler(): когда нажимают объект ChildSprite (оранжевый квадрат), на экране печатается сообщение trace(), а затем вызывается метод ChildSprite.draw(), рисующий темно-желтый квадрат вместо голубого, нарисованного методом mouseOverHandler(). Метод mouseDownHandler() также добавляет прослушиватель событий mouseMove и подписчик mouseMoveHandler() (как описано ниже), обрабатывающий перемещение мыши. Затем вызывается метод startDrag(), позволяющий перетаскивать объект Sprite.
   • mouseOut/mouseOutHandler(): отправляется, когда указатель покидает область квадрата. Вызывается метод draw(), чтобы вернуть квадрату обычный размер и цвет.
   • mouseOver/mouseOverHandler(): отправляется, когда указатель мыши находится над квадратом. Этот метод перерисовывает квадрат так, что он становится больше, а фон становится темно-желтым.
   • mouseUp/mouseUpHandler(): когда пользователь отпускает кнопку мыши, прослушиватель события mouseMove удаляется и вызывается метод stopDrag фиксирующий местоположение квадрата.
   • mouseMove/mouseMoveHandler(): вызывается в рамках функции mouseDownHandler() и отправляется, когда пользователь удерживает левую кнопку мыши и перетаскивает квадрат.
   • mouseWheel/mouseWheelHandler(): отправляется при прокручивании пользователем колесика мыши над квадратом.
3. Затем экземпляр ChildSprite с именем child добавляется в список отображения с помощью метода addChild(), который быстро рисует оранжевый квадрат.

Примечания.

• Класс MouseEventExample должен быть в корне документа.
• Некоторые из перечисленных выше методов событий объявляют локальную переменную sprite, которой присваивается значение event.target типа Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}