TextLineMetrics  - AS3

O valor de subida do texto é o comprimento da linha de base até o topo da altura da linha em pixels. Consulte a medida da "Subida" no diagrama da visão geral da classe.

Elementos da API relacionados

O valor de descida do texto é o comprimento da linha de base até a parte inferior da linha em pixels. Consulte a medida da "Descida" no diagrama da visão geral da classe.

Elementos da API relacionados

O valor de altura do texto das linhas selecionadas (não necessariamente o texto completo) em pixels. A altura da linha de texto não inclui a altura da medianiz. Consulte a medida da "Altura da linha" no diagrama da visão geral da classe.

Elementos da API relacionados

O valor de entrelinha é a medida da distância vertical entre as linhas de texto. Consulte a medida da "Entrelinha" no diagrama da visão geral da classe.

Elementos da API relacionados

O valor de largura é a largura do texto das linhas selecionadas (não necessariamente o texto completo) em pixels. A largura da linha de texto não é idêntica à largura do campo de texto. A largura da linha de texto é relativa à largura do campo de texto menos a largura da medianiz de 4 pixels (2 pixels em cada lado). Consulte a medida da "Largura da linha do texto" no diagrama da visão geral da classe.

Elementos da API relacionados

O valor de x é a posição esquerda do primeiro caractere em pixels. Esse valor inclui as larguras da margem, do recuo (se houver) e da medianiz. Consulte "Posição-x da linha do texto" no diagrama da visão geral da classe.

Elementos da API relacionados

Cria um objeto TextLineMetrics. O objeto TextLineMetrics contém informações sobre a métrica de texto de uma linha de texto dentro de um campo de texto. Os objetos dessa classe são retornados pelo método flash.text.TextField.getLineMetrics().

Consulte o diagrama na visão geral da classe para conferir as propriedades no contexto.

Elementos da API relacionados

1. Crie uma propriedade chamada label do tipo TextField.
2. O construtor chama configureAssets(), que faz o seguinte:
   • Define o alinhamento do palco como superior-esquerdo e sem escala.
   • Cria um novo objeto TextField denominado label.
   • Ativa o plano de fundo de label e define a cor como branco.
   • Permite que o texto de label seja espalhado em várias linhas com quebra automática de texto.
   • Atribui o resultado de uma chamada a getLabelText() para a propriedade text de label. O método getLabelText() cria uma variável do tipo XML e a atribui a um nó XML denominado body, preenchido com uma frase longa.
   • Adiciona label à lista de exibição utilizando addChild().
3. Um método chamado resizeHandler() que é ouvinte de eventos resize realizados no palco é então adicionado. Sempre que o tamanho da janela do Flash Player for alterado, um evento RESIZE será despachado e acontecerá o seguinte:
   • draw() é chamado para garantir que label seja exibido no centro do palco e esteja cercado por um buffer de 10 pixels.
   • Em seguida, setTimeout() executa showMetrics() após um breve atraso. O atraso será adicionado porque a métrica de linha não foi atualizada depois que o evento RESIZE foi concluído e o palco foi totalmente redesenhado.
   • showMetrics() atribui uma variável TextLineMetrics denominada metrics ao resultado de uma chamada para getLineMetrics() e essa variável é passada a uma nova ocorrência de uma ocorrência LineMetricsReader denominada reader. Em seguida, as duas variáveis são utilizadas nas chamadas para trace() para imprimir a primeira (e única) linha de label e as informações fornecidas pela ocorrência LineMetricsReader através do seu método toString().
4. O construtor força um despacho único do evento resize para forçar que label seja desenhado corretamente quando o arquivo SWF for carregado pela primeira vez.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}