ColorMatrixFilter  - AS3

Conjunto de 20 elementos para la transformación de color 4x5. No se puede modificar directamente el valor de la propiedad matrix (por ejemplo, myFilter.matrix[2] = 1;). En su lugar, debe obtener una referencia al conjunto, realizar el cambio en la referencia y restaurar el valor.

Este filtro de la matriz de colores separa cada píxel de origen en sus componentes rojo, verde, azul y alfa como srcR, srcG, srcB, srcA. Para calcular el resultado de cada uno de los cuatro canales, el valor de cada píxel de la imagen se multiplica por los valores de la matriz de transformación. Opcionalmente, se puede añadir un desplazamiento que oscile entre -255 y 255 para cada resultado (el quinto elemento de cada fila de la matriz). El filtro combina cada componente de color en un único píxel y escribe el resultado. En la siguiente fórmula, el intervalo desde a[0] hasta a[19] corresponde a las entradas 0-19 en el conjunto de 20 elementos que se transmite a la propiedad matrix:

	redResult   = (a[0]  * srcR) + (a[1]  * srcG) + (a[2]  * srcB) + (a[3]  * srcA) + a[4]
	greenResult = (a[5]  * srcR) + (a[6]  * srcG) + (a[7]  * srcB) + (a[8]  * srcA) + a[9]
	blueResult  = (a[10] * srcR) + (a[11] * srcG) + (a[12] * srcB) + (a[13] * srcA) + a[14]
	alphaResult = (a[15] * srcR) + (a[16] * srcG) + (a[17] * srcB) + (a[18] * srcA) + a[19]
	

Para cada valor de color del conjunto, un valor de 1 equivale al 100% del canal que se envía al resultado, conservando el valor del canal de color.

Los cálculos se realizan con valores de color no multiplicados. Si el gráfico de entrada se compone de valores de color premultiplicados, esos valores se convertirán automáticamente en valores de color no multiplicados para esta operación.

Hay dos modos optimizados disponibles:

Sólo alfa. Cuando pasa al filtro una matriz que ajusta solamente el componente alfa, tal y como aquí se indica, el filtro optimiza su rendimiento:

	    1 0 0 0 0
	    0 1 0 0 0
	    0 0 1 0 0
	    0 0 0 N 0  (where N is between 0.0 and 1.0)
	

Versión rápida. Disponible sólo con procesadores que disponen de acelerador SSE/AltiVec, como Intel ^® Pentium ^® 3 y posteriores y Apple ^® G4 y posteriores. El acelerador se utiliza cuando los términos del multiplicador corresponden al rango comprendido entre -15.99 y 15.99, y los términos del sumador a[4], a[9], a[14] y a[19] corresponden al rango entre -8000 y8000.

Inicializa una instancia ColorMatrixFilter nueva con los parámetros especificados.

Devuelve una copia de este objeto de filtro.

La función buildChild() crea un nuevo objeto Loader denominado loader. Para cada llamada a buildChild(), se asocia un detector de eventos al objeto Loader para detectar eventos complete que se controlan con la función transferida a buildChild().

Las funciones applyRed(), applyGreen() y applyBlue() utilizan distintos valores para el conjunto matrix para conseguir distintos efectos de ConvolutionFilter.

Nota: para obtener los mejores resultados, utilice una imagen de aproximadamente 80 píxeles de anchura. El nombre y la ubicación del archivo de imagen deben coincidir con el valor transferido a la propiedad url. Por ejemplo, el valor transferido a url en el ejemplo señala a un archivo de imagen llamado "Image.jpg" que se encuentra en el mismo directorio que el archivo SWF.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.filters.ColorMatrixFilter;
    import flash.net.URLRequest;

    public class ColorMatrixFilterExample extends Sprite {
        private var size:uint  = 140;
        private var url:String = "Image.jpg";

        public function ColorMatrixFilterExample() {
            buildChild(null);
            buildChild(applyRed);
            buildChild(applyGreen);
            buildChild(applyBlue);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if (loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyRed(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([1, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyGreen(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 1, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyBlue(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 1, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}