| Pacote | flash.filesystem |
| Classe | public class StorageVolume |
| Herança | StorageVolume  Object |
| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
- A propriedade
storageVolumede um objeto StorageVolumeChangeEvent é um objeto StorageVolume. Este objeto representa o volume de armazenamento que foi montado ou desmontado. - O método
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes()retorna um vetor de objetos StorageVolume. Cada um destes objetos StorageVolume representa um volume de armazenamento montado.
Elementos da API relacionados
flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume
flash.events.StorageVolumeChangeEvent.storageVolume
Propriedades públicas
Ocultar propriedades públicas herdadas
Mostrar propriedades públicas herdadas| Propriedade | Definido por | ||
|---|---|---|---|
 | constructor : Object
Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto. | Object | |
| drive : String [somente leitura]
A letra da unidade de volume no Windows. | StorageVolume | ||
| fileSystemType : String [somente leitura]
O tipo de sistema de arquivos no volume de armazenamento (como "FAT", "NTFS", "HFS" ou "UFS"). | StorageVolume | ||
| isRemovable : Boolean [somente leitura]
Se o sistema operacional considerar que o volume de armazenamento é removível (verdadeiro) ou não (falso). | StorageVolume | ||
| isWritable : Boolean [somente leitura]
Se um volume for gravável (verdadeiro) ou não (falso). | StorageVolume | ||
| name : String [somente leitura]
O nome do volume. | StorageVolume | ||
| rootDirectory : File [somente leitura]
Um objeto Arquivo correspondente ao diretório raiz do volume. | StorageVolume | ||
Métodos públicos
| Método | Definido por | ||
|---|---|---|---|
StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)
A função de construtor. | StorageVolume | ||
|
Indica se um objeto tem uma propriedade especificada definida. | Object | |
|
Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro. | Object | |
|
Indica se a propriedade especificada existe e é enumerável. | Object | |
|
Define a disponibilidade de uma propriedade dinâmica para operações de repetição. | Object | |
|
Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade. | Object | |
|
Retorna a representação de string do objeto especificado. | Object | |
|
Retorna o valor primitivo do objeto especificado. | Object | |
Detalhes da propriedade
drive | propriedade |
fileSystemType | propriedade |
fileSystemType:String [somente leitura] | Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
O tipo de sistema de arquivos no volume de armazenamento (como, "FAT", "NTFS", "HFS" ou"UFS").
Implementação
public function get fileSystemType():StringExemplo ( Como usar este exemplo )
O seguinte código relaciona o caminho nativo do diretório raiz e o tipo de sistema de arquivos de cada volume de armazenamento montado:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}
isRemovable | propriedade |
isRemovable:Boolean [somente leitura] | Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
Se o sistema operacional considerar que o volume de armazenamento é removível ( true) ou não (false).
A seguinte tabela lista os valores da propriedade StorageVolume.isRemovable de vários tipos de dispositivos:
| Tipo de dispositivo | Mac OS | Windows | Linux |
|---|---|---|---|
| CD/DVD (fixo) | true | true | true |
| Unidade flash USB | true | true | true |
| Unidade de disco rígido USB | false | false | true |
| Unidade de disco rígido FireWire | false | false | true |
| Volume compartilhado | true | false | - 1 |
| Unidade de Rede | false | false | false |
| Leitor de cartão de armazenamento (vazio) | - 2 | false | - 2 |
| Leitor de cartão de armazenamento (com cartão SD/CF) | true | true | true |
1 O Linux não tem o conceito de volume compartilhado.
2 No Windows, um leitor de cartão vazio é listado como um dispositivo não removível. Nos sistemas operacionais Mac e Linux, os leitores de carro vazios não são listados como volumes de armazenamento.
Implementação
public function get isRemovable():BooleanExemplo ( Como usar este exemplo )
O seguinte código emite uma lista de volumes de armazenamento não removíveis, seguidos por uma lista de volumes de armazenamento removíveis:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
if (!volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
if (volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
isWritable | propriedade |
isWritable:Boolean [somente leitura] | Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
Se um volume for gravável (true) ou não (false).
Observação: você pode determinar a quantidade do espaço disponível em um volume, chamando a propriedade rootDirectory.spaceAvailble do objeto StorageVolume.
Implementação
public function get isWritable():BooleanElementos da API relacionados
flash.fileSystem.File.spaceAvailable
Exemplo ( Como usar este exemplo )
O seguinte código emite uma lista de volumes de armazenamento graváveis e o espaço disponível em cada um:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
if(volumes[i].isWritable)
{
trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
}
}
name | propriedade |
name:String [somente leitura] | Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
O nome do volume. Se não houver nenhum nome, esta propriedade será definida como null.
Implementação
public function get name():StringExemplo ( Como usar este exemplo )
O seguinte código relaciona o caminho nativo do diretório raiz e o nome de sistema de arquivos (se houver) de cada volume de armazenamento montado:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var name:String = new String();
if (volumes[i].name)
{
name = "(" + volumes[i].name + ")";
}
trace(volumes[i].rootDirectory.nativePath, name);
}
rootDirectory | propriedade |
rootDirectory:File [somente leitura] | Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
Um objeto Arquivo correspondente ao diretório raiz do volume.
Implementação
public function get rootDirectory():FileExemplo ( Como usar este exemplo )
O seguinte código relaciona o caminho nativo do diretório raiz de cada volume de armazenamento montado:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath);
}
Detalhes do construtor
StorageVolume | () | Construtor |
public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 2 |
A função de construtor. Geralmente, você não chama esta função de construtor diretamente (para criar novos objetos StorageVolume). De preferência, faça referência a objetos StorageVolume, acessando a propriedade storageVolume de um objeto StorageVolumeChangeEvent ou chamando StorageVolumeInfo.getStorageVolumes().
rootDirPath:File | |
name:String | |
writable:Boolean | |
removable:Boolean | |
fileSysType:String | |
drive:String |
Exemplos Como usar este exemplo
StorageVolumeExample.as
O seguinte código relaciona as propriedades de cada volume de armazenamento montado:
package
{
import flash.display.Sprite;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeExample extends Sprite
{
public function StorageVolumeExample()
{
var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var volume:StorageVolume = volumes[i];
trace("nativePath:", volume.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace("________________________________________________________");
}
}
}
}
StorageVolumeChangeEventExample.as
O seguinte código relaciona as propriedades de cada volume de armazenamento que foi montado ou desmontado. Observe que a propriedade
storageVolume do StorageVolumeChangeEvent só é definida para o evento storageVolumeMount; é null para o eventostorageVolumeUnmount:
package
{
import flash.display.Sprite;
import flash.events.StorageVolumeChangeEvent;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeChangeEventExample extends Sprite
{
public function StorageVolumeChangeEventExample()
{
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
}
public function mountEventHandler(event:StorageVolumeChangeEvent):void
{
var volume:StorageVolume = event.storageVolume;
trace("VOLUME MOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace();
}
public function unmountEventHandler(event:StorageVolumeChangeEvent):void
{
trace("VOLUME UNMOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace();
}
}
}
Wed Jun 13 2018, 11:10 AM Z