Arbeiten mit File-Objekten in AIR

Mit der File-Klasse können Sie folgende Aktionen ausführen:

• Abrufen des Pfads zu speziellen Verzeichnissen, einschließlich des Benutzerverzeichnisses, des Dokumentverzeichnisses des Benutzers, des Verzeichnisses, aus dem die Anwendung gestartet wurde, und des Anwendungsverzeichnisses.

• Kopieren von Dateien und Verzeichnissen

• Verschieben von Dateien und Verzeichnissen

• Löschen von Dateien und Verzeichnissen (bzw. Verschieben in den Papierkorb)

• Auflisten von Dateien und Verzeichnissen in einem bestimmten Verzeichnis

• Erstellen temporärer Dateien und Ordner

Sobald ein File-Objekt auf einen Dateipfad zeigt, können Sie mithilfe der FileStream-Klasse Daten in der Datei lesen oder Daten in die Datei schreiben.

Ein File-Objekt kann auch auf den Pfad einer Datei oder eines Verzeichnisses zeigen, das noch gar nicht existiert. Sie können ein solches File-Objekt beim Erstellen einer Datei oder eines Verzeichnisses verwenden.

Jedes File-Objekt hat zwei Eigenschaften, die jeweils seinen Pfad definieren:

Die File-Klasse enthält statische Eigenschaften, um auf Standardverzeichnisse von MAC OS, Windows und Linux zu zeigen. Zu diesen Eigenschaften gehören:

Diese Eigenschaften verfügen auf verschiedenen Betriebssystemen über unterschiedliche Werte. Zum Beispiel verwenden Mac und Windows jeweils unterschiedliche native Pfade zum Desktopverzeichnis des Benutzers. Die File.desktopDirectory -Eigenschaft verweist jedoch auf jeder Plattform auf einen geeigneten Verzeichnispfad. Nutzen Sie diese Eigenschaften als Grundlage für Verweise auf andere Verzeichnisse und Dateien, die von der Anwendung verwendet werden, um Anwendungen zu schreiben, die auf allen Plattformen gleichermaßen gut funktionieren. Verwenden Sie anschließend die resolvePath() -Methode für die genauere Festlegung des Pfads. Der nachfolgende Code verweist z. B. auf die Datei „preferences.xml“ im Speicherordner der Anwendung.

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Mit der File-Klasse können Sie zwar auf einen spezifischen Dateipfad zeigen, damit erhalten Sie möglicherweise jedoch Anwendungen, die nicht auf allen Plattformen funktionieren. Der Pfad C:\Dokumente und Einstellungen\joe\ funktioniert zum Beispiel nur unter Windows. Deshalb sind die statischen Eigenschaften der File-Klasse besser geeignet, zum Beispiel File.documentsDirectory .

Die tatsächlichen nativen Pfade dieser Verzeichnisse variieren je nach Betriebssystem und Computerkonfiguration. Die in dieser Tabelle genannten Pfade sind typische Beispiele. Sie sollten stets mit den entsprechenden Eigenschaften der statischen File-Klasse auf diese Verzeichnisse verweisen, um sicherzustellen, dass Ihre Anwendung auf jeder Plattform korrekt funktioniert. In einer echten AIR-Anwendung stammen die in der Tabelle gezeigten Werte für Anwendungs_ID und Dateiname aus dem Anwendungsdeskriptor. Wenn Sie im Anwendungsdeskriptor eine Herausgeber-ID angeben, wird diese ID in diesen Pfaden an die Anwendungs-ID angehängt. Der Wert für Benutzername ist der Kontoname des Benutzers, der die Installation durchführt.

Es gibt verschiedene Möglichkeiten, um ein File-Objekt so einzurichten, dass es auf ein Verzeichnis zeigt.

Es gibt verschiedene Möglichkeiten, um die Datei festzulegen, auf die ein File-Objekt zeigt.

Sie können auch den Pfad eines vorhandenen File-Objekts ändern, indem Sie die Methode resolvePath() aufrufen oder die Eigenschaft nativePath oder url des Objekts ändern. Hier ein Beispiel unter Windows:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

Wenn Sie mit der nativePath -Eigenschaft arbeiten, verwenden Sie den Schrägstrich (/) Verzeichnistrennzeichen. Unter Windows können Sie auch den umgekehrten Schrägstrich (\) verwenden, dies sollte jedoch vermieden werden, da der entsprechende Code dann nicht auf allen Plattformen verwendet werden kann.

In AIR können Sie beim Definieren der url -Eigenschaft eines File-Objekts eines der folgenden URL-Schemata verwenden:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Unter bestimmten Betriebssystemen, insbesondere iOS und Mac OS X, können Benutzer Anwendungsdateien automatisch in einem Remote-Speicher sichern. Unter iOS unterliegt es gewissen Einschränkungen, ob Dateien gesichert werden können und an welchem Ort Dateien für verschiedene Zwecke gespeichert werden können.

Die folgenden Punkte fassen zusammen, wie Sie die Richtlinien von Apple für die Dateisicherung und -speicherung einhalten. Weitere Informationen finden Sie in den nächsten Abschnitten.

• Um anzugeben, dass eine Datei nicht gesichert werden muss und (nur iOS) vom Betriebssystem gelöscht werden kann, falls der Speicherplatz des Geräts nicht mehr ausreicht, speichern Sie die Datei im Cacheverzeichnis ( File.cacheDirectory ). Dies ist der bevorzugte Speicherort unter iOS und sollte für die meisten Dateien verwendet werden, die neu generiert oder heruntergeladen werden können.

• Um anzugeben, dass eine Datei nicht gesichert werden muss, jedoch nicht vom Betriebssystem gelöscht werden soll, speichern Sie die Datei in einem der Verzeichnisse der Anwendungsbibliothek, z. B. im Anwendungsspeicherverzeichnis ( File.applicationStorageDirectory ) oder im Dokumentenverzeichnis ( File.documentsDirectory ). Setzen Sie die Eigenschaft preventBackup des File-Objekts auf true . Dies ist laut Apple erforderlich bei Inhalten, die neu generiert oder heruntergeladen werden können, jedoch für das einwandfreie Funktionieren Ihrer Anwendung bei Offline-Verwendung notwendig sind.

Mit der Methode getRelativePath() können Sie den relativen Pfad zwischen zwei Dateien ermitteln:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

Der zweite Parameter der Methode getRelativePath() , der Parameter useDotDot bewirkt, dass in den Ergebnissen die .. -Syntax verwendet werden kann, um übergeordnete Verzeichnisse zu bezeichnen:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

Unter Windows und Mac OS muss die Groß- und Kleinschreibung für Datei- und Pfadnamen nicht beachtet werden. Im Folgenden zeigen zwei File-Objekte auf dieselbe Datei:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Allerdings wird in Dokument- und Verzeichnisnamen durchaus Groß- und Kleinschreibung verwendet. Im folgenden Code wird beispielsweise davon ausgegangen, dass sich im Verzeichnis „documents“ ein Ordner mit dem Namen „AIR Test“ befindet:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

Die Methode canonicalize() konvertiert das Objekt nativePath , um die exakte Groß-/Kleinschreibung für den Datei- oder Verzeichnisnamen zu verwenden. Bei Systemen, die zwischen Groß- und Kleinschreibung unterscheiden (wie Linux), korrigiert die canonicalize() -Methode für den Fall, dass sich mehrere Dateien nur in der Groß- und Kleinschreibung unterscheiden, den Pfad, um ihn an die erste gefundene Datei anzupassen (die Reihenfolge wird dabei vom System bestimmt).

Unter Windows können Sie mithilfe der Methode canonicalize() auch kurze Dateinamen („8.3-Namen“) in lange Dateinamen konvertieren:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Verschiedene Betriebssysteme unterstützen Paketdateien und Dateien für symbolische Links:

Pakete – Unter Mac OS können Verzeichnisse als Pakete gekennzeichnet werden und erscheinen dann im Mac OS-Finder als einzelne Dateien, nicht als Verzeichnisse.

Symbolische Vrknüpfungen – Mac OS, Linux und Windows Vista unterstützen symbolische Verknüpfungen. Symbolische Links ermöglichen, dass eine Datei auf eine andere Datei oder ein Verzeichnis auf der Festplatte zeigt. Obwohl sie sich ähneln, sind symbolische Links nicht dasselbe wie Aliasnamen. Ein Alias wird immer als Datei (nicht als Verzeichnis) betrachtet, und das Lesen und Schreiben von oder in einen Alias oder in eine Verknüpfung betrifft nie die ursprüngliche Datei oder das ursprüngliche Verzeichnis, auf die bzw. das verwiesen wird. Abgesehen davon verhält sich ein symbolischer Link genau wie die Datei oder das Verzeichnis, auf die bzw. das verwiesen wird. Der symbolische Link kann als Datei oder als Verzeichnis betrachtet werden. Das Lesen von einem oder Schreiben in einen symbolischen Link betrifft die Datei oder das Verzeichnis, auf die bzw. das verwiesen wird, nicht den symbolischen Link selbst. Unter Windows wird zusätzlich die isSymbolicLink -Eigenschaft für ein File-Objekt, das auf einen Verknüpfungspunkt (im NTFS-Dateisystem verwendet) verweist, mit dem Wert true belegt.

Die File-Klasse besitzt die Eigenschaften isPackage und isSymbolicLink , um zu überprüfen, ob ein File-Objekt auf ein Paket oder einen symbolischen Link verweist.

Der folgende Code durchläuft das Desktopverzeichnis des Benutzers und listet alle Unterverzeichnisse auf, die keine Pakete sind:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Der folgende Code durchläuft das Desktopverzeichnis des Benutzers und listet alle Dateien und Verzeichnisse auf, die keine symbolische Links sind:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Die Methode canonicalize() ändert den Pfad eines symbolischen Links so, dass er auf die Datei oder das Verzeichnis zeigt, auf die bzw. das der Link verweist. Der folgende Code durchläuft das Desktopverzeichnis des Benutzers und erstellt einen Bericht über alle Pfade, auf die von Dateien verwiesen wird, die symbolische Links sind:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

Die Eigenschaft spaceAvailable eines File-Objekts bezeichnet den Speicherplatz in Byte, der an diesem Dateispeicherort zur Verfügung steht. Im folgenden Beispielcode wird der im Anwendungsspeicherverzeichnis verfügbare Speicherplatz überprüft:

trace(File.applicationStorageDirectory.spaceAvailable); 

Wenn das File-Objekt auf ein Verzeichnis verweist, gibt die spaceAvailable -Eigenschaft an, wie viel Speicherplatz die Dateien in diesem Verzeichnis einnehmen können. Wenn das File-Objekt auf eine Datei verweist, gibt die Eigenschaft spaceAvailable an, wie groß die Datei werden kann. Wenn der Dateispeicherort nicht vorhanden ist, wird die Eigenschaft spaceAvailable auf 0 eingestellt. Wenn das File-Objekt auf einen symbolischen Link verweist, entspricht der Wert, auf den die Eigenschaft spaceAvailable gesetzt wird, dem verfügbaren Speicherplatz an dem Speicherort, auf den der symbolische Link verweist.

Normalerweise ist der für ein Verzeichnis oder eine Datei verfügbare Speicherplatz identisch mit dem Speicherplatz, der auf dem Datenträger mit der Datei bzw. dem Verzeichnis verfügbar ist. Der verfügbare Speicherplatz kann jedoch auch Speicherkontingente und verzeichnisspezifische Limits berücksichtigen.

Wenn Sie einem Datenträger eine Datei oder ein Verzeichnis hinzufügen, wird dabei im Allgemeinen mehr Speicherplatz benötigt, als die Datei bzw. der Inhalt des Verzeichnisses tatsächlich belegen. Das Betriebssystem kann zum Beispiel zusätzlichen Speicherplatz zum Speichern von Indexinformationen benötigen. Auch Festplattensektoren benötigen unter Umständen zusätzlichen Speicher. Der verfügbare Speicherplatz ändert sich zudem dynamisch. Sie können also nicht davon ausgehen, dass Sie den gesamten gemeldeten Speicherplatz für das Speichern von Dateien verwenden können. Informationen dazu, wie Sie ins Dateisystem schreiben, finden Sie unter Lese- und Schreibvorgänge in Dateien .

Die StorageVolumeInfo.getStorageVolumes() -Methode liefert ausführlichere Informationen über gemountete Speichermedien (siehe Arbeiten mit Speichermedien ).

In AIR 2 können Sie eine Datei mit der Anwendung öffnen, die im Betriebssystem zum Öffnen der jeweiligen Datei registriert ist. Beispielsweise kann eine AIR-Anwendung eine DOC-Datei mit der dafür registrierten Anwendung öffnen. Verwenden Sie die openWithDefaultApplication() -Methode eines File-Objekts zum Öffnen der Datei. Mit dem folgenden Code wird beispielsweise eine Datei namens „test.doc“ auf dem Desktop des Anwenders mit der Standardanwendung für DOC-Dateien geöffnet:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Mit dem folgenden Code können Sie zu einer MP3-Datei navigieren und sie in der Standardanwendung zum Abspielen von MP3-Dateien öffnen.

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Die openWithDefaultApplication() -Methode kann nicht mit Dateien verwendet werden, die sich im Anwendungsverzeichnis befinden.

AIR verhindert das Öffnen bestimmter Dateien mit der openWithDefaultApplication() -Methode. Unter Windows verhindert AIR das Öffnen von Dateien mit bestimmten Dateitypen, wie beispielsweise EXE oder BAT. Unter Mac OS und Linux verhindert AIR, dass Sie Dateien öffnen, die in bestimmten Anwendungen gestartet werden. (Dazu zählen Terminal und AppletLauncher unter Mac OS sowie csh, bash und ruby unter Linux.) Wenn Sie versuchen, eine dieser Dateien mit der openWithDefaultApplication() -Methode zu öffnen, wird ein Ausnahmefehler ausgegeben. Eine vollständige Liste der Dateitypen, die nicht geöffnet werden können, finden Sie im Referenzhandbuch im Eintrag für die File.openWithDefaultApplication() -Methode.