WorkerDomain  - AS3

La instancia de WorkerDomain en la que se está ejecutando actualmente el código. Se trata de la única instancia de WorkerDomain en la aplicación.

Indica si el contexto del motor de ejecución actual admite los objetos WorkerDomain y Worker para ejecución simultánea de código.

Si la simultaneidad está disponible, el valor de esta propiedad es true.

Crea una nueva instancia de Worker a partir de los bytes de un swf.

Cada programa de trabajo se crea a partir de una aplicación swf aislada y se ejecuta en ella. Para crear una instancia de Worker, debe obtener los bytes del archivo SWF como una instancia de ByteArray y transferirlo a este método. Hay tres formas comunes de acceder a los bytes de un swf para este fin:

• Utilizar la metaetiqueta [Embed] para incorporar el archivo .swf en la aplicación como un ByteArray:

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Cargar un archivo SWF externo con un URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Utilizar un solo swf como programa de trabajo primordial y de segundo plano:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Crear un objeto Worker con createWorker() no inicia la ejecución del objeto. Para iniciar la ejecución del código de un programa de trabajo, debe llamar al método start() del objeto Worker.

Los programas de trabajo son útiles, ya que reducen las posibilidades de pérdidas de velocidad de fotogramas debidas al bloqueo del subproceso principal por parte de otro código. No obstante, los programas de trabajo requieren memoria adicional del sistema y mayor uso de CPU, y esto puede afectar significativamente al rendimiento general de la aplicación. Dado que cada programa de trabajo utiliza su propia instancia de la máquina virtual del motor de ejecución, incluso la sobrecarga de un programa de trabajo trivial puede ser muy grande. Cuando utilice programas de trabajo, pruebe el código en todas las plataformas de destino para garantizar que no exigen demasiados recursos de uso del sistema. Adobe recomienda no utilizar más de uno o dos programas de trabajo en segundo plano en un escenario típico.

Parámetros

Proporciona acceso al conjunto de programas de trabajo de WorkerDomain que están actualmente en ejecución (la propiedad state de la instancia de Worker es WorkerState.RUNNING).