Filtro bagliore con gradiente

Flash Player 9 e versioni successive, Adobe AIR 1.0 e versioni successive

La classe GradientGlowFilter consente di applicare un effetto di bagliore avanzato a oggetti di visualizzazione e oggetti BitmapData. L'effetto offre un maggiore controllo cromatico del bagliore e a propria volta produce un effetto bagliore più realistico. Inoltre, il filtro bagliore con gradiente consente di applicare un bagliore con gradiente ai bordi interni, esterni o superiore di un oggetto.

Nell'esempio seguente viene disegnato un cerchio sullo stage, a cui viene applicato un filtro bagliore con gradiente. Spostando il mouse più verso destra e verso il basso, la quantità di sfocatura aumenta rispettivamente in direzione orizzontale e verticale. Inoltre, ogni volta che si fa clic sullo stage, l'intensità della sfocatura aumenta. 

import flash.events.MouseEvent; 
import flash.filters.BitmapFilterQuality; 
import flash.filters.BitmapFilterType; 
import flash.filters.GradientGlowFilter; 
 
// Create a new Shape instance. 
var shape:Shape = new Shape(); 
 
// Draw the shape. 
shape.graphics.beginFill(0xFF0000, 100); 
shape.graphics.moveTo(0, 0); 
shape.graphics.lineTo(100, 0); 
shape.graphics.lineTo(100, 100); 
shape.graphics.lineTo(0, 100); 
shape.graphics.lineTo(0, 0); 
shape.graphics.endFill(); 
 
// Position the shape on the Stage. 
addChild(shape); 
shape.x = 100; 
shape.y = 100; 
 
// Define a gradient glow. 
var gradientGlow:GradientGlowFilter = new GradientGlowFilter(); 
gradientGlow.distance = 0; 
gradientGlow.angle = 45; 
gradientGlow.colors = [0x000000, 0xFF0000]; 
gradientGlow.alphas = [0, 1]; 
gradientGlow.ratios = [0, 255]; 
gradientGlow.blurX = 10; 
gradientGlow.blurY = 10; 
gradientGlow.strength = 2; 
gradientGlow.quality = BitmapFilterQuality.HIGH; 
gradientGlow.type = BitmapFilterType.OUTER; 
 
// Define functions to listen for two events. 
function onClick(event:MouseEvent):void 
{ 
    gradientGlow.strength++; 
    shape.filters = [gradientGlow]; 
} 
 
function onMouseMove(event:MouseEvent):void 
{ 
    gradientGlow.blurX = (stage.mouseX / stage.stageWidth) * 255; 
    gradientGlow.blurY = (stage.mouseY / stage.stageHeight) * 255; 
    shape.filters = [gradientGlow]; 
} 
stage.addEventListener(MouseEvent.CLICK, onClick); 
stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);