TextFlowTextLineFactory

Pacchetto	flashx.textLayout.factory
Classe	public class TextFlowTextLineFactory
Ereditarietà	TextFlowTextLineFactory TextLineFactoryBase Object

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

Flash Player 10, AIR 1.5

La classe TextFlowTextLineFactory consente di creare facilmente oggetti TextLine per visualizzare testo da un flusso di testo.

Le righe di testo sono statiche e vengono create in modo da adattarsi a un unico rettangolo di delimitazione, ma possono avere più paragrafi e formati, oltre a elementi grafici agganciati. Per creare oggetti TextLine direttamente da una stringa, utilizzate StringTextLineFactory.

Nota: quando si utilizzano elementi grafici agganciati, la proprietà source dell'oggetto InlineGraphicElement deve essere un'istanza di un oggetto DisplayObject o Class che rappresenta una risorsa incorporata. Non è possibile utilizzare oggetti URLRequest. La larghezza e l'altezza dell'elemento grafico agganciato, definite al momento della creazione della riga, vengono utilizzate per comporre il flusso.

Vedere gli esempi

Elementi API correlati

TextFlow
StringTextLineFactory

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		compositionBounds : Rectangle Il rettangolo all'interno del quale vengono create le righe di testo.	TextLineFactoryBase
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		horizontalScrollPolicy : String Specifica come vengono create le righe quando i limiti della composizione non sono abbastanza estesi.	TextLineFactoryBase
		isTruncated : Boolean [sola lettura] Indica se il testo è stato troncato quando sono state create le righe.	TextLineFactoryBase
		swfContext : ISWFContext L'istanza ISWFContext utilizzata per effettuare chiamate FTE, se necessarie.	TextLineFactoryBase
		truncationOptions : flashx.textLayout.factory:TruncationOptions Specifica le opzioni per il troncamento del testo se non rientra nei limiti della composizione.	TextLineFactoryBase
		verticalScrollPolicy : String Specifica come vengono create le righe quando i limiti della composizione non sono abbastanza estesi.	TextLineFactoryBase

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		TextFlowTextLineFactory() Crea un oggetto TextFlowTextLineFactory.	TextFlowTextLineFactory
		createTextLines(callback:Function, textFlow:flashx.textLayout.elements:TextFlow):void Crea oggetti TextLine dal flusso di testo specificato.	TextFlowTextLineFactory
		getContentBounds():Rectangle Il rettangolo più piccolo in cui viene adattato il contenuto disposto.	TextLineFactoryBase
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object

Descrizione della funzione di costruzione

()

Funzione di costruzione

public function TextFlowTextLineFactory()

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

Flash Player 10, AIR 1.5

Crea un oggetto TextFlowTextLineFactory.

Descrizione dei metodi

createTextLines

()

metodo

public function createTextLines(callback:Function, textFlow:flashx.textLayout.elements:TextFlow):void

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

Flash Player 10, AIR 1.5

Crea oggetti TextLine dal flusso di testo specificato.

Le righe di testo vengono composte in modo da adattarsi ai limiti assegnati alla proprietà compositionBounds. Mentre viene creata ogni riga, factory chiama la funzione specificata nel parametro callback. A questa funzione viene passato l'oggetto TextLine ed è responsabile della visualizzazione della riga. Se per una riga è presente un colore di sfondo, factory chiama inoltre la funzione di callback con un oggetto Shape che contiene un rettangolo per il colore di sfondo.

Tenete presente che i criteri di scorrimento della factory controllano il numero di righe che viene generato.

Parametri

	`callback:Function` — funzione da chiamare con ogni oggetto TextLine generato. La funzione di callback viene chiamata con un oggetto Shape che rappresenta un colore di sfondo qualsiasi, se presente, e con oggetti TextLine per il testo.

	`textFlow:flashx.textLayout.elements:TextFlow` — L'oggetto TextFlow da cui vengono create le righe.

Esempi Come utilizzare questo esempio

TextFlowTextLineFactory_example.as

Nell'esempio seguente viene utilizzata TextFlowTextLineFactory per creare un insieme di righe di testo. Il metodo factory, createTextLines(), viene chiamato due volte utilizzando la stessa frase. Le proprietà factory e i formati di flusso vengono modificati tra una chiamata e l'altra per creare un effetto "ombra esterna".

package flashx.textLayout.factory.examples
{
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.geom.Rectangle;
    import flash.text.engine.TextLine;
    
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.factory.TextFlowTextLineFactory;
    import flashx.textLayout.formats.TextLayoutFormat;

    public class TextFlowTextLineFactory_example extends Sprite
    {
        public function TextFlowTextLineFactory_example()
        {
            var factory:TextFlowTextLineFactory = new TextFlowTextLineFactory();
            factory.compositionBounds = new Rectangle( 100, 100, 200, 130 );
            
            var flow:TextFlow = new TextFlow();

            var format:TextLayoutFormat = new TextLayoutFormat();
            format.fontFamily = "LilyUPC, Verdana, _sans";
            format.fontSize = 32;
            format.color = 0x000000;
            format.textAlpha = .5;
            
            var span:SpanElement = new SpanElement();
            span.text = "The quick brown fox jumped over the lazy dog.";            
            span.format = format;
            
            var para:ParagraphElement = new ParagraphElement();
            para.addChild( span );
            
            flow.addChild( para );
            
            factory.createTextLines( useTextLines, flow );
            
            factory.compositionBounds = new Rectangle( 99, 99, 200, 130 );
            format.color = 0x990000;
            format.textAlpha = 1;
            span.format = format;
            factory.createTextLines( useTextLines, flow );
            
            graphics.beginFill(0x555555,.5);
            graphics.drawRect( 99, 99, 201, 131 );
            graphics.endFill();

        }
        
        private function useTextLines( lineOrShape:DisplayObject ):void
        {
            this.addChild( lineOrShape );
        }
        
    }
}

Note legali | Informativa sulla privacy online

TextFlowTextLineFactory - AS3

Classi x

TextFlowTextLineFactory

createTextLines