| Pakket | flash.text.engine |
| Klasse | public final class TextElement |
| Overerving | TextElement  ContentElement Object |
| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
content van een TextBlock-object om een blok tekst te maken. Wijst dit toe aan een GroupElement-object om het te combineren met andere grafische en tekstelementen als eenheid. Gebruik de klasse ElementFormat om de tekst op te maken.
Verwante API-elementen
Openbare eigenschappen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
 | constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| elementFormat : ElementFormat
Het ElementFormat-object dat voor het element wordt gebruikt. | ContentElement | |
| eventMirror : EventDispatcher
Het object EventDispatcher dat kopieën ontvangt van elke gebeurtenis die naar geldige tekstregels wordt verzonden die op dit content-element zijn gebaseerd. | ContentElement | |
| groupElement : GroupElement [alleen-lezen]
Het GroupElement-object dat dit element bevat, of null als het niet in een groep is. | ContentElement | |
| rawText : String [alleen-lezen]
Een kopie van de tekst in het element, inclusief U+FDEF-tekens. | ContentElement | |
| text : String
Ontvangt de tekst die de inhoud van het element is. | TextElement | ||
| textBlock : flash.text.engine:TextBlock [alleen-lezen]
Het TextBlock waar dit element bij hoort. | ContentElement | |
| textBlockBeginIndex : int [alleen-lezen]
De index in het tekstblok van het eerste teken van dit element. | ContentElement | |
| textRotation : String
De rotatie die wordt toegepast op het element als een eenheid. | ContentElement | |
| userData : *
Hiermee kan de toepassing willekeurige gegevens aan het element koppelen. | ContentElement | |
Openbare methoden
| Methode | Gedefinieerd door | ||
|---|---|---|---|
TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")
Hiermee wordt een nieuwe instantie TextElement gemaakt. | TextElement | ||
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
Vervangt de met de parameters beginIndex en endIndex opgegeven tekenreeks door de inhoud van de parameter newText. | TextElement | ||
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
Openbare constanten
Eigenschapdetails
text | eigenschap |
Constructordetails
TextElement | () | Constructor |
public function TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Hiermee wordt een nieuwe instantie TextElement gemaakt.
Parameterstext:String (default = null)null.
| |
elementFormat:ElementFormat (default = null)null.
| |
eventMirror:EventDispatcher (default = null)EventDispatcher dat kopieën ontvangt van elke gebeurtenis die naar de tekstregels wordt verzonden die op dit contentelement zijn gebaseerd. De standaardwaarde is null.
| |
textRotation:String (default = "rotate0")TextRotation voor deze eigenschap. De standaardwaarde is TextRotation.ROTATE_0.
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt een TextElement-object gemaakt van een reeks tekst, opgemaakt met de lettergrootte 12 en de kleur rood (0xCC0000) en toegewezen aan de eigenschap
content van een TextBlock. De functie createLines() wordt aangeroepen om het blok tekst op te splitsen in regels van elk 150 pixels.
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.ElementFormat;
public class TextElementExample extends Sprite {
public function TextElementExample():void {
var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
"sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
"enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
"aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
"in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
"sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
"mollit anim id est laborum.";
var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
createLines(textBlock);
}
private function createLines(textBlock:TextBlock):void {
var yPos = 20;
var textLine:TextLine = textBlock.createTextLine (null, 150);
while (textLine)
{
addChild(textLine);
textLine.x = 15;
yPos += textLine.textHeight+2;
textLine.y = yPos;
textLine = textBlock.createTextLine(textLine, 150);
}
}
}
}
Methodedetails
replaceText | () | methode |
public function replaceText(beginIndex:int, endIndex:int, newText:String):void| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Vervangt de met de parameters beginIndex en endIndex opgegeven tekenreeks door de inhoud van de parameter newText. De waarden beginIndex en endIndex verwijzen naar de huidige inhoud van text.
Als u tekst wilt verwijderen, geeft u null door voor newText.
Als u tekst wilt invoegen, geeft u dezelfde waarde door voor beginIndex en endIndex. De nieuwe tekst wordt voor de opgegeven index ingevoegd.
Als u tekst wilt toevoegen, geeft u text.length voor beginIndex en endIndex door.
Als u alle tekst wilt instellen, geeft u 0 door voor beginIndex en text.length voor endIndex.
Parameters
beginIndex:int — De op nul gebaseerde indexwaarde voor de beginpositie van het vervangingsbereik.
| |
endIndex:int — De op nul gebaseerde indexwaarde na de eindpositie van het vervangingsbereik.
| |
newText:String — De tekst die moet worden gebruikt om het opgegeven tekenbereik te vervangen.
|
Gegenereerde uitzondering
RangeError — De opgegeven parameter beginIndex of endIndex bevindt zich buiten het bereik.
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld wordt
replaceText() meerdere keren aangeroepen voor het volgende:
- het invoegen van een tekenreeks aan het begin van de tekst
- het toevoegen van een tekenreeks aan het einde van de tekst
- het invoegen van een tekenreeks in het midden van de tekst
- het vervangen van de volledige tekst door nieuwe tekst
package {
import flash.display.Sprite;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.TextElement;
import flash.text.engine.TextBlock;
import flash.text.engine.TextLine;
public class TextElement_replaceTextExample extends Sprite {
public function TextElement_replaceTextExample():void {
var str:String = "0123456";
var fontDescription:FontDescription = new FontDescription("Arial");
var format:ElementFormat = new ElementFormat(fontDescription);
format.fontSize = 14;
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
textElement.replaceText(0, 0, "abc");
createLine(textBlock, 20); //"abc0123456"
textElement.replaceText(10, 10, "abc");
createLine(textBlock, 40); // "abc0123456abc"
textElement.replaceText(5, 8, "abc");
createLine(textBlock, 60); // "abc01abc56abc"
textElement.replaceText(0, 13, "abc");
createLine(textBlock, 80); // "abc"
textElement.replaceText(0, 3, "That's all she wrote!");
createLine(textBlock, 100); // "That's all she wrote" */
}
private function createLine(textBlock:TextBlock, y:Number):void {
var textLine:TextLine = textBlock.createTextLine(null, 150);
textLine.x = 10;
textLine.y = y;
addChild(textLine);
}
}
}
Wed Jun 13 2018, 11:42 AM Z