Búsqueda de subcadenas y patrones en cadenas

Búsqueda de subcadenas coincidentes

El método search() devuelve la posición del índice de la primera subcadena que coincide con un patrón determinado, como se indica en este ejemplo:

var str:String = "The more the merrier."; 
// (This search is case-sensitive.) 
trace(str.search("the")); // output: 9 

También se pueden utilizar expresiones regulares para definir el patrón que se debe buscar, como se indica en este ejemplo:

var pattern:RegExp = /the/i; 
var str:String = "The more the merrier."; 
trace(str.search(pattern)); // 0

La salida del método trace() es 0 porque el primer carácter de la cadena es la posición de índice 0. La búsqueda no distingue mayúsculas de minúsculas porque está establecido el indicador i en la expresión regular.

El método search() busca una sola coincidencia y devuelve su posición de índice inicial, aunque el indicador g (global) esté establecido en la expresión regular.

En el siguiente ejemplo se muestra una expresión regular más compleja, que coincide con una cadena entre comillas dobles:

var pattern:RegExp = /"[^"]*"/; 
var str:String = "The \"more\" the merrier."; 
trace(str.search(pattern)); // output: 4 
 
str = "The \"more the merrier."; 
trace(str.search(pattern)); // output: -1  
// (Indicates no match, since there is no closing double quotation mark.)

El método match() funciona de manera similar. Busca una subcadena coincidente. Sin embargo, al utilizar el indicador global en un patrón de expresión regular, como en el siguiente ejemplo, match() devuelve un conjunto de subcadenas coincidentes:

var str:String = "bob@example.com, omar@example.org"; 
var pattern:RegExp = /\w*@\w*\.[org|com]+/g; 
var results:Array = str.match(pattern);

El conjunto results se establece en:

["bob@example.com","omar@example.org"]

Para obtener más información sobre las expresiones regulares, consulte Uso de expresiones regulares .

Sustitución de subcadenas coincidentes

Se puede utilizar el método replace() para buscar un patrón específico en una cadena y sustituir las coincidencias por la cadena de sustitución especificada, como se indica en el siguiente ejemplo:

var str:String = "She sells seashells by the seashore."; 
var pattern:RegExp = /sh/gi; 
trace(str.replace(pattern, "sch")); //sche sells seaschells by the seaschore. 

En este ejemplo se puede observar que las cadenas coincidentes no distinguen mayúsculas de minúsculas porque está establecido el indicador i ( ignoreCase ) en la expresión regular y se sustituyen todas las coincidencias porque está establecido el indicador g ( global ). Para obtener más información, consulte Uso de expresiones regulares .

Se pueden incluir los siguientes códigos de sustitución $ en la cadena de sustitución. El texto de sustitución mostrado en la tabla siguiente se inserta en lugar del código de sustitución $ :

Por ejemplo, a continuación se muestra el uso de los códigos de sustitución $2 y $1 , que representan el primer y el segundo grupo coincidente captado:

var str:String = "flip-flop"; 
var pattern:RegExp = /(\w+)-(\w+)/g; 
trace(str.replace(pattern, "$2-$1")); // flop-flip

También se puede utilizar una función como segundo parámetro del método replace() . El texto coincidente se sustituye por el valor devuelto por la función.

var str:String = "Now only $9.95!"; 
var price:RegExp = /\$([\d,]+.\d+)+/i; 
trace(str.replace(price, usdToEuro)); 
 
function usdToEuro(matchedSubstring:String,                                  capturedMatch1:String,                                  index:int,                                  str:String):String 
{ 
    var usd:String = capturedMatch1; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.853690; 
    var euro:Number = parseFloat(usd) * exchangeRate; 
    const euroSymbol:String = String.fromCharCode(8364); 
    return euro.toFixed(2) + " " + euroSymbol; 
}

Si se utiliza una función como segundo parámetro del método replace() , se pasan los siguientes argumentos a la función:

• La parte coincidente de la cadena.

• Las coincidencias de grupos de paréntesis de captura. El número de argumentos pasados de esta forma varía en función del número de grupos entre paréntesis coincidentes. Se puede determinar el número de grupos entre paréntesis coincidentes comprobando arguments.length - 3 dentro del código de la función.

• La posición de índice en la que comienza la coincidencia en la cadena.

• La cadena completa.