Pacote | fl.controls.dataGridClasses |
Classe | public class DataGridColumn |
Herança | DataGridColumn Object |
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Você pode especificar o tipo de componente que exibirá os dados de um DataGridColumn. As características que podem ser especificadas incluem o texto que aparece no cabeçalho da coluna e informam se a coluna pode ser editada, classificada ou redimensionada.
Elementos da API relacionados
Propriedade | Definido por | ||
---|---|---|---|
cellRenderer : Object
Classe usada para renderizar os itens nessa coluna. | DataGridColumn | ||
constructor : Object
Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto. | Object | ||
dataField : String
Identifica o nome do campo ou propriedade no item do provedor de dados associado à coluna. | DataGridColumn | ||
editable : Boolean = true
Indica se os itens na coluna podem ser editados. | DataGridColumn | ||
editorDataField : String = "text"
Identifica o nome da propriedade do editor de itens que contém os novos dados para o item da lista. | DataGridColumn | ||
headerRenderer : Object
Classe usada para renderizar o cabeçalho dessa coluna. | DataGridColumn | ||
headerText : String
Nome da coluna a ser exibido no cabeçalho da coluna. | DataGridColumn | ||
imeMode : String
Modo do editor de métodos de entrada (IME). | DataGridColumn | ||
itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor
Indica a classe das ocorrências do editor de itens a serem usadas para a coluna, quando ela for editável. | DataGridColumn | ||
labelFunction : Function
Função que determina o texto a ser exibido nesta coluna. | DataGridColumn | ||
minWidth : Number
Largura mínima da coluna, em pixels. | DataGridColumn | ||
resizable : Boolean = true
Indica se o usuário tem permissão para alterar a largura da coluna. | DataGridColumn | ||
sortable : Boolean = true
Indica se o usuário pode clicar no cabeçalho da coluna atual para classificar o provedor de dados. | DataGridColumn | ||
sortCompareFunction : Function
Função de retorno de chamada que é chamada durante a classificação dos dados na coluna. | DataGridColumn | ||
sortDescending : Boolean = false
Indica se DataGridColumn deve ser classificado em ordem crescente ou decrescente. | DataGridColumn | ||
sortOptions : uint = 0
Uma ou mais constantes definidas, identificadas pelo nome ou número e separadas pelo operador OR (|) em nível de bits. | DataGridColumn | ||
visible : Boolean
Indica se a coluna é visível. | DataGridColumn | ||
width : Number
Largura da coluna, em pixels. | DataGridColumn |
Método | Definido por | ||
---|---|---|---|
DataGridColumn(columnName:String = null)
Cria uma nova ocorrência de DataGridColumn. | DataGridColumn | ||
Indica se um objeto tem uma propriedade especificada definida. | Object | ||
Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro. | Object | ||
Retorna a string exibida pelo renderizador de itens para o objeto de dados especificado. | DataGridColumn | ||
Indica se a propriedade especificada existe e é enumerável. | Object | ||
Define a disponibilidade de uma propriedade dinâmica para operações de repetição. | Object | ||
Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade. | Object | ||
Retorna uma representação de string do objeto DataGridColumn. | DataGridColumn | ||
Retorna o valor primitivo do objeto especificado. | Object |
cellRenderer | propriedade |
cellRenderer:Object
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Classe usada para renderizar os itens nessa coluna. O tipo dessa propriedade pode ser Class, Sprite ou String. Se o tipo de propriedade for String, o valor da String deve ser um nome de classe totalmente qualificado.
O valor padrão é null.
Implementação
public function get cellRenderer():Object
public function set cellRenderer(value:Object):void
Elementos da API relacionados
Exemplo ( Como usar este exemplo )
import fl.controls.dataGridClasses.DataGridColumn; var dgc:DataGridColumn = new DataGridColumn("Field"); dgc.cellRenderer = "MyCustomCellRendererClass"; dg.addColumn(dgc);
dataField | propriedade |
public var dataField:String
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Identifica o nome do campo ou propriedade no item do provedor de dados associado à coluna.
editable | propriedade |
public var editable:Boolean = true
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se os itens na coluna podem ser editados. Um valor de true
indica que os itens da coluna podem ser editados; um valor de false
indica que não podem.
Se a propriedade for definida como true
e a propriedade editable
de DataGrid também for true
, os itens em uma coluna serão editáveis e poderão ser individualmente editados ao clicar em um item ou ao navegar para o item usando o Tab e as teclas de seta.
O valor padrão é true.
editorDataField | propriedade |
public var editorDataField:String = "text"
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Identifica o nome da propriedade do editor de itens que contém os novos dados para o item da lista.
Por exemplo, o itemEditor
padrão é TextInput, para que o valor padrão da propriedade editorDataField
seja "text"
. Esse valor especifica a propriedade text
do componente TextInput.
O valor padrão é "text".
headerRenderer | propriedade |
headerRenderer:Object
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Classe usada para renderizar o cabeçalho dessa coluna.
O tipo dessa propriedade pode ser Class, Sprite ou String. Se o tipo de propriedade for String, o valor da string deve ser um nome de classe totalmente qualificado.
O valor padrão é null.
Implementação
public function get headerRenderer():Object
public function set headerRenderer(value:Object):void
Elementos da API relacionados
headerText | propriedade |
headerText:String
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Nome da coluna a ser exibido no cabeçalho da coluna. Por padrão, o componente DataGrid usa o valor da propriedade dataField
como o nome da coluna.
Implementação
public function get headerText():String
public function set headerText(value:String):void
Exemplo ( Como usar este exemplo )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var dp:DataProvider = new DataProvider(); dp.addItem({name:"Person A", sales:13453}); dp.addItem({name:"Person B", sales:23432}); dp.addItem({name:"Person C", sales:9454}); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Employee:"; var salesCol:DataGridColumn = new DataGridColumn("sales"); salesCol.headerText = "Sales:"; salesCol.labelFunction = currencyFormatter; salesCol.sortOptions = Array.NUMERIC; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(salesCol); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(320, 240); addChild(myDataGrid); function currencyFormatter(item:Object):String { return "$" + item.sales.toFixed(0); }
imeMode | propriedade |
imeMode:String
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Modo do editor de métodos de entrada (IME). O IME permite que os usuários insiram texto em chinês, japonês e coreano. A classe flash.system.IMEConversionMode define as constantes a serem usadas como os valores válidos dessa propriedade.
Se essa propriedade for null
, o modo do IME é definido como o valor da propriedade imeMode
do componente DataGrid.
O valor padrão é null.
Implementação
public function get imeMode():String
public function set imeMode(value:String):void
Elementos da API relacionados
itemEditor | propriedade |
public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica a classe das ocorrências do editor de itens a serem usadas para a coluna, quando ela for editável. O tipo dessa propriedade pode ser Class, Sprite ou String. Se o tipo de propriedade for String, o valor da string deve ser um nome de classe totalmente qualificado.
O valor padrão é "fl.controls.dataGridClasses.DataGridCellEditor".
Exemplo ( Como usar este exemplo )
import fl.controls.dataGridClasses.DataGridColumn; var dgc:DataGridColumn = new DataGridColumn("Field"); dgc.itemEditor = "MyCustomItemEditorClass"; dg.addColumn(dgc);
labelFunction | propriedade |
labelFunction:Function
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Função que determina o texto a ser exibido nesta coluna. Por padrão, a coluna exibe o texto do campo de dados que corresponde ao nome da coluna. Entretanto, uma coluna também pode ser usada para exibir o texto de mais de um campo de dados ou para exibir o conteúdo que não está no formato adequado. Isso pode ser feito usando a propriedade labelFunction
para especificar uma função de retorno de chamada.
Se ambas as propriedades, labelFunction
e labelField
, forem definidas, a labelFunction
tem prioridade.
O valor padrão é null.
Implementação
public function get labelFunction():Function
public function set labelFunction(value:Function):void
Exemplo ( Como usar este exemplo )
import fl.controls.DataGrid; import fl.controls.ScrollPolicy; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var i:uint; var totalRows:uint = 16; var dp:DataProvider = new DataProvider(); for (i = 0; i < totalRows; i++) { dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()}); } var c1:DataGridColumn = new DataGridColumn("col1"); c1.sortOptions = Array.NUMERIC; var c2:DataGridColumn = new DataGridColumn("col2"); c2.sortOptions = Array.NUMERIC; var c3:DataGridColumn = new DataGridColumn("col3"); c3.sortOptions = Array.NUMERIC; c3.labelFunction = currencyFormatter; var dg:DataGrid = new DataGrid(); dg.setSize(200, 300); dg.addColumn(c1); dg.addColumn(c2); dg.addColumn(c3); dg.dataProvider = dp; addChild(dg); function getRandomNumber():Number { return Math.random() * 100; } function currencyFormatter(data:Object):String { var value:Number = Number(data.col3); return "$" + value.toFixed(2); }
labelFunction
e sortCompareFunction
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var data:XML = <data> <item name="Employee A" isManager="1" /> <item name="Employee B" isManager="0" /> <item name="Employee C" isManager="1" /> </data>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); nameDGC.sortCompareFunction = isManager; nameDGC.labelFunction = nameLabelFunction; var myDataGrid:DataGrid = new DataGrid() myDataGrid.addColumn(nameDGC); myDataGrid.dataProvider = dp; myDataGrid.width = 200; myDataGrid.rowCount = myDataGrid.length; myDataGrid.move(10, 10); addChild(myDataGrid); function nameLabelFunction(item:Object):String { var managerString:String = ""; if (item.isManager == "1") { managerString = " (Manager)"; } return item.name + managerString; } function isManager(itemA:Object, itemB:Object):int { if (itemA.isManager > itemB.isManager) { return -1; } else if (itemA.isManager < itemB.isManager) { return 1; } else { return 0; } }
minWidth | propriedade |
minWidth:Number
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Largura mínima da coluna, em pixels.
O valor padrão é 20.
Implementação
public function get minWidth():Number
public function set minWidth(value:Number):void
Elementos da API relacionados
Exemplo ( Como usar este exemplo )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var data:XML = <data> <row col1="item 1.A" col2="item 1.B" col3="item 1.C" /> <row col1="item 2.A" col2="item 2.B" col3="item 2.C" /> <row col1="item 3.A" col2="item 3.B" col3="item 3.C" /> </data>; var dp:DataProvider = new DataProvider(data); var c1:DataGridColumn = new DataGridColumn("col1"); c1.minWidth = 100; var c2:DataGridColumn = new DataGridColumn("col2"); var c3:DataGridColumn = new DataGridColumn("col3"); var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(c1); myDataGrid.addColumn(c2); myDataGrid.addColumn(c3); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(300, 200); myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler); addChild(myDataGrid); function columnStretchHandler(event:DataGridEvent):void { var column:DataGridColumn; for each (column in myDataGrid.columns) { trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth); } trace("---"); }
resizable | propriedade |
public var resizable:Boolean = true
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se o usuário tem permissão para alterar a largura da coluna. Um valor de true
indica que o usuário pode alterar a largura da coluna; um valor de false
indica que ele não pode fazer isso.
O valor padrão é true.
sortable | propriedade |
public var sortable:Boolean = true
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se o usuário pode clicar no cabeçalho da coluna atual para classificar o provedor de dados. Um valor de true
indica que a coluna pode ser classificada ao clicar em seu cabeçalho; um valor de false
indica que isso não pode ser feito.
O valor padrão é true.
Exemplo ( Como usar este exemplo )
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var data:XML = <dataProvider> <data col1="Person A" col2="11.383" /> <data col1="Person B" col2="3.399" /> <data col1="Person C" col2="25.624" /> </dataProvider> var dp:DataProvider = new DataProvider(data); var c1:DataGridColumn = new DataGridColumn("col1"); var c2:DataGridColumn = new DataGridColumn("col2"); c2.sortable = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(c1); myDataGrid.addColumn(c2); myDataGrid.dataProvider = dp; myDataGrid.move(10, 10); myDataGrid.setSize(160, 120); addChild(myDataGrid);
sortable
da coluna da grade de dados como false
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; import fl.events.DataGridEvent; var xmlDP:XML = <items> <item name="Person 1" bio="Person 1 bio" /> <item name="Person 2" bio="Person 2 bio" /> </items>; var dp:DataProvider = new DataProvider(xmlDP); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Name:"; var bioCol:DataGridColumn = new DataGridColumn("bio"); bioCol.headerText = "Bio:"; bioCol.sortable = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(bioCol); myDataGrid.dataProvider = dp; myDataGrid.rowCount = dp.length; myDataGrid.width = 200; myDataGrid.move(10, 10); myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler); addChild(myDataGrid); function headerReleaseHandler(event:DataGridEvent):void { var myDG:DataGrid = event.currentTarget as DataGrid; trace("dataField:" + event.dataField); trace("columnIndex:" + event.columnIndex); trace("{DataGrid}.sortDescending:" + myDG.sortDescending); trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending); trace(""); }
sortCompareFunction | propriedade |
sortCompareFunction:Function
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Função de retorno de chamada que é chamada durante a classificação dos dados na coluna. Se essa propriedade não for especificada, os dados são classificados por string ou número, dependendo da propriedade sortOptions
. Quando especificada, a propriedade sortCompareFunction
permite que você crie seu método personalizado de classificação para a coluna da grade de dados atual.
O valor padrão é null.
Implementação
public function get sortCompareFunction():Function
public function set sortCompareFunction(value:Function):void
Elementos da API relacionados
Exemplo ( Como usar este exemplo )
labelFunction
e sortCompareFunction
:
import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var data:XML = <data> <item name="Employee A" isManager="1" /> <item name="Employee B" isManager="0" /> <item name="Employee C" isManager="1" /> </data>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); nameDGC.sortCompareFunction = isManager; nameDGC.labelFunction = nameLabelFunction; var myDataGrid:DataGrid = new DataGrid() myDataGrid.addColumn(nameDGC); myDataGrid.dataProvider = dp; myDataGrid.width = 200; myDataGrid.rowCount = myDataGrid.length; myDataGrid.move(10, 10); addChild(myDataGrid); function nameLabelFunction(item:Object):String { var managerString:String = ""; if (item.isManager == "1") { managerString = " (Manager)"; } return item.name + managerString; } function isManager(itemA:Object, itemB:Object):int { if (itemA.isManager > itemB.isManager) { return -1; } else if (itemA.isManager < itemB.isManager) { return 1; } else { return 0; } }
sortDescending | propriedade |
public var sortDescending:Boolean = false
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se DataGridColumn deve ser classificado em ordem crescente ou decrescente. Um valor de true
indica que o DataGridColumn é classificado em ordem decrescente; um valor de false
indica que sua classificação é em ordem crescente.
O valor padrão é false.
sortOptions | propriedade |
public var sortOptions:uint = 0
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Uma ou mais constantes definidas, identificadas pelo nome ou número e separadas pelo operador OR (|) em nível de bits. Essas constantes são usadas para especificar a operação de classificação.
O valor padrão é 0.
Elementos da API relacionados
Exemplo ( Como usar este exemplo )
sortOptions
para especificar que uma coluna da grade de dados deve ser classificada em ordem numérica:
import fl.data.DataProvider; import fl.controls.dataGridClasses.DataGridColumn; var data:XML = <players> <player name="Player 1" score="1234" /> <player name="Player 2" score="198" /> <player name="Player 3" score="987" /> </players>; var dp:DataProvider = new DataProvider(data); var nameDGC:DataGridColumn = new DataGridColumn("name"); var scoreDGC:DataGridColumn = new DataGridColumn("score"); scoreDGC.sortOptions = Array.NUMERIC; dg.addColumn(nameDGC); dg.addColumn(scoreDGC); dg.dataProvider = dp;
visible | propriedade |
visible:Boolean
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se a coluna é visível. Um valor de true
indica que a coluna é visível; um valor de false
indica que não é.
O valor padrão é true.
Implementação
public function get visible():Boolean
public function set visible(value:Boolean):void
Exemplo ( Como usar este exemplo )
visible
de cada uma dessas colunas clicando na ocorrência Button correspondente no Palco.
import fl.controls.Button; import fl.controls.DataGrid; import fl.controls.dataGridClasses.DataGridColumn; import fl.data.DataProvider; var dp:DataProvider = new DataProvider(); dp.addItem({name:"Person A", average:0.297}); dp.addItem({name:"Person B", average:0.288}); dp.addItem({name:"Person C", average:0.310}); var nameCol:DataGridColumn = new DataGridColumn("name"); nameCol.headerText = "Name:"; var averageCol:DataGridColumn = new DataGridColumn("average"); averageCol.headerText = "Average:"; averageCol.labelFunction = numberFormatter; averageCol.sortOptions = Array.NUMERIC; averageCol.visible = false; var myDataGrid:DataGrid = new DataGrid(); myDataGrid.addColumn(nameCol); myDataGrid.addColumn(averageCol); myDataGrid.dataProvider = dp; myDataGrid.rowCount = dp.length; myDataGrid.width = 320; myDataGrid.move(10, 10); addChild(myDataGrid); var nameButton:Button = new Button(); nameButton.label = "Toggle name"; nameButton.toggle = true; nameButton.selected = nameCol.visible; nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10); nameButton.addEventListener(Event.CHANGE, changeHandler); addChild(nameButton); var averageButton:Button = new Button(); averageButton.label = "Toggle average"; averageButton.toggle = true; averageButton.selected = averageCol.visible; averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y); averageButton.addEventListener(Event.CHANGE, changeHandler); addChild(averageButton); function numberFormatter(item:Object):String { return Number(item.average).toFixed(3); } function changeHandler(event:Event):void { var colIndex:int = -2; var col:DataGridColumn; switch (event.currentTarget) { case nameButton: colIndex = myDataGrid.getColumnIndex("name"); break; case averageButton: colIndex = myDataGrid.getColumnIndex("average"); break; default: return; } if (colIndex > -1) { col = myDataGrid.getColumnAt(colIndex); col.visible = !col.visible; myDataGrid.removeColumnAt(colIndex); myDataGrid.addColumnAt(col, colIndex); } myDataGrid.spaceColumnsEqually(); }
width | propriedade |
width:Number
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Largura da coluna, em pixels.
O valor padrão é 100.
Implementação
public function get width():Number
public function set width(value:Number):void
Elementos da API relacionados
DataGridColumn | () | Construtor |
public function DataGridColumn(columnName:String = null)
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Cria uma nova ocorrência de DataGridColumn.
ParâmetroscolumnName:String (default = null ) — Nome da coluna a ser exibido no cabeçalho da coluna. Se nenhum nome for especificado, o valor dataField será usado.
|
Elementos da API relacionados
itemToLabel | () | método |
public function itemToLabel(data:Object):String
Versão da linguagem: | ActionScript 3.0 |
Versão de produto: | Flash CS3 |
Versões de runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Retorna a string exibida pelo renderizador de itens para o objeto de dados especificado. Se o DataGridColumn ou seu componente DataGrid tiver uma propriedade labelFunction
não nula, ele aplicará a função ao objeto de dados. Caso contrário, o método extrai o conteúdo do campo que é especificado pela propriedade dataField
ou obtém o valor da string do objeto de dados. Se o método não puder converter o parâmetro em uma string, ele retornará um espaço único.
Parâmetros
data:Object — O objeto a ser renderizado.
|
String — String que pode ser exibida com base no objeto data especificado.
|
toString | () | método |
- Adicione os componentes DataGrid e Button à biblioteca.
- Salve esse código como DataGridColumnExample.as no mesmo diretório que FLA.
- Defina DocumentClass em FLA como DataGridColumnExample.
package { import flash.display.Sprite; import flash.events.MouseEvent; import fl.data.DataProvider; import fl.events.DataChangeEvent; import fl.controls.DataGrid; import fl.controls.Button; import fl.controls.dataGridClasses.DataGridColumn; public class DataGridColumnExample extends Sprite { private var dg:DataGrid; private var dp:DataProvider; private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ]; public function DataGridColumnExample() { dp = new DataProvider(); dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged); dg = new DataGrid(); addChild(dg); dg.move(10,45); dg.setSize(450,300); dg.addColumn(new DataGridColumn("name")); dg.addColumn(new DataGridColumn("phone")); dg.addColumn(new DataGridColumn("email")); var firstColumn = dg.columns[0]; firstColumn.resizable = false; var secondColumn = dg.columns[1]; secondColumn.sortable = false; var thirdColumn = dg.columns[2]; thirdColumn.sortable = false; var addContactBtn:Button = new Button(); addContactBtn.label = "Add Contact"; addContactBtn.move(10,10); addContactBtn.addEventListener(MouseEvent.CLICK, addContact); addChild(addContactBtn); } private function getRandomPhone():String { return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit(); } private function randomDigit():String { return String(Math.round(Math.random()*10)%10); } private function getRandomName():String { return names[Math.round(Math.random()*names.length)%names.length]; } private function addContact(e:MouseEvent):void { var randomName:String = getRandomName() dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } ); } private function dataChanged(e:DataChangeEvent):void { var changedItems:Array = e.items; dg.addItem(changedItems[0]); } } }
Wed Jun 13 2018, 11:10 AM Z