WorkerDomain  - AS3

Wystąpienie klasy WorkerDomain, w której działa uruchomiony kod. Jest to jedyny obiekt WorkerDomain w aplikacji.

Wskazuje, czy bieżący kontekst środowiska wykonawczego obsługuje klasę WorkerDomain i obiekty Worker na potrzeby współbieżnego wykonywania kodu.

Jeśli współbieżność jest dostępna, ta właściwość ma wartość true.

Tworzy nowe wystąpienie klasy Worker na podstawie bajtów pliku SWF.

Każdy proces roboczy jest tworzony i wykonywany jako odizolowana aplikacja SWF. Aby utworzyć wystąpienie klasy Worker, należy pobrać bajty pliku SWF jako wystąpienie klasy ByteArray i przekazać je do tej metody. Istnieją trzy typowe metody uzyskiwania dostępu do bajtów pliku SWF stosowane w takich sytuacjach:

• Użycie znacznika meta [Embed] i osadzenie pliku SWF w aplikacji jako obiektu ByteArray:

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Wczytanie zewnętrznego pliku SWF przy użyciu klasy URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Użycie pojedynczego pliku SWF jako pierwotnego procesu roboczego i procesu roboczego działającego w tle:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Utworzenie obiektu Worker za pomocą metody createWorker() nie powoduje rozpoczęcia wykonywania procesu roboczego. Aby rozpocząć wykonywanie kodu procesu roboczego, należy wywołać metodę start() obiektu Worker.

Przydatność procesów roboczych polega na możliwości redukcji prawdopodobieństwa pominięcia klatek animacji spowodowanego blokowaniem głównego wątku renderującego przez inny kod. Jednak procesy robocze wymagają większej ilości pamięci systemowej i zwiększają obciążenie procesora, co może mieć negatywny wpływ na ogólną wydajność aplikacji. Każdy proces roboczy używa własnego wystąpienia maszyny wirtualnej środowiska wykonawczego, dlatego nawet niewielki obiekt może wprowadzać duży narzut związany z dodatkowymi operacjami. Wprowadzając do kodu procesy robocze, należy go przetestować na wszystkich platformach docelowych i upewnić się, że obciążenie systemu nie jest za duże. Firma Adobe zaleca, aby w typowych sytuacjach nie używać więcej niż dwóch procesów roboczych działających w tle.

Parametry

Zapewnia dostęp do zestawu aktualnie uruchomionych procesów roboczych w klasie WorkerDomain (takich, gdzie właściwość state wystąpienia klasy Worker ma wartość WorkerState.RUNNING).