FocusManager  - AS3 Flash

Pobiera lub ustawia bieżący przycisk domyślny.

Przycisk domyślny to przycisk formularza, który wywołuje zdarzenie click po naciśnięciu klawisza Enter, w zależności od tego, który składnik jest w danej chwili aktywny.

Pobiera lub ustawia wartość określającą, czy przycisk domyślny jest włączony. Jeśli ta wartość jest ustawiona na true, menedżer aktywności monitoruje klawisz Enter i wywołuje zdarzenie click dla przycisku domyślnego w wypadku naciśnięcia klawisza Enter, gdy aktywny jest akurat składnik inny niż Button. Jeśli ta wartość jest ustawiona na false, menedżer aktywności nie monitoruje klawisza Enter. Składniki, które korzystają z klawisza Enter, ustawiają tę właściwość na false, aby zapobiec wywoływaniu zdarzenia click dla przycisku domyślnego (o ile istnieje), gdy użytkownik naciśnie klawisz Enter.

Podstawowy obiekt DisplayObjectContainer dla interfejsu IFocusManager, zazwyczaj stół montażowy.

Pobiera unikatowy indeks aktywacji klawiszem Tab, który ma być używany w tej pętli aktywacji.

Pobiera lub ustawia wartość określającą, czy aktywny składnik powinien być oznaczony wizualnym wskaźnikiem aktywności.

Tworzy nowe wystąpienie składnika FocusManager.

Menedżer aktywności zarządza aktywnością w obiektach podrzędnych obiektu DisplayObjectContainer.

Uaktywnia instancję klasy.

Instancja klasy FocusManager dodaje detektory zdarzeń umożliwiające jej monitorowanie interakcji z klawiaturą i myszą związanych ze zmianami aktywności.

Dezaktywuje składnik FocusManager.

Instancja klasy FocusManager usuwa detektory zdarzeń umożliwiające jej monitorowanie interakcji z klawiaturą i myszą związanych ze zmianami aktywności.

Pobiera obiekt interaktywny zawierający dany obiekt, jeśli istnieje. Odtwarzacz może aktywować składnik podrzędny składnika programu Flash; ta metoda określa, który obiekt interaktywny jest aktywny z perspektywy składnika.

Parametry

Pobiera obiekt interaktywny, który jest w danej chwili aktywny. Firma Adobe zaleca wywoływanie tej metody zamiast korzystania z obiektu Stage, ponieważ wskazuje ona precyzyjnie aktywny składnik. Obiekt Stage może zwrócić składnik podrzędny aktywnego składnika.

Pobiera obiekt interaktywny, który stałby się aktywny, gdyby użytkownik nacisnął klawisz Tab w celu przejścia do następnego obiektu. Jeśli w aplikacji nie ma innych poprawnych obiektów, ta metoda pobiera obiekt, który jest obecnie aktywny.

Parametry

Ustawia wartość showFocusIndicator na false i usuwa wizualny wskaźnik aktywności z aktywnego obiektu, jeśli taki istnieje.

Czyni aktywnym składnik IFocusManagerComponent. Ta metoda nie sprawdza widoczności, stanu włączenia ani innych warunków.

Parametry

Ustawia wartość showFocusIndicator na true i rysuje wizualny wskaźnik aktywności na aktywnym obiekcie, jeśli taki istnieje.

W celu uruchomienia przykładu należy wykonać poniższe czynności:

1. Dodaj składnik TextInput do biblioteki.
2. Zapisz ten kod pod nazwą FocusManagerExample.as w tym samym katalogu, co plik FLA.
3. W pliku FLA ustaw klasę dokumentu na FocusManagerExample.

package
{
    import fl.controls.TextInput;
    import fl.managers.FocusManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.utils.Timer;

    public class FocusManagerExample extends Sprite 
    {
        private var fm:FocusManager;
        
        public function FocusManagerExample() {
            buildGridOfTextInputs();

            fm = new FocusManager(this);
            var t:Timer = new Timer(1000);
            t.addEventListener(TimerEvent.TIMER,secondPassed);
            t.start();
        }
        private function buildGridOfTextInputs():void {
            var rowSpacing:uint = 30;
            var colSpacing:uint = 110;
            var totalRows:uint = 4;
            var totalCols:uint = 3;
            var i:uint;
            
            for(i = 0; i < totalRows * totalCols; i++) {
                var ti:TextInput = new TextInput()
                ti.name = "component"+i.toString();
                ti.addEventListener(FocusEvent.FOCUS_IN,focusChange);
                ti.setSize(100,20);
                ti.x = 10 + ((i % totalCols) * colSpacing);
                ti.y = 10 + (Math.floor(i / totalCols) * rowSpacing);
                ti.tabEnabled = true;
                addChild(ti);
            }
        }
        private function secondPassed(e:TimerEvent):void {
            var nextComponent:InteractiveObject = fm.getNextFocusManagerComponent();
            fm.setFocus(nextComponent);    
        }
        
        private function focusChange(e:FocusEvent):void {
            trace("Focus change: " + e.target.name);
        }
    }
}