TextLineMetrics  - AS3

Wydłużenie górne tekstu jest to odległość między linią bazową a górną krawędzią wiersza tekstowego (w pikselach). Sprawdź wartość „Wydłużenie górne” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Wydłużenie dolne tekstu jest to odległość między linią bazową a dolną krawędzią wiersza tekstowego (w pikselach). Sprawdź wartość „Wydłużenie dolne” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Wysokość tekstu w zaznaczonych wierszach (niekoniecznie całego tekstu), wyrażona w pikselach. Wysokość wiersza tekstowego nie obejmuje wysokości odstępu. Sprawdź wartość „Wysokość wiersza” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Interlinia jest to wielkość odstępu między wierszami tekstu. Sprawdź wartość „Interlinia” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Szerokość tekstu w zaznaczonych wierszach (niekoniecznie całego tekstu), wyrażona w pikselach. Szerokość wiersza tekstowego nie jest równa szerokości pola tekstowego. Szerokość wiersza tekstowego stanowi szerokość pola tekstowego pomniejszoną o 4 piksele szerokości odstępu (po 2 piksele po każdej stronie). Sprawdź wartość „Szerokość wiersza tekstowego” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Współrzędna x pierwszego znaku (od lewej strony, w pikselach). Ta wartość uwzględnia margines, wcięcie (jeśli istnieje) oraz wartości dla szerokości odstępu. Sprawdź wartość „Położenie X wiersza tekstowego” na diagramie w ogólnym opisie dla tej klasy.

Powiązane elementy interfejsu API

Tworzy obiekt TextLineMetrics. Obiekt TextLineMetrics zawiera informacje o wymiarach wiersza w polu tekstowym. Obiekty tej klasy są zwracane przez metodę flash.text.TextField.getLineMetrics().

Informacje o właściwościach w kontekście przedstawia diagram w ogólnym opisie tej klasy.

Powiązane elementy interfejsu API

1. Utwórz właściwość typu TextField o nazwie label.
2. Konstruktor wywołuje metodę configureAssets(), która:
   • Ustawia wyrównanie stołu montażowego do górnego lewego rogu bez skalowania.
   • Tworzy nowy obiekt TextField o nazwie label.
   • Włącza tło obiektu label i ustawia kolor biały.
   • Umożliwia rozmieszczenie w obiekcie label tekstu w wielu wierszach za pomocą automatycznego zawijania.
   • Przypisuje wyniki wywołania metody getLabelText() do właściwości text obiektu label. Metoda getLabelText() tworzy zmienną typu XML i przypisuje ją do węzła XML o nazwie body zapełnianego długą instrukcją.
   • Dodaje obiekt label do wyświetlanej listy za pomocą metodyaddChild().
3. Następnie dodawana jest metoda o nazwie resizeHandler(), która nasłuchuje wykonanych na stole montażowym zdarzeń resize. Podczas każdej zmiany wielkości okna programu Flash Player, zostaje wywołane zdarzenie RESIZE i uruchamiane są następujące metody:
   • Metoda draw(), która odpowiada za umieszczenie obiektulabel na środku stołu montażowego i otoczenie go 10-pikselowym buforem.
   • metoda setTimeout(), która po krótkiej chwili wywołuje metodę showMetrics(). Ta krótka chwila jest potrzebna na ukończenie zdarzenia RESIZE i przerysowanie stołu montażowego, po czym możliwa jest aktualizacja wymiarów wiersza.
   • Metoda showMetrics() przypisuje zmienną TextLineMetrics o nazwie metrics do wyników wywołania funkcji getLineMetrics(), a następnie ta zmienna zostaje przekazana do nowej instancji LineMetricsReader o nazwie reader. Następnie obydwie zmienne wykorzystuje się w wywołaniach metody trace() w celu wydruku pierwszego (i jedynego) wiersza obiektu label oraz informacji instancji LineMetricsReader za pomocą metody toString().
4. Konstruktor wywołuje pojedynczą dyspozycję zdarzenia resize w celu poprawnego narysowania obiektu label podczas pierwszego ładowania pliku SWF.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}