Geolocation

Paquete	flash.sensors
Clase	public class Geolocation
Herencia	Geolocation EventDispatcher Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

La clase Geolocation distribuye eventos como respuesta a la ubicación del sensor del dispositivo.

Si un dispositivo admite geolocalización, puede utilizar esta clase para obtener la ubicación geográfica actual del dispositivo. La ubicación geográfica se muestra en el dispositivo en forma de coordenadas de latitud y longitud (en formato WGS-84 estándar). Cuando la ubicación del dispositivo cambia, puede recibir actualizaciones acerca de los cambios. Si el dispositivo admite esta función, podrá obtener información acerca de la altitud, precisión, encabezado, velocidad y marca de hora del último cambio en la ubicación.

Compatibilidad con perfil de AIR: esta función sólo se admite en dispositivos móviles. No se admite en dispositivos de escritorio ni de AIR para TV. Puede probar la compatibilidad en tiempo de ejecución con la propiedad Geolocation.isSupported. Consulte Compatibilidad con perfil de AIR para obtener información sobre la compatibilidad de la API con varios perfiles.

Nota: Para activar la localización geográfica en iOS, asegúrese de que añade una pareja clave-valor al elemento infoAdditions en el archivo xml de la aplicación. Consulte Configuración de iOS para obtener más información sobre el elemento infoAdditions.

Ver los ejemplos

Más información

Cristophe Coenraets: Colaboración entre varios usuarios de Google Maps

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		isSupported : Boolean [estática] [solo lectura] Si hay un sensor de ubicación disponible en el dispositivo (true); en caso contrario, false.	Geolocation
		locationAlwaysUsePermission : Boolean Esta propiedad determina el uso del tipo de permiso de acceso de geolocalización.	Geolocation
		muted : Boolean [solo lectura] Especifica si el usuario ha denegado el acceso a la geolocalización (true) o lo ha autorizado (false).	Geolocation
		permissionStatus : String [estática] [solo lectura]	Geolocation

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		Geolocation() Crea una nueva instancia de Geolocation.	Geolocation
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra un objeto de detector de eventos con un objeto EventDispatcher, de modo que el detector reciba la notificación de un evento.	EventDispatcher
		dispatchEvent(event:Event):Boolean Distribuye un evento en el flujo del evento.	EventDispatcher
		hasEventListener(type:String):Boolean Comprueba si el objeto EventDispatcher tiene detectores registrados para un tipo concreto de evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Elimina un detector del objeto EventDispatcher.	EventDispatcher
		requestPermission():void	Geolocation
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		setRequestedUpdateInterval(interval:Number):void Se utiliza para establecer el intervalo de tiempo para las actualizaciones, en milisegundos.	Geolocation
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object
		willTrigger(type:String):Boolean Comprueba si hay registrado un detector de eventos con este objeto EventDispatcher o con cualquiera de sus ascendientes para el tipo de evento concreto.	EventDispatcher

Eventos

Haga clic para obtener más información sobre los eventos

Ocultar eventos heredados

Mostrar eventos heredados

	Resumen	Definido por
activate	[evento broadcast] Se distribuye cuando Flash Player o AIR pasan a estar activos.	EventDispatcher
deactivate	[evento broadcast] Se distribuye cuando Flash Player o de AIR pasan a estar inactivos.	EventDispatcher
permissionStatus		Geolocation
status	El objeto Geolocation distribuye eventos de estado cuando el usuario cambia el acceso al sensor de ubicación.	Geolocation
update	El evento update se distribuye como respuesta a las actualizaciones del sensor del ubicación.	Geolocation

Información sobre propiedades

isSupported

propiedad

isSupported:Boolean [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

Si hay un sensor de ubicación disponible en el dispositivo (true); en caso contrario, false.

Implementación
public static function get isSupported():Boolean

locationAlwaysUsePermission

propiedad

locationAlwaysUsePermission:Boolean

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 29

Esta propiedad determina el uso del tipo de permiso de acceso de geolocalización. El tipo de permiso puede ser Siempre o Cuando está en uso. Si la propiedad está definida en false, requerirá el permiso Cuando está en uso; si no es así, requerirá el permiso Siempre. Establezca la propiedad antes de realizar una llamada a requestPermission (). El valor predeterminado de la propiedad es false.

Implementación
public function get locationAlwaysUsePermission():Boolean
public function set locationAlwaysUsePermission(value:Boolean):void

muted

propiedad

muted:Boolean [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

Especifica si el usuario ha denegado el acceso a la geolocalización (true) o lo ha autorizado (false). Cuando cambia este valor, se distribuye un evento status.

Implementación
public function get muted():Boolean

Elementos de API relacionados

status

permissionStatus

propiedad

permissionStatus:String [solo lectura]

Implementación
public static function get permissionStatus():String

Información sobre constructores

()

Información sobre

public function Geolocation()

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

Crea una nueva instancia de Geolocation.

Información sobre métodos

requestPermission

()

método

public function requestPermission():void

setRequestedUpdateInterval

()

método

public function setRequestedUpdateInterval(interval:Number):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

Se utiliza para establecer el intervalo de tiempo para las actualizaciones, en milisegundos. El intervalo de actualización sólo se utiliza como sugerencia para conservar la batería. El tiempo real entre las actualizaciones de ubicación puede ser mayor o menor que este valor. Cualquier cambio en el intervalo de actualización con este método afecta a todos los detectores de eventos update registrados. La clase Geolocation puede utilizarse sin llamar al método setRequestedUpdateInterval(). En este caso, la plataforma devolverá actualizaciones basadas en su intervalo predeterminado.

Nota: los iPhone de primera generación, que no incluyen unidad GPS, distribuyen eventos update de forma ocasional. En estos dispositivos, un objeto Geolocation inicialmente distribuye uno o dos eventos update. Seguidamente, distribuye eventos update cuando cambia notablemente la información.

Parámetros

interval:Number — intervalo de actualización solicitado. Si interval <= 0, cualquier llamada a este método no surtirá ningún efecto.

Emite

ArgumentError — El intervalo especificado es menor que cero.

Información sobre eventos

permissionStatus

Evento

Tipo de objeto de evento: flash.events.PermissionEvent

status

Evento

Tipo de objeto de evento: flash.events.StatusEvent
propiedad StatusEvent.type = flash.events.StatusEvent.STATUS

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

El objeto Geolocation distribuye eventos status cuando el usuario cambia el acceso al sensor de ubicación. Por ejemplo, si en respuesta a una solicitud del dispositivo, el usuario impide que la aplicación acceda a datos de ubicación, el objeto Geolcation distribuye un evento status. Cuando el estado cambie a un estado en que el sensor de ubicación no esté disponible, la propiedad muted de la instancia de Geolocation es true.

Define el valor de la propiedad type de un objeto de evento status.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`code`	Descripción del estado del objeto.
`currentTarget`	Objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`level`	La categoría del mensaje, por ejemplo, `"status"`, `"warning"` o `"error"`.
`target`	El objeto que informa sobre su estado.

Elementos de API relacionados

muted

update

Evento

Tipo de objeto de evento: flash.events.GeolocationEvent
propiedad GeolocationEvent.type = flash.events.GeolocationEvent.UPDATE

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2, Flash Lite 4

El evento update se distribuye como respuesta a las actualizaciones del sensor del ubicación. El evento se distribuye en las circunstancias siguientes:

Cuando se conecta una nueva función de detector mediante addEventListener(), este evento se envía una vez a todos los detectores registrados para proporcionar el valor actual de la ubicación. Nota: AIR distribuye el primer evento justo después de que el dispositivo tenga una última ubicación conocida; el código debe tener en cuenta que el evento distribuido inicialmente puede no contener la ubicación actual.
Siempre que se obtienen actualizaciones de la ubicación en la plataforma a intervalos determinados del dispositivo.
Siempre que la aplicación omite un cambio en la ubicación (por ejemplo, la aplicación se está despertando después de estar inactiva).

Define el valor de la propiedad type de un objeto de evento GeolocationEvent.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	Objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto Geolocation que recibe los datos.

Ejemplos Cómo utilizar este ejemplo

GeolocationExample.as

En el ejemplo siguiente, la aplicación muestra la latitud, longitud y precisión horizontal de los eventos update de geolocalización a medida que se reciben.

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.GeolocationEvent;
    import flash.events.MouseEvent;
    import flash.events.StatusEvent;
    import flash.sensors.Geolocation;
    import flash.text.TextField;
    import flash.text.TextFormat;
    
    public class GeolocationTest extends Sprite
    {
        
        private var geo:Geolocation; 
        private var log:TextField;
        
        public function GeolocationTest()
        {            
            super();
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            setUpTextField();
            
            if (Geolocation.isSupported) 
            { 
                geo = new Geolocation(); 
                if (!geo.muted) 
                { 
                    geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler); 
                } 
                geo.addEventListener(StatusEvent.STATUS, geoStatusHandler);
            } 
            else 
            { 
                log.text = "Geolocation not supported"; 
            } 
        }
        
        public function geoUpdateHandler(event:GeolocationEvent):void 
        { 
            log.text = "latitude : " + event.latitude.toString() + "\n"; 
            log.appendText("longitude : " + event.longitude.toString() + "\n");
        } 
        
        public function geoStatusHandler(event:StatusEvent):void 
        { 
            if (geo.muted)
                geo.removeEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
            else
                geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
        }
        
        private function setUpTextField():void
        {
            log = new TextField();
            var format:TextFormat = new TextFormat("_sans", 24);
            log.defaultTextFormat = format;
            log.border = true;
            log.wordWrap = true;
            log.multiline = true;
            log.x = 10;
            log.y = 10;
            log.height = stage.stageHeight - 20;
            log.width = stage.stageWidth - 20;
            log.addEventListener(MouseEvent.CLICK, clearLog);
            addChild(log);
        }
        private function clearLog(event:MouseEvent):void
        {
            log.text = "";
        }
    }
}

Avisos legales | Política de privacidad en línea

Geolocation - AS3

Clases x

isSupported

locationAlwaysUsePermission

muted

permissionStatus

Geolocation

requestPermission

setRequestedUpdateInterval

permissionStatus

status

update