FlowOperationEvent  - AS3

De gegenereerde fout (indien van toepassing) tijdens een bewerking. Als er tijdens een bewerking een fout optreedt, wordt een verwijzing naar het foutobject toegevoegd aan de gebeurtenis FLOW_OPERATION_END. Hierdoor hebt u de gelegenheid om de fout op te lossen, voordat deze in Flash Player optreedt. Als u de gebeurtenis annuleert, zal de fout niet in optreden in Flash Player.

Bewerkingen kunnen met behulp van nesting worden samengevoegd tot samengestelde bewerkingen. Deze markering beschrijft het nestingniveau van de bewerking.

De bewerking die op het punt van starten staat of die net is geëindigd.

Verwante API-elementen

Maakt een gebeurtenisobject dat informatie bevat over een flowbewerking.

Definieert de waarde van de eigenschap type van een flowOperationBegin-gebeurtenisobject. Wordt verzonden voordat een bewerking wordt uitgevoerd. Door het annuleren van deze gebeurtenis wordt de bewerking geblokkeerd.

Definieert de waarde van de eigenschap type van een flowOperationComplete-gebeurtenisobject. Wordt verzonden nadat alle bewerkingen, inclusief bewerkingen in behandeling en samengestelde bewerkingen, voltooid zijn, de compositie is voltooid en de weergave wordt verschoven.

Definieert de waarde van de eigenschap type van een flowOperationEnd-gebeurtenisobject. Wordt verzonden nadat een bewerking is uitgevoerd. Fouten worden opgeslagen in OperationEvent.error. Als er een fout is, zorgt het annuleren van deze gebeurtenis ervoor dat de fout niet opnieuw optreedt. Doorgaans zijn alle fouten waarschijnlijk onherstelbaar.

Het wijzigen van een bewerking mislukt mogelijk op dat moment (nadat de bewerking is uitgevoerd).

In dit voorbeeld wordt weergegeven hoe u een gebeurtenishandler kunt maken die luistert naar het begin en einde van een tekstflowbewerking. De twee belangrijkste stappen zijn het aanroepen van de methode addEventListener() voor de tekstflow en het maken van een gebeurtenishandlerfunctie.

De aanroep naar addEventListener() wordt uitgevoerd naar de TextFlow-instantie. U kunt de eenvoudige tekenreeks "flowOperationBegin" of "flowOperationEnd" gebruiken, maar het is veiliger om respectievelijk de statische constante FlowOperationEvent.FLOW_OPERATION_BEGIN of FlowOperationEvent.FLOW_OPERATION_END te gebruiken.

De gebeurtenishandlerfuncties in dit voorbeeld zijn opBeginHandler() en opEndHandler(). De opBeginHandler()-methode gebruikt de trace()-functie om een trace-instructie te maken die aangeeft dat een plakbewerking is gestart. De opEndHandler()-methode gebruikt ook de trace()-functie, maar maakt alleen een trace-instructie als er een fout optreedt.

package flashx.textLayout.events.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.compose.StandardFlowComposer;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.events.FlowOperationEvent;
    import flashx.textLayout.operations.FlowOperation;
    import flashx.textLayout.operations.PasteOperation;
    import flashx.undo.UndoManager;

    public class FlowOperationEvent_example extends Sprite
    {
        private var inputContainer:Sprite;
        private var inputTextFlow:TextFlow;
        private var inputController:ContainerController;
        private var inputEditManager:EditManager;
        private var inputUndoManager:UndoManager;

        public function FlowOperationEvent_example()
        {
            var replaceText:String = "paste text here";
            inputTextFlow = new TextFlow();

            inputContainer = new Sprite();
            inputContainer.x = 30;
            inputContainer.y = 100;

             this.stage.addChild( inputContainer );

            inputController = new ContainerController(inputContainer, 225, 20);
            inputController.verticalScrollPolicy = flashx.textLayout.container.ScrollPolicy.OFF;

            inputTextFlow = TextConverter.importToFlow(replaceText, TextConverter.PLAIN_TEXT_FORMAT);
            inputTextFlow.flowComposer = new StandardFlowComposer(); 
            inputTextFlow.flowComposer.addController(inputController);

            inputUndoManager = new UndoManager();
            inputEditManager = new EditManager(inputUndoManager);
            inputTextFlow.interactionManager = inputEditManager;

            inputTextFlow.addEventListener(FlowOperationEvent.FLOW_OPERATION_BEGIN, opBeginHandler);
            inputTextFlow.addEventListener(FlowOperationEvent.FLOW_OPERATION_END, opEndHandler);
            inputTextFlow.flowComposer.updateAllControllers();
        }

        private function opBeginHandler(evt:FlowOperationEvent):void { 
            var flowOp:FlowOperation = evt.operation; 
            if(flowOp is PasteOperation) {
                trace("You can cancel or modify the paste operation in this event handler.");
            }
        }

        private function opEndHandler(evt:FlowOperationEvent):void { 
            var flowOp:FlowOperation = evt.operation; 
            if(evt.error) {
                trace("You can handle the error here and call preventDefault().");
            }
        }
    }
}