Bitmap  - AS3

The BitmapData object being referenced.

Controls whether or not the Bitmap object is snapped to the nearest pixel. The PixelSnapping class includes possible values:

• PixelSnapping.NEVER—No pixel snapping occurs.
• PixelSnapping.ALWAYS—The image is always snapped to the nearest pixel, independent of transformation.
• PixelSnapping.AUTO—The image is snapped to the nearest pixel if it is drawn with no rotation or skew and it is drawn at a scale factor of 99.9% to 100.1%. If these conditions are satisfied, the bitmap image is drawn at 100% scale, snapped to the nearest pixel. Internally, this value allows the image to be drawn as fast as possible using the vector renderer.

Controls whether or not the bitmap is smoothed when scaled. If true, the bitmap is smoothed when scaled. If false, the bitmap is not smoothed when scaled.

Initializes a Bitmap object to refer to the specified BitmapData object.

	bitmapData:BitmapData (default = null) — The BitmapData object being referenced.
	pixelSnapping:String (default = "auto") — Whether or not the Bitmap object is snapped to the nearest pixel.
	smoothing:Boolean (default = false) — Whether or not the bitmap is smoothed when scaled. For example, the following examples show the same bitmap scaled by a factor of 3, with smoothing set to false (left) and true (right):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. A property url is created, which is the location and name of the image file
2. The class constructor calls the configureAssets() method, which, in turn, calls the completeHandler() method.
3. configureAssets() creates a Loader object, which then instantiates an event listener, which is dispatched when completeHandler() completes the image manipulation.
4. Next, the buildChild() method creates a new instance of a URLRequest object, request, with url passed so the file name and location are known.
5. The request object is passed to the loader.load() method, which loads the image into memory via a display object.
6. The image is then placed on the display list, which promptly displays the image on screen at coordinates x = 0, y = 0.
7. The completeHandler() method then performs the following tasks:
   1. Creates a second Loader object, along with a Bitmap object, which is initialized with the Loader object.
   2. Creates a second Bitmap object, duplicate, which in turn calls the duplicateImage() method, which creates a duplicate of the original image.
   3. Creates a BitmapData object, which is assigned to the duplicate object's BitmapData object.
   4. Creates a new Rectangle object initialized with the same coordinates, width, and height as the original image.
   5. Creates a new Point object, which defaults to x = 0, y = 0.
   6. Creates the following variables:
      • operation: applies the new color when the threshold value is >= the original.
      • threshold: the value against which each pixel is compared is set to light gray with an alpha of 0xCC.
      • color: the color that the pixels will be set to that pass the threshold test, which is solid yellow in this case.
      • mask: set to the exact opposite of color, (transparent blue).
      • copySource: set to false, indicating that the pixel values are not copied in the event the threshold value does not pass. This value has no meaning because the image is duplicated and only pixels that pass the threshold test are changed.
   7. Calls the threshold() method by using the preceding variables. The resulting threshold equation is as follows: if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Notes:

• You will need to compile the SWF file with "Local playback security" set to "Access local files only".
• This example requires that a file named Image.gif be placed in the same directory as your SWF file.
• It is recommended that you use an image up to 80 pixels wide.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}