CapsStyle - Referência da API Adobe ActionScript® 3 (AS3 )

Pacote	flash.display
Classe	public final class CapsStyle
Herança	CapsStyle Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

A classe CapsStyle é uma enumeração de valores constantes que especificam o estilo de formatação de letras a ser usado no desenho de linhas. As constantes são fornecidas para uso como valores no parâmetro caps do método flash.display.Graphics.lineStyle(). Você pode especificar os três tipos de extremidades a seguir:

Três tipos de extremidades: NENHUM, ARREDONDADO e QUADRADO.

Veja os exemplos

Elementos da API relacionados

flash.display.Graphics.lineStyle()

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		hasOwnProperty(name:String):Boolean Indica se um objeto tem uma propriedade especificada definida.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se a propriedade especificada existe e é enumerável.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String Retorna a representação de string do objeto especificado.	Object
		valueOf():Object Retorna o valor primitivo do objeto especificado.	Object

Constantes públicas

	Constante		Definido por
		NONE : String = "none" [estático] Usado para especificar nenhuma extremidade no parâmetro "caps" do método flash.display.Graphics.lineStyle().	CapsStyle
		ROUND : String = "round" [estático] Usado para especificar extremidades arredondadas no parâmetro "caps" do método flash.display.Graphics.lineStyle().	CapsStyle
		SQUARE : String = "square" [estático] Usado para especificar extremidades quadradas no parâmetro "caps" do método flash.display.Graphics.lineStyle().	CapsStyle

Detalhes da constante

NONE

Constante

public static const NONE:String = "none"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Usado para especificar nenhuma extremidade no parâmetro caps do método flash.display.Graphics.lineStyle().

ROUND

Constante

public static const ROUND:String = "round"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Usado para especificar extremidades arredondadas no parâmetro caps do método flash.display.Graphics.lineStyle().

SQUARE

Constante

public static const SQUARE:String = "square"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Usado para especificar extremidades quadradas no parâmetro caps do método flash.display.Graphics.lineStyle().

Exemplos Como usar este exemplo

CapsStyleExample.as

O exemplo a seguir usa a classe CapsStyleExample para desenhar três linhas paralelas, cada uma com um estilo diferente de extremidade de linha.

As propriedades de cada linha são definidas desta forma:
- O comprimento da linha é definido como 80 pixels.
- A cor da borda é definida como laranja.
- O tamanho da borda é definido como 30 pixels.
- A cor do realce é definida como cinza.
- O tamanho do realce é definido como 0 pixels.
- O alfa é definido como 1, tornando-o sólido.
- A referência de pixels é definida como "false" (traçados não referenciados como pixels completos).
- O modo de escala de linha é definido como normal, que dimensiona a espessura.
- O estilo de união das extremidades da borda é definido como MITER.
- O limite de mitre é definido como 1, indicando que o mitre é cortado próximo à linha.
O construtor da classe cria três linhas verticais, começando em x = 0, y = 0, chamando o método drawLine() três vezes com o uso dos três diferentes estilos de extremidade de linha (nenhum, arredondado e quadrado). Cada uma das três chamadas ao método drawLine() usa o estilo de extremidade e as propriedades anteriormente listadas para desenhar uma linha vertical e o realce de linha associado. As chamadas criam primeiro um novo objeto Shape child e então usam os métodos da classe Graphics para definir o estilo de linha e desenhar as linhas e os realces. Cada ocorrência de child é adicionada à lista de exibição e desenhada no palco.
Os segmentos de linha conectados são então redesenhados com o uso do método refreshLayout() em y = 80 pixels e começando em x = 80 pixels, com uma separação de 25 pixels entre os segmentos de linha.

package {
    import flash.display.CapsStyle;
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class CapsStyleExample extends Sprite {
        private var lineLength:uint            = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderJointStyle:String    = JointStyle.MITER;
        private var borderMiterLimit:uint      = 1;

        public function CapsStyleExample() {
            drawLine(CapsStyle.NONE);
            drawLine(CapsStyle.ROUND);
            drawLine(CapsStyle.SQUARE);
            refreshLayout();
        }

        private function drawLine(capsStyle:String):void {
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     capsStyle,
                                     borderJointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = lineLength;
            lastChild.y = lineLength;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = lineLength;
                lastChild = child;
            }
        }
    }
}

Aspectos jurídicos | Política de privacidade on-line

CapsStyle - AS3

Classes x

NONE

ROUND

SQUARE