| Pacote | flash.desktop |
| Classe | public class DockIcon |
| Herança | DockIcon  InteractiveIcon Icon EventDispatcher Object |
| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0 |
Suporte a perfil do AIR: este recurso conta com suporte em todos os sistemas operacionais para desktop, mas não é compatível com dispositivos móveis nem com dispositivos AIR for TV. Você pode testar o suporte em tempo de execução usando a propriedadeNativeApplication.supportsDockIcon. Consulte Suporte a perfil do AIR para obter mais informações sobre o suporte de API através de múltiplos perfis.
Você pode usar a classe DockIcon para alterar a aparência do ícone padrão, por exemplo, para animar o ícone ou acrescentar gráficos adicionais. Você pode também adicionar itens ao menu de ícones do encaixe. Os itens de menu que você acrescenta são exibidos acima dos itens do menu padrão.
Uma ocorrência da classe DockIcon não pode ser criada. Obtenha o objeto que representa o ícone de encaixe do sistema operacional do NativeApplication.icon.
Nem todos os sistemas operacionais têm ícones de encaixe. Verifique NativeApplication.supportsDockIcon para determinar se os ícones de encaixe são suportados no sistema atual. Se os ícones de encaixe forem suportados, a propriedade NativeApplication.icon é do tipo DockIcon. Caso contrário, o tipo de NativeApplication.icon é outra subclasse de InteractiveIcon, geralmente SystemTrayIcon.
Importante: tentar chamar um método da classe DockIcon no objeto NativeApplication.icon em um sistema operacional para o qual o AIR não suporta os ícones de encaixe gera uma exceção do tempo de execução.
Elementos da API relacionados
flash.desktop.NativeApplication.supportsDockIcon
flash.desktop.SystemTrayIcon
Ocultar propriedades públicas herdadas
Mostrar propriedades públicas herdadas| Propriedade | Definido por | ||
|---|---|---|---|
| bitmaps : Array [substituir]
A imagem do ícone como uma matriz de objetos BitmapData de tamanhos diferentes. | DockIcon | ||
 | constructor : Object
Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto. | Object | |
| height : int [substituir] [somente leitura]
A altura de exibição atual do ícone, em pixels. | DockIcon | ||
| menu : NativeMenu
O menu fornecido pelo sistema desse ícone de encaixe. | DockIcon | ||
| width : int [substituir] [somente leitura]
A largura de exibição atual do ícone, em pixels. | DockIcon | ||
| Método | Definido por | ||
|---|---|---|---|
| addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Registra um objeto de ouvinte de evento em um objeto EventDispatcher, de forma que o ouvinte receba a notificação de um evento. | EventDispatcher | |
Notifica o usuário que ocorreu um evento que pode exigir atenção. | DockIcon | ||
|
Envia um evento para o fluxo de eventos. | EventDispatcher | |
|
Verifica se o objeto EventDispatcher tem ouvintes registrados para um tipo específico de evento. | EventDispatcher | |
|
Indica se um objeto tem uma propriedade especificada definida. | Object | |
|
Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro. | Object | |
|
Indica se a propriedade especificada existe e é enumerável. | Object | |
|
Remove um ouvinte do objeto EventDispatcher. | EventDispatcher | |
|
Define a disponibilidade de uma propriedade dinâmica para operações de repetição. | Object | |
|
Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade. | Object | |
|
Retorna a representação de string do objeto especificado. | Object | |
|
Retorna o valor primitivo do objeto especificado. | Object | |
|
Verifica se um ouvinte de evento está registrado nesse objeto EventDispatcher ou em qualquer um de seus ancestrais para o tipo de evento especificado. | EventDispatcher | |
bitmaps | propriedade |
bitmaps:Array[substituir] | Versões de runtime: | AIR 1.0 |
A imagem do ícone como uma matriz de objetos BitmapData de tamanhos diferentes.
Quando um ícone é exibido em um determinado contexto do sistema operacional, será usado (e escalado, se necessário) o bitmap na matriz mais próximo do tamanho exibido. Os tamanhos comuns incluem 16x16, 32x32, 48x48 e 128x128. (Ícones de 512x512 pixels podem ser usados para ícones de alguns sistemas operacionais em um futuro próximo.)
Em alguns contextos, o sistema operacional poderá usar um ícone de sistema padrão se nada tiver sido atribuído à propriedade bitmaps. Em outros contextos, não aparece nenhum ícone.
Para definir ou alterar a aparência do ícone, atribua uma matriz dos objetos BitmapData para a propriedade bitmaps:
icon.bitmaps = new Array(icon16x16.bitmapData, icon128x128.bitmapData);
Modificar a matriz bitmaps diretamente não tem efeito algum.
Para limpar a imagem do ícone, atribua uma matriz vazia à propriedade bitmaps.
Observação: ao carregar arquivos de imagem para um ícone, o formato de arquivo PNG geralmente fornece a melhor mesclagem alfa. O formato GIF só suporta ativação ou desativação de transparência (sem mesclagem). O formato JPG não suporta nenhum tipo de transparência.
Implementação
override public function get bitmaps():Array override public function set bitmaps(value:Array):void height | propriedade |
height:int [somente leitura] [substituir] | Versões de runtime: | AIR 1.0 |
A altura de exibição atual do ícone, em pixels.
Alguns contextos de itens suportam tamanhos dinâmicos. A propriedade height indica a altura do ícone escolhida na matriz bitmaps para o contexto atual. A altura de exibição atual poderá ser diferente se o sistema operacional tiver escalado o ícone.
Implementação
override public function get height():int menu | propriedade |
menu:NativeMenu| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0 |
O menu fornecido pelo sistema desse ícone de encaixe.
Qualquer item no menu é exibido acima dos itens padrão. Os itens padrão não podem ser modificados ou removidos.
Implementação
public function get menu():NativeMenu public function set menu(value:NativeMenu):voidExemplo ( Como usar este exemplo )
import flash.desktop.NativeApplication;
import flash.events.Event;
private function createDockIconMenu():void{
if(NativeApplication.supportsDockIcon){
var dockIcon:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;
var dockMenu:NativeMenu = new NativeMenu();
var command:NativeMenuItem = dockMenu.addItem(new NativeMenuItem("Command"));
command.addEventListener(Event.SELECT, onCommand);
dockIcon.menu = dockMenu;
}
}
private function onCommand(event:Event):void{
//do command...
}
width | propriedade |
width:int [somente leitura] [substituir] | Versões de runtime: | AIR 1.0 |
A largura de exibição atual do ícone, em pixels.
Alguns contextos de itens suportam tamanhos dinâmicos. A propriedade width indica a largura do ícone escolhida na matriz bitmaps para o contexto atual. A largura de exibição atual poderá ser diferente se o sistema operacional tiver escalado o ícone.
Implementação
override public function get width():intbounce | () | método |
public function bounce(priority:String = "informational"):void| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0 |
Notifica o usuário que ocorreu um evento que pode exigir atenção.
Chamar esse método faz o ícone de encaixe "pular" se, e somente se, o aplicativo estiver em segundo plano. Se a priority for NotificationType.Informational, haverá um único pulo do ícone. Se a priority for NotificationType.Critical, então o ícone pula até que o aplicativo seja trazido para o primeiro plano.
Parâmetros
priority:String (default = "informational") |
Elementos da API relacionados
Exemplo ( Como usar este exemplo )
import flash.display.DockIcon;
import flash.display.NotificationType;
import flash.desktop.NativeApplication;
if(NativeApplication.supportsDockIcon){
var dockIcon:DockIcon = NativeApplication.nativeApplication.icon As DockIcon;
dockIcon.bounce(NotificationType.CRITICAL);
}
package {
import flash.desktop.DockIcon;
import flash.desktop.NativeApplication;
import flash.display.Loader;
import flash.display.NativeMenu;
import flash.display.NativeMenuItem;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.TimerEvent;
import flash.net.URLRequest;
import flash.utils.Timer;
public class AnimatedDockIcon extends Sprite
{
private var imageURLs:Array = ['gfx/frame01.png',
'gfx/frame02.png',
'gfx/frame03.png',
'gfx/frame04.png'];
private var images:Array = new Array();
private var animTimer:Timer = new Timer(100);
public function AnimatedDockIcon()
{
NativeApplication.nativeApplication.autoExit = false;
addEventListener(Event.COMPLETE, loadImages);
loadImages();
animTimer.addEventListener(TimerEvent.TIMER,advanceFrame);
addMenu();
stage.nativeWindow.close();
}
private function addMenu():void{
var menu:NativeMenu = new NativeMenu();
var start:NativeMenuItem = menu.addItem(new NativeMenuItem("Start animation"));
var stop:NativeMenuItem = menu.addItem(new NativeMenuItem("Stop animation"));
start.addEventListener(Event.SELECT, startTimer);
stop.addEventListener(Event.SELECT, stopTimer);
var dockIcon:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;
dockIcon.menu = menu;
}
private function startTimer(event:Event):void{
animTimer.start();
}
private function stopTimer(event:Event):void{
animTimer.stop();
}
private var currentFrame:int = 0;
private function advanceFrame(event:Event):void{
if(currentFrame < images.length){
currentFrame++;
} else {
currentFrame = 0;
}
NativeApplication.nativeApplication.icon.bitmaps = [images[currentFrame]];
}
private function loadImages(event:Event = null):void{
if(event != null){
images.push(event.target.content.bitmapData);
}
if(imageURLs.length > 0){
var urlString:String = imageURLs.pop();
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadImages, false, 0, true);
loader.load(new URLRequest(urlString));
} else {
var complete:Event = new Event(Event.COMPLETE,false,false);
dispatchEvent(complete);
}
}
}
}
Wed Jun 13 2018, 11:10 AM Z