DisplacementMapFilter  - AS3

Especifica el valor de transparencia alfa que debe utilizarse para desplazamientos fuera de los límites. Se especifica como un valor normalizado de 0,0 a 1,0. Por ejemplo, 0,25 establece un valor de transparencia del 25%. El valor predeterminado es 0. Utilice esta propiedad si mode se define como DisplacementMapFilterMode.COLOR.

Especifica el color que debe utilizarse para desplazamientos fuera de los límites. El rango de desplazamiento válido va de 0,0 a 1,0. Los valores tienen formato hexadecimal. El valor predeterminado de color es 0. Utilice esta propiedad si mode se define como DisplacementMapFilterMode.COLOR.

Describe qué canal de color se utilizará en la imagen del mapa para desplazar el resultado x. Los valores posibles son constantes BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementos de API relacionados

Describe qué canal de color se utilizará en la imagen del mapa para desplazar el resultado y. Los valores posibles son constantes BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementos de API relacionados

Objeto BitmapData que contiene los datos del mapa de desplazamiento.

Elementos de API relacionados

Un valor que contiene el desplazamiento de la esquina superior izquierda del objeto de visualización de destino desde la esquina superior izquierda de la imagen del mapa.

Elementos de API relacionados

Modo del filtro. Los valores posibles son constantes DisplacementMapFilterMode:

• DisplacementMapFilterMode.WRAP: ajusta el valor de desplazamiento al otro lado de la imagen de origen.
• DisplacementMapFilterMode.CLAMP: fija el valor de desplazamiento en el borde de la imagen de origen.
• DisplacementMapFilterMode.IGNORE: si el valor de desplazamiento está fuera de rango, omite el desplazamiento y utiliza el píxel de origen.
• DisplacementMapFilterMode.COLOR: si el valor de desplazamiento está fuera de rango, sustituye los valores de las propiedades color y alpha.

Elementos de API relacionados

Multiplicador que debe utilizarse para ajustar el tamaño del resultado del desplazamiento de x con respecto al cálculo del mapa.

Multiplicador que debe utilizarse para ajustar el tamaño del resultado del desplazamiento de y con respecto al cálculo del mapa.

Inicializa una instancia DisplacementMapFilter con los parámetros especificados.

Elementos de API relacionados

Devuelve una copia de este objeto de filtro.

1. La clase define variables para el color de fondo, para la etiqueta del campo de texto y para el tamaño y el desplazamiento que se utilizarán en diversas funciones.
2. La función constructora llama al método draw(), que utiliza los métodos de la clase Graphics para dibujar un cuadrado con relleno degradado radial. Observe que graphics es una propiedad del objeto DisplacementMapFilterExample que amplía Sprite.
3. La función constructora llama al método createLabel(), que crea un campo de texto con el valor de labelText y lo añade a la lista de visualización.
4. La función constructora llama al método createFilter(), que hace lo siguiente:
   • Crea una variable llamada filter para el objeto filter.
   • Llama al método getDisplacementMapFilter() y asigna su valor devuelto a la variable filter.
   • Transfiere filter a la propiedad filters del objeto DisplacementFilterExample (clase principal).
5. El método getBitmapFilter() crea un objeto BitmapData llamado mapBitmap y le asigna los resultados del método createBitmapData(). El objeto mapBitmap, junto con otras variables, define un nuevo filtro de mapa de desplazamiento.
6. El método createBitmapData() crea un nuevo objeto BitmapData basado en el contenido actual del objeto DisplacementMapFilterExample. Crea un nuevo mapa de bits basado en bitmapData y lo añade al escenario.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}