XML-objecten samenstellen en transformeren

Flash Player 9 of hoger, Adobe AIR 1.0 of hoger

Met de methode prependChild() of de methode appendChild() kunt u een eigenschap toevoegen aan het begin of einde van een lijst met eigenschappen van een object XML, zoals in het volgende voorbeeld wordt getoond:

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

U kunt als volgt de methode insertChildBefore() of de methode insertChildAfter() gebruiken om een eigenschap toe te voegen voor of na een bepaalde eigenschap:

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Zoals in het volgende voorbeeld wordt getoond, kunt u ook de accoladeoperatoren ( { en } ) gebruiken om gegevens via verwijzing (van andere variabelen) door te geven bij het samenstellen van XML-objecten:

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

U kunt eigenschappen en kenmerken toewijzen aan een object XML met de operator = , zoals in het volgende voorbeeld:

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Hiermee wordt het XML-object x ingesteld op het volgende:

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Met de operatoren + en += kunt u XMLList-objecten samenvoegen.

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Hiermee wordt het XMLList-object xList ingesteld op het volgende:

<a>test1</a> 
<b>test2</b> 
<c>test3</c>