WorkerDomain  - AS3

코드가 현재 실행 중인 WorkerDomain 인스턴스입니다. 이는 응용 프로그램의 유일한 WorkerDomain입니다.

현재 런타임 컨텍스트에서 동시 코드 실행을 위해 WorkerDomain 및 Worker 객체를 지원하는지 여부를 나타냅니다.

동시성을 사용할 수 있는 경우 이 속성 값은 true입니다.

swf의 바이트에서 새 Worker 인스턴스를 만듭니다.

생성된 각각의 워커는 격리된 swf 응용 프로그램으로 실행됩니다. Worker 인스턴스를 만들려면 SWF 파일의 바이트를 ByteArray 인스턴스로 가져와 이 메서드로 전달합니다. 이를 위해 swf의 바이트에 액세스하는 일반적인 방법에는 다음과 같은 세 가지가 있습니다.

• [Embed] 메타태그를 사용하여 .swf 파일을 응용 프로그램에 ByteArray로 포함합니다.

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• URLLoader를 사용하여 외부 SWF 파일을 불러옵니다.

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 단일 swf를 최초 워커 및 백그라운드 워커로 모두 사용합니다.

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

createWorker()를 사용하여 Worker 객체를 만들면 워커의 실행이 시작되지 않습니다. 워커의 코드 실행을 시작하려면 Worker 객체의 start() 메서드를 호출합니다.

프레임 속도는 기본 렌더링 스레드가 다른 코드에 의해 차단될 때 감소할 수 있으며, 워커를 사용하면 이러한 문제를 최소화할 수 있습니다. 그러나 워커는 시스템 메모리 및 CPU를 추가로 점유하며 이는 곧 전반적인 응용 프로그램 성능의 저하로 이어질 수 있습니다. 각 워커에서는 자체의 런타임 가상 머신 인스턴스를 사용하므로 작은 워커도 큰 오버헤드를 일으킬 수 있습니다. 워커를 사용할 경우 모든 대상 플랫폼에서 해당 코드를 테스트하여 시스템에 추가되는 부담이 너무 크지 않은지 확인해야 합니다. 일반적인 상황에서 백그라운드 워커는 3개 이상 사용하지 않는 것이 좋습니다.

매개 변수

WorkerDomain에서 현재 실행 중인 워커 집합에 액세스할 수 있도록 합니다(Worker 인스턴스의 state 속성이 WorkerState.RUNNING임).