ShaderFilter  - AS3

El crecimiento en píxeles debajo del objeto de destino.

El crecimiento es el área que supera los límites del objeto de destino que se transfiere al objeto shader durante la ejecución. En tiempo de ejecución, Flash Player o AIR calcula los límites normales de un clip de película y los amplía en función de los valores de leftExtension, rightExtension, topExtension y bottomExtension.

El valor predeterminado es 0.

El crecimiento en píxeles a la izquierda del objeto de destino.

El crecimiento es el área que supera los límites del objeto de destino que se transfiere al objeto shader durante la ejecución. En tiempo de ejecución, Flash Player o AIR calcula los límites normales de un clip de película y los amplía en función de los valores de leftExtension, rightExtension, topExtension y bottomExtension.

El valor predeterminado es 0.

El crecimiento en píxeles a la derecha del de destino.

El crecimiento es el área que supera los límites del objeto de destino que se transfiere al objeto shader durante la ejecución. En tiempo de ejecución, Flash Player o AIR calcula los límites normales de un clip de película y los amplía en función de los valores de leftExtension, rightExtension, topExtension y bottomExtension.

El valor predeterminado es 0.

Sombreado que se utiliza en el filtro.

El objeto Shader asignado a la propiedad shader debe especificar al menos una entrada image4. No es necesario que la entrada se especifique con código de la propiedad input asociada al objeto ShaderInput. En su lugar, se utiliza automáticamente el objeto al que se aplica el filtro como primera entrada (la entrada con index 0). Un objeto shader empleado como filtro puede especificar más de una entrada. En ese caso, cualquier entrada adicional debe especificarse mediante la propiedad input de la instancia de ShaderInput.

Cuando se asigna una instancia de Shader a esta propiedad, el sombreado se copia internamente y la operación del filtro utiliza la copia interna, no una referencia al objeto shader original. Todos los cambios realizados en el objeto shader, como la modificación de los valores de los parámetros, la entrada o el código de bytes, no se aplican al sombreado copiado que se utiliza en el filtro. Para que los cambios del objeto shader se tengan en cuenta en la salida del filtro, debe reasignar la instancia de Shader a la propiedad shader. Como con todos los filtros, también se debe reasignar la instancia de ShaderFilter a la propiedad filters de objeto de visualización para poder aplicar los cambios del filtro.

El crecimiento en píxeles encima del objeto de destino.

El crecimiento es el área que supera los límites del objeto de destino que se transfiere al objeto shader durante la ejecución. En tiempo de ejecución, Flash Player o AIR calcula los límites normales de un clip de película y los amplía en función de los valores de leftExtension, rightExtension, topExtension y bottomExtension.

El valor predeterminado es 0.

Crea un nuevo filtro de sombreado.

Elementos de API relacionados

Tenga en cuenta que este ejemplo asume que existe un archivo de código de bytes de sombreado llamado "gradient.pbj" en el mismo directorio que el directorio de salida de la aplicación.

//
// Source code for the shader:
//
<languageVersion : 1.0;>

kernel RedGradientFilter
<
    namespace: "Adobe::Example";
    vendor: "Adobe examples";
    version: 1;
    description: "Applies a gradient across the red channel of the input image.";
>
{
    input image4 src;
    output pixel4 dst;
    
    parameter float width
    <
        description: "The width of the image to which the shader is applied.";
        minValue: 0.0;
    >;

    void evaluatePixel()
    {
        pixel4 temp = sampleNearest(src, outCoord());
        temp.r = 1.0 - (outCoord().x * (1.0 / width));
        dst = temp;
    }
}

//
// ActionScript source code:
//
package {
    import flash.display.Shader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.filters.ShaderFilter;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;

    public class ShaderFilterExample extends Sprite {
        
        private var loader:URLLoader;
        private var s:Sprite;
        
        public function ShaderFilterExample() {
            loader = new URLLoader();
            loader.dataFormat = URLLoaderDataFormat.BINARY;
            loader.addEventListener(Event.COMPLETE, loadCompleteHandler);
            loader.load(new URLRequest("gradient.pbj"));
            
            s = new Sprite();
            s.graphics.beginFill(0x009900);
            s.graphics.drawCircle(100, 100, 100);
            addChild(s);
        }
        
        private function loadCompleteHandler(event:Event):void {
            var shader:Shader = new Shader(loader.data);
            shader.data.width.value = [s.width];
            
            var gradientFilter:ShaderFilter = new ShaderFilter(shader);
            s.filters = [gradientFilter];
        }
    }
}