XML-variabelen initialiseren

Flash Player 9 of hoger, Adobe AIR 1.0 of hoger

U kunt als volgt een letterlijke XML toewijzen aan een object XML:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Zoals in het volgende fragment wordt getoond, kunt u ook de constructor new gebruiken om een instantie van een object XML te maken van een tekenreeks die XML-gegevens bevat:

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Wanneer de XML-gegevens in de tekenreeks niet correct zijn samengesteld (wanneer bijvoorbeeld een afsluitingstag ontbreekt), wordt een uitvoeringsfout weergegeven.

U kunt gegevens ook via verwijzing (van andere variabelen) in een object XML doorgeven, zoals in het volgende voorbeeld wordt getoond:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Met de klasse URLLoad kunt u XML-gegevens van een URL laden, zoals in het volgende voorbeeld wordt getoond:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Met de klasse XMLSocket kunt u XML-gegevens lezen van een socketverbinding. Zie de beschrijving van de klasse XMLSocket in de Naslaggids voor ActionScript 3.0 voor het Adobe Flash-platform voor meer informatie.