DropShadowFilter  - AS3

Valor de transparência alfa da cor de sombra. Os valores válidos são 0,0 a 1,0. Por exemplo, ,25 define um valor de transparência de 25%. O valor padrão é 1,0.

Ângulo da sombra. Os valores válidos são 0 a 360 graus (ponto flutuante). O valor padrão é 45.

Intensidade de desfoque horizontal. Os valores válidos são 0 a 255,0 (ponto flutuante). O valor padrão é 4,0.

Intensidade do desfoque vertical. Os valores válidos são 0 a 255,0 (ponto flutuante). O valor padrão é 4,0.

Cor da sombra. Os valores válidos estão no formato hexadecimal 0xRRGGBB. O valor padrão é 0x000000.

Distância de deslocamento da sombra, em pixels. O valor padrão é de 4,0 (ponto flutuante).

Indica se o objeto está ou não oculto. O valor true indica que o próprio objeto não está desenhado; somente a sombra é visível. O padrão é false (o objeto é mostrado).

Indica se a sombra é ou não uma sombra interna. O valor true indica uma sombra interna. O padrão é false, uma sombra externa (uma sombra em volta das bordas externas do objeto).

Aplica um efeito de tachado (true), que torna efetivamente transparente o preenchimento do objeto e revela a cor de plano de fundo do documento. O padrão é false (sem tachado).

Número de vezes para aplicar o filtro. O valor padrão é BitmapFilterQuality.LOW, que é equivalente a aplicar o filtro uma vez. O valor BitmapFilterQuality.MEDIUM aplica o filtro duas vezes; o valor BitmapFilterQuality.HIGH aplica três vezes. Os filtros com valores menores são renderizados mais rapidamente.

Para a maioria dos aplicativos, um valor de qualidade baixo, médio ou alto é suficiente. Embora você possa usar valores numéricos adicionais até 15 para obter efeitos diferentes, os valores maiores são renderizados mais lentamente. Em vez de aumentar o valor de quality, você pode normalmente obter um efeito similar, com uma renderização mais rápida, simplesmente aumentando os valores das propriedades blurX e blurY.

Elementos da API relacionados

Intensidade da impressão ou dispersão. Quanto maior o valor, mais cores são impressas e mais forte será o contraste entre a sombra e o plano de fundo. Os valores válidos são 0 a 255,0. O padrão é 1,0.

Cria uma nova ocorrência DropShadowFilter com os parâmetros especificados.

Elementos da API relacionados

Retorna uma cópia deste objeto de filtro.

1. Declare três propriedades que são usadas para desenhar o quadrado no qual o filtro é aplicado.
2. Crie a função de construtor. O construtor chama o método draw(), que usa os métodos da classe Graphics acessado por meio da propriedade graphics do Sprite para desenhar um quadrado laranja.
3. No construtor, declare uma variável filter como um objeto BitmapFilter e atribua-a ao valor de retorno de uma chamada para getBitmapFilter(). O método getBitmapFilter() define o filtro de sombra usado.
4. Crie um novo objeto Array myFilters e adicione filter à matriz. Atribua a matriz myFilters à propriedade filters do objeto DropShadowFilterExample. Isso aplica todos os filtros encontrados em myFilters, o que, nesse caso, é somente filter.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}