FocusEvent  - AS3

Especifica a direção do foco para um evento focusIn.

Elementos da API relacionados

Se for true, a propriedade relatedObject será definida como null pelos motivos relacionados às caixas de proteção de segurança. Se o valor nominal de relatedObject for uma referência a um DisplayObject de outra caixa de proteção, a propriedade relatedObject será definida como null, a menos que haja permissão em ambas as direções do limite dessa caixa de proteção. A permissão é estabelecida chamando Security.allowDomain() de um arquivo SWF ou fornecendo um arquivo de diretivas do servidor de um arquivo de imagem e definindo a propriedade LoaderContext.checkPolicyFile quando carregar a imagem.

Elementos da API relacionados

O valor de código da tecla pressionada para disparar um evento keyFocusChange.

Uma referência para a ocorrência de InteractiveObject complementar que é afetada pela alteração no foco. Por exemplo, quando ocorre um evento focusOut, o relatedObject representa o InteractiveObject que ganhou foco.

O valor dessa propriedade pode ser null em duas situações: se não houver nenhum objeto relacionado, ou se houver um objeto relacionado, mas que esteja em uma área de segurança à qual você não tem acesso. Use a propriedade isRelatedObjectInaccessible() para determinar qual desses motivos se aplica.

Elementos da API relacionados

Indica se o modificador da tecla Shift está ativado, caso em que o valor é true. Do contrário, o valor padrão é false. Esta propriedade só será usada se o FocusEvent for do tipo keyFocusChange.

Cria um objeto Event com informações específicas pertinentes a eventos focus. Objetos Event são transmitidos como parâmetros para ouvintes de eventos.

Elementos da API relacionados

Cria uma cópia do objeto FocusEvent e define o valor de cada propriedade para corresponder ao do original.

Retorna uma string que contém todas as propriedades do objeto FocusEvent. A string está no seguinte formato:

[FocusEvent type=valor bubbles=valor cancelable=valor relatedObject=valor shiftKey=valor] keyCode=valor]

Define o valor da propriedade type de um objeto de evento focusIn.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento focusOut.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento keyFocusChange.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento mouseFocusChange.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

1. Ele declara as propriedades child (do tipo Sprite) e childCount (do tipo uint).
2. Um loop for cria cinco quadrados azuis claro em (0,0). Ele começa atribuindo a child a uma nova ocorrência CustomSprite. Cada vez que um objeto CustomSprite é criado, ocorre o seguinte:
   • A propriedade size do tipo uint é definida como 50 pixels e bgColor é definida como azul claro.
   • As propriedades buttonMode e useHandCursor da classe Sprite são definidas como true no construtor.
   • Um ouvinte de evento de tipo click é instanciado, juntamente com o assinante associado clickHandler(). O método do assinante cria uma variável local target de tipo Sprite e a atribui a qualquer um das caixas clicadas. O foco do palco é então atribuído a target.
   • O método draw() é chamado, o que cria um quadrado de 50 x 50 pixels chamando os métodos beginFill(), drawRect() e endFill() da classe Graphics e as propriedades da ocorrência.
3. No loop for, o método configureListener() é chamado, o que instancia três ouvintes/assinantes de evento:
   • focusIn/focusInHandler() é despachado depois do evento click para qualquer objeto da lista de exibição (caixa) clicada.
   • focusOut/focusOutHandler() é despachado quando outra caixa é clicada ou se o foco deixar o palco (por exemplo, clicando fora do Flash Player).
   • keyFocusChange/keyFocusChangeHandler() será despachado se você usar a tecla Tab ou se as teclas de seta à esquerda ou seta à direita selecionarem um objeto da lista de exibição. O método keyFocusChangeHandler(), no entanto, engana as teclas de seta à esquerda e seta à direita, e chama o método preventDefault() para desativá-las.
4. No loop for, cada quadrado é adicionado à lista de exibição e exibido (todos na mesma área) por meio do addChild().
5. O construtor então chama o refreshLayout(), que distribui quadrados laranjas em torno da parte superior (y = 0) da exibição, com 5 pixels separando cada quadrado.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}