BlurFilter  - AS3

수평 흐림 효과의 정도를 나타냅니다. 유효한 값은 0부터 255(부동 소수점)까지입니다. 기본값은 4입니다. 2의 거듭제곱 값(예: 2, 4, 8, 16, 32 등)은 다른 값보다 빠르게 렌더링하도록 최적화되었습니다.

수직 흐림 효과의 정도를 나타냅니다. 유효한 값은 0부터 255(부동 소수점)까지입니다. 기본값은 4입니다. 2의 거듭제곱 값(예: 2, 4, 8, 16, 32 등)은 다른 값보다 빠르게 렌더링하도록 최적화되었습니다.

흐리게 처리하기를 실행하는 횟수입니다. 기본값은 BitmapFilterQuality.LOW로서 필터를 1회 적용하는 것과 동일합니다. 값 BitmapFilterQuality.MEDIUM은 필터를 2회 적용하고 값 BitmapFilterQuality.HIGH는 3회 적용합니다. 낮은 값을 가진 필터가 보다 빠르게 렌더링됩니다.

대부분의 응용 프로그램의 경우 quality 값을 낮음, 중간, 높음으로 설정하면 충분합니다. 15까지의 추가 숫자 값을 사용하여 흐림 효과의 적용 횟수를 늘릴 수 있으나 값이 커질수록 렌더링 속도가 느려집니다. quality 값을 올리는 대신 간단히 blurX 및 blurY 속성의 값을 올려도 보다 빠른 렌더링으로 유사한 효과를 얻을 수 있습니다.

다음과 같은 BitmapFilterQuality 상수를 사용하여 quality 속성의 값을 지정할 수 있습니다.

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

지정된 매개 변수를 사용하여 해당 필터를 초기화합니다. 기본값은 부드럽게 초점이 흐려진 이미지를 만들어냅니다.

이 필터 객체의 복사본을 반환합니다.

1. 필요한 클래스를 가져옵니다.
2. draw() 함수에서 사용할 세 가지 속성을 선언합니다. 이 함수는 흐림 필터를 적용할 객체를 그립니다.
3. 다음과 같은 기능을 하는 BlurFilterExample() 생성자 함수를 만듭니다.
   • 나중에 선언될 draw() 함수를 호출합니다.
   • filter 변수를 BitmapFilter 객체로 선언하고, 이 객체를 getBitmapFilter() 호출의 반환 값에 할당합니다.
   • 새 Array 객체 myFilters를 만들고 filter를 배열에 추가한 다음 myFilters를 BlurFilterExample 객체의 filters 속성에 할당합니다. 이것은 myFilters의 모든 필터에 적용되며, 이 경우에는 filter뿐입니다.
4. 필터의 속성을 만들고 설정하는 getBitmapFilter() 함수를 만듭니다.
5. draw() 함수를 만듭니다. 이 함수는 Sprite 클래스의 graphics 속성을 통해 액세스되는 Graphics 클래스의 메서드를 사용하여 사각형을 그립니다.

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}