FlowGroupElement

Paket	flashx.textLayout.elements
Klasse	public class FlowGroupElement
Vererbung	FlowGroupElement FlowElement Object
Unterklassen	ParagraphFormattedElement, SubParagraphGroupElementBase

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Die FlowGroupElement-Klasse ist die Basisklasse für FlowElement-Objekte, die ein Array mit untergeordneten Elementen haben können. Zu diesen Klassen gehören TextFlow, ParagraphElement, DivElement und LinkElement.

FlowGroupElement-Objekte können nicht direkt erstellt werden. Durch Aufrufen von new FlowGroupElement() wird ein Ausnahmefehler ausgegeben.

Standard-MXML-EigenschaftmxmlChildren

Verwandte API-Elemente

DivElement
LinkElement
ParagraphElement
TextFlow

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		alignmentBaseline : * TextLayoutFormat: Gibt die Grundlinie an, an dem die dominierende Grundlinie ausgerichtet wird.	FlowElement
		backgroundAlpha : * TextLayoutFormat: Alpha-Wert (Transparenz) für den Hintergrund (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		backgroundColor : * TextLayoutFormat: Hintergrundfarbe des Texts (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		baselineShift : * TextLayoutFormat: Betrag, um den die Grundlinie vom dominantBaseline-Wert verschoben wird.	FlowElement
		blockProgression : * TextLayoutFormat: Gibt eine vertikale oder horizontale Abfolge der Zeilenplatzierung an.	FlowElement
		breakOpportunity : * TextLayoutFormat: Gibt die Position von Zeilenumbrüchen in einem mehrzeiligen Text an.	FlowElement
		cffHinting : * TextLayoutFormat: Die für diesen Text verwendete Art des CFF-Hintings.	FlowElement
		clearFloats : * TextLayoutFormat: Steuert, wie der Text bei einem Float umbricht.	FlowElement
		color : * TextLayoutFormat: Farbe des Texts.	FlowElement
		columnCount : * TextLayoutFormat: Anzahl der Textspalten (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		columnGap : * TextLayoutFormat: Gibt den Zwischenraum in Pixeln an, der zwischen den Spalten gelassen werden soll (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		columnWidth : * TextLayoutFormat: Spaltenbreite in Pixeln (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		computedFormat : flashx.textLayout.formats:ITextLayoutFormat [schreibgeschützt] Gibt die berechneten Formatattribute zurück, die für dieses Element wirksam sind.	FlowElement
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		coreStyles : Object [schreibgeschützt] Gibt die coreStyles für dieses FlowElement zurück.	FlowElement
		digitCase : * TextLayoutFormat: Die für diesen Text verwendete Ziffernart.	FlowElement
		digitWidth : * TextLayoutFormat: Die für diesen Text verwendete Ziffernbreite.	FlowElement
		direction : * TextLayoutFormat: Gibt die standardmäßige bidirektionale Einbettungsebene des Texts im Textblock an.	FlowElement
		dominantBaseline : * TextLayoutFormat: Gibt an, welche Elementgrundlinie an der alignmentBaseline ausgerichtet wird, um die vertikale Position des Elements auf der Linie zu bestimmen.	FlowElement
		firstBaselineOffset : * TextLayoutFormat: Gibt die Grundlinienposition der ersten Linie im Container an.	FlowElement
		fontFamily : * TextLayoutFormat: Der Name der zu verwendenden Schriftart oder eine durch Kommas getrennte Liste mit Schriftartnamen.	FlowElement
		fontLookup : * TextLayoutFormat: Zu verwendende Schriftartsuche.	FlowElement
		fontSize : * TextLayoutFormat: Die Textgröße in Pixeln.	FlowElement
		fontStyle : * TextLayoutFormat: Stil des Texts.	FlowElement
		fontWeight : * TextLayoutFormat: Schriftartstärke.	FlowElement
		format : flashx.textLayout.formats:ITextLayoutFormat Direkt für dieses Element angewendete TextLayoutFormat-Eigenschaften.	FlowElement
		id : String Weist einem Element einen identifizierenden Namen zu, sodass es möglich ist, einen Stil für das Element durch Verweis auf die ID festzulegen.	FlowElement
		justificationRule : * TextLayoutFormat: Regel zum Ausrichten von Text in einem Absatz.	FlowElement
		justificationStyle : * TextLayoutFormat: Der Stil, der zum Ausrichten des Absatzes verwendet wird.	FlowElement
		kerning : * TextLayoutFormat: Beim Kerning werden die Pixel zwischen bestimmten Zeichenpaaren angepasst, um die Lesbarkeit zu verbessern.	FlowElement
		leadingModel : * TextLayoutFormat: Gibt das Zeilenabstandsmodell an, das eine Kombination von Zeilenabstandsbasis und Zeilenabstandsrichtung ist.	FlowElement
		ligatureLevel : * TextLayoutFormat: Steuert, welche in der Schriftart definierten Ligaturen im Text verwendet werden können.	FlowElement
		lineBreak : * TextLayoutFormat: Steuert Zeilenumbruch im Container (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		lineHeight : * TextLayoutFormat: Steuerelemente für den Zeilenabstand des Texts.	FlowElement
		lineThrough : * TextLayoutFormat: Wenn „true“, wird Durchstreichung angewendet, d. h eine mitten durch den Text gezogene Linie.	FlowElement
		linkActiveFormat : * TextLayoutFormat: Definiert die Formatierungsattribute für Links im normalen Status.	FlowElement
		linkHoverFormat : * TextLayoutFormat: Definiert die Formatierungsattribute, die für Links verwendet werden, über die der Mauszeiger bewegt wird („Hover“-Status).	FlowElement
		linkNormalFormat : * TextLayoutFormat: Definiert die Formatierungsattribute für Links im normalen Status.	FlowElement
		listAutoPadding : * TextLayoutFormat: Legt einen automatischen Einzug für die Startkante von Listen fest, wenn der Auffüllwert der Liste auf dieser Seite „auto“ lautet.	FlowElement
		listMarkerFormat : * TextLayoutFormat: Definiert die Listenmarkierungen der Formatierungsattribute.	FlowElement
		listStylePosition : * TextLayoutFormat: Zulässige Werte sind ListStylePosition.INSIDE, ListStylePosition.OUTSIDE, FormatValue.INHERIT. Standardwert ist nicht definiert, d. h. wurde nicht festgelegt. Wenn die Eigenschaft während einer Kaskade nicht definiert ist, wird der Wert aus einem übergeordneten Element übernommen.	FlowElement
		listStyleType : * TextLayoutFormat: Zulässige Werte sind ListStyleType.UPPER_ALPHA, ListStyleType.LOWER_ALPHA, ListStyleType.UPPER_ROMAN, ListStyleType.LOWER_ROMAN, ListStyleType.NONE, ListStyleType.DISC, ListStyleType.CIRCLE, ListStyleType.SQUARE, ListStyleType.BOX, ListStyleType.CHECK, ListStyleType.DIAMOND, ListStyleType.HYPHEN, ListStyleType.ARABIC_INDIC, ListStyleType.BENGALI, ListStyleType.DECIMAL, ListStyleType.DECIMAL_LEADING_ZERO, ListStyleType.DEVANAGARI, ListStyleType.GUJARATI, ListStyleType.GURMUKHI, ListStyleType.KANNADA, ListStyleType.PERSIAN, ListStyleType.THAI, ListStyleType.URDU, ListStyleType.CJK_EARTHLY_BRANCH, ListStyleType.CJK_HEAVENLY_STEM, ListStyleType.HANGUL, ListStyleType.HANGUL_CONSTANT, ListStyleType.HIRAGANA, ListStyleType.HIRAGANA_IROHA, ListStyleType.KATAKANA, ListStyleType.KATAKANA_IROHA, ListStyleType.LOWER_ALPHA, ListStyleType.LOWER_GREEK, ListStyleType.LOWER_LATIN, ListStyleType.UPPER_ALPHA, ListStyleType.UPPER_GREEK, ListStyleType.UPPER_LATIN, FormatValue.INHERIT. Standardwert ist nicht definiert, d. h. wurde nicht festgelegt. Wenn die Eigenschaft während einer Kaskade nicht definiert ist, wird der Wert aus einem übergeordneten Element übernommen.	FlowElement
		locale : * TextLayoutFormat: Das Gebietsschema des Texts.	FlowElement
		mxmlChildren : Array Wendet ein Array von untergeordneten Elementen auf dieses Objekt an.	FlowGroupElement
		numChildren : int [schreibgeschützt] Gibt die Anzahl der untergeordneten FlowElements dieses FlowGroupElement-Objekts zurück.	FlowGroupElement
		paddingBottom : * TextLayoutFormat: Der untere Versatz in Pixeln.	FlowElement
		paddingLeft : * TextLayoutFormat: Der linke Einzug in Pixeln.	FlowElement
		paddingRight : * TextLayoutFormat: Der rechte Einzug in Pixeln.	FlowElement
		paddingTop : * TextLayoutFormat: Der obere Versatz in Pixeln.	FlowElement
		paragraphEndIndent : * TextLayoutFormat: Eine Zahl, die den Versatz des unteren Absatzrands in Pixeln angibt.	FlowElement
		paragraphSpaceAfter : * TextLayoutFormat: Eine Zahl, die den Leerraum nach dem Absatz (in Pixeln) festlegt.	FlowElement
		paragraphSpaceBefore : * TextLayoutFormat: Eine Zahl, die den Wert für den Leeraum vor dem Absatz in Pixeln angibt.	FlowElement
		paragraphStartIndent : * TextLayoutFormat: Eine Zahl, die den Versatz des oberen Absatzrands angibt in Pixeln angibt.	FlowElement
		parent : FlowGroupElement [schreibgeschützt] Gibt das übergeordnete Element dieses FlowElement-Objekts zurück.	FlowElement
		parentRelativeEnd : int [schreibgeschützt] Gibt das relative Ende diesesFlowElement-Objekts im übergeordneten Element zurück.	FlowElement
		parentRelativeStart : int [schreibgeschützt] Gibt den relativen Beginn diesesFlowElement-Objekts im übergeordneten Element zurück.	FlowElement
		renderingMode : * TextLayoutFormat: Der für diesen Text verwendete Wiedergabemodus.	FlowElement
		styleName : * TextLayoutFormat: Weist einem Element eine identifizierende Klasse zu, sodass es möglich ist, einen Stil für das Element durch Verweis auf styleName festzulegen.	FlowElement
		styles : Object [schreibgeschützt] Gibt die Stile für dieses FlowElement zurück.	FlowElement
		tabStops : * TextLayoutFormat: Gibt die Tabulatoren an, die dem Absatz zugewiesen sind.	FlowElement
		textAlign : * TextLayoutFormat: Ausrichtung der Zeilen im Absatz relativ zum Container.	FlowElement
		textAlignLast : * TextLayoutFormat: Ausrichtung der letzten (oder einzigen) Zeile im Absatz relativ zum Container im ausgerichteten Text.	FlowElement
		textAlpha : * TextLayoutFormat: Wert für Alpha (Transparenz) des Texts.	FlowElement
		textDecoration : * TextLayoutFormat: Auszeichnung im Text.	FlowElement
		textIndent : * TextLayoutFormat: Eine Zahl, die die Einrückung der ersten Zeile des Absatzes in Pixeln festlegt.	FlowElement
		textJustify : * TextLayoutFormat: Gibt Optionen für die Ausrichtung des Texts an.	FlowElement
		textLength : int [schreibgeschützt] Gibt die Gesamtlänge des Textes, der zum FlowElement-Objekt und den untergeordneten Elementen gehört, zurück.	FlowElement
		textRotation : * TextLayoutFormat: Bestimmt die Gradzahl zum Drehen dieses Texts.	FlowElement
		tracking : Object [Nur Schreiben] Legt das Verfolgen fest und ist synonym mit der trackingRight-Eigenschaft.	FlowElement
		trackingLeft : * TextLayoutFormat: Zahl in Pixeln (oder Prozent der Schriftgröße, z. B. 120 %), die die Laufweite (manuelles Kerning) angibt, auf die linke Seite jedes Zeichens angewendet werden soll.	FlowElement
		trackingRight : * TextLayoutFormat: Zahl in Pixeln (oder Prozent der Schriftgröße, z. B. 120 %), die die Laufweite (manuelles Kerning) angibt, die auf die rechte Seite jedes Zeichens angewendet werden soll.	FlowElement
		typeName : String Zu jedem FlowElement gehört ein typeName.	FlowElement
		typographicCase : * TextLayoutFormat: Die für diesen Text verwendete typografische Buchstabenart.	FlowElement
		userStyles : Object Ermöglicht das Lesen und Schreiben von Benutzerstilen in einem FlowElement-Objekt.	FlowElement
		verticalAlign : * TextLayoutFormat: Vertikale Ausrichtung oder Blocksatz (übernimmt Standardwert, wenn während der Kaskade nicht definiert).	FlowElement
		whiteSpaceCollapse : * TextLayoutFormat: Blendet Leerraum aus oder behält ihn bei, wenn Text in einem TextFlow importiert wird.	FlowElement
		wordSpacing : * TextLayoutFormat: Legt den optimalen, minimalen und maximalen Abstand (als Vielfaches der Breite einer normalen Leerstelle) zwischen Wörtern fest, der beim Blocksatz verwendet wird.	FlowElement

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		FlowGroupElement() Basisklasse - das Aufrufen von new FlowGroupElement() verursacht einen Ausnahmefehler.	FlowGroupElement
		addChild(child:FlowElement):FlowElement Hängt ein untergeordnetes FlowElement-Objekt an.	FlowGroupElement
		addChildAt(index:uint, child:FlowElement):FlowElement Fügt der festgelegten Indexposition ein untergeordnetes FlowElement-Objekt hinzu.	FlowGroupElement
		clearStyle(styleProp:String):void Löscht den vom styleProp-Parameter festgelegten Stil aus diesem FlowElement-Objekt.	FlowElement
		deepCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement Erstellt eine tiefe Kopie dieses FlowElement-Objekts, einschließlich untergeordneter Elemente, indem der Inhalt zwischen zwei festgelegten Zeichenpositionen kopiert und die Kopie als FlowElement-Objekt zurückgegeben wird.	FlowElement
		equalUserStyles(otherElement:FlowElement):Boolean Vergleicht die userStyles dieses Elements mit den userStyles anderer Elemente.	FlowElement
		findChildIndexAtPosition(relativePosition:int):int Diese Methode sucht für eine gegebene relative Textposition nach der Indexposition des ersten untergeordneten FlowElements, das die relative Position enthält.	FlowGroupElement
		findLeaf(relativePosition:int):FlowLeafElement Sucht bei einer gegebenen relativen Textposition nach dem Blattelement, das die Position enthält.	FlowGroupElement
		getAbsoluteStart():int Gibt die Startposition des Elements im Textfluss als absolute Indexposition zurück.	FlowElement
		getCharAtPosition(relativePosition:int):String Gibt das Zeichen an der festgelegten Position relativ zu diesem FlowElement-Objekt zurück.	FlowElement
		getCharCodeAtPosition(relativePosition:int):int Gibt den Zeichencode an der festgelegten Position relativ zu diesem FlowElement zurück.	FlowElement
		getChildAt(index:int):FlowElement Gibt das untergeordnete FlowElement an der festgelegten Indexposition zurück.	FlowGroupElement
		getChildIndex(child:FlowElement):int Sucht in untergeordneten Elementen nach dem festgelegten FlowElement-Objekt und gibt dessen Indexposition zurück.	FlowGroupElement
		getElementRelativeStart(ancestorElement:FlowElement):int Gibt den Beginn dieses Elements relativ zu einem übergeordneten Element zurück.	FlowElement
		getFirstLeaf():FlowLeafElement Gibt das erste untergeordnete FlowLeafElement für diese Gruppe zurück.	FlowGroupElement
		getLastLeaf():FlowLeafElement Gibt das letzte untergeordnete FlowLeafElement für diese Gruppe zurück.	FlowGroupElement
		getNextSibling():FlowElement Gibt das nächste gleichgeordnete FlowElement in der Textflusshierarchie zurück.	FlowElement
		getParagraph():ParagraphElement Gibt das mit diesem Element verknüpfte ParagraphElement-Objekt zurück.	FlowElement
		getPreviousSibling():FlowElement Gibt das vorherige gleichgeordnete FlowElement in der Textflusshierarchie zurück.	FlowElement
		getStyle(styleProp:String):* Gibt den Wert des vom styleProp-Parameter festgelegten Stils zurück. Dieser legt den Stilnamen fest und kann einen beliebigen Benutzerstilnamen enthalten.	FlowElement
		getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String [override]	FlowGroupElement
		getTextFlow():flashx.textLayout.elements:TextFlow Durchsucht die Textflusshierarchie in aufsteigender Richtung, um das TextFlow-Stammobjekt für das Element zurückzugeben.	FlowElement
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		initialized(document:Object, id:String):void Wird für MXML-Objekte aufgerufen, nachdem das Implementierungsobjekt erstellt und sämtliche im MXML-Tag angegebenen Komponenteneigenschaften initialisiert wurden.	FlowElement
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		removeChild(child:FlowElement):FlowElement Entfernt das angegebene untergeordnete FlowElement-Objekt aus der Gruppe.	FlowGroupElement
		removeChildAt(index:uint):FlowElement Entfernt das untergeordnete FlowElement-Objekt an der festgelegten Indexposition.	FlowGroupElement
		replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void Ersetzt untergeordnete Elemente in der Gruppe durch die festgelegten neuen Elemente.	FlowGroupElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		setStyle(styleProp:String, newValue:*):void Legt für den vom styleProp-Parameter festgelegten Stil den vom newValue-Parameter festgelegten Wert fest.	FlowElement
		shallowCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement Erstellt eine Kopie dieses FlowElement-Objekts, indem der Inhalt zwischen zwei angegebenen Zeichenpositionen kopiert wird.	FlowElement
		splitAtIndex(childIndex:int):FlowGroupElement Teilt dieses Objekt an der Position, die durch den childIndex-Parameter festgelegt wurde.	FlowGroupElement
		splitAtPosition(relativePosition:int):FlowElement Teilt dieses FlowElement-Objekt an der vom relativePosition-Parameter angegebenen Position, die einer relativen Position im Text für dieses Element entspricht.	FlowElement
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

Eigenschaftendetails

mxmlChildren

Eigenschaft

mxmlChildren:Array

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Wendet ein Array von untergeordneten Elementen auf dieses Objekt an. Verwendet die replaceChildren()-Methode zum Anhängen der Elemente im Array. Vorgesehen für die Verwendung während eines MXML-kompilierten Imports.

Implementierung
public function get mxmlChildren():Array
public function set mxmlChildren(value:Array):void

Auslöser

TypeError — Wenn das Array-Element kein FlowElement oder String ist.

Verwandte API-Elemente

FlowGroupElement.replaceChildren()

numChildren

Eigenschaft

numChildren:int [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Gibt die Anzahl der untergeordneten FlowElements dieses FlowGroupElement-Objekts zurück.

Implementierung
public function get numChildren():int

Konstruktordetails

()

Konstruktor

public function FlowGroupElement()

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Basisklasse - das Aufrufen von new FlowGroupElement() verursacht einen Ausnahmefehler.

Methodendetails

addChild

()

Methode

public function addChild(child:FlowElement):FlowElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Hängt ein untergeordnetes FlowElement-Objekt an. Das neue untergeordnete Element wird an das Ende der Liste der untergeordneten Elemente hinzugefügt.

Parameter

child:FlowElement — Das anzuhängende untergeordnete Element.

Rückgabewerte

FlowElement — Das untergeordnete FlowElement.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird die addChild()-Methode aufgerufen, um einen Bereich zu einem Absatz hinzuzufügen und den Absatz zum Textfluss hinzuzufügen.

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildExample extends Sprite
    {        
        public function FlowGroupElement_addChildExample()
        {
            // create string for text flow
            var simpleText:String = "It was a dark and stormy night.";        
                    
            // define TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span:SpanElement = new SpanElement;
            span.text = simpleText;
            // add span to paragraph and add paragraph to text flow
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

addChildAt

()

Methode

public function addChildAt(index:uint, child:FlowElement):FlowElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Fügt der festgelegten Indexposition ein untergeordnetes FlowElement-Objekt hinzu.

Parameter

	`index:uint` — Indexposition, an der das untergeordnete Element hinzugefügt wird, wobei die erste Position 0 ist.

	`child:FlowElement` — Das hinzuzufügende untergeordnete Element.

Rückgabewerte

FlowElement — Das untergeordnete FlowElement.

Auslöser

RangeError — Der index ist außerhalb des gültigen Bereichs.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird addChildAt aufgerufen, um drei Bereiche zu einem Absatz hinzuzufügen.

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildAtExample extends Sprite
    {        
        public function FlowGroupElement_addChildAtExample()
        {
            // define text strings for the contents of the text flow
            var textA:String = "It was a dark and stormy night. ";
            var textB:String = "The quick red fox jumped over the lazy brown dog. ";
            var textC:String = "Mary had a little lamb. ";
            // define TextFlow, ParagraphElement and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            span1.text = textA;
            span2.text = textB;
            span3.text = textC;
            // add spans at specified positions
            paragraph.addChildAt(0, span2);
            paragraph.addChildAt(0, span1);
            paragraph.addChildAt(1, span3);
            textFlow.addChild(paragraph);
            // assign composer, controller, and update to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findChildIndexAtPosition

()

Methode

public function findChildIndexAtPosition(relativePosition:int):int

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Diese Methode sucht für eine gegebene relative Textposition nach der Indexposition des ersten untergeordneten FlowElements, das die relative Position enthält. Aufgrund von FlowElements mit einer Länge von „null“ kann mehr als ein untergeordnetes Element kann eine relative Position enthalten.

Überprüfen Sie die untergeordneten Elemente, um nach dem FlowElement zu suchen, das die relative Position enthält. Die bereitgestellte relative Position ist relativ zu diesem FlowElement.

Parameter

relativePosition:int — die relative Position zu diesem Element

Rückgabewerte

int — Indexposition des ersten untergeordneten Elements, das die relativePosition enthält

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird die Indexposition eines untergeordneten Elements an einer relativen Position im Text gesucht und die Farbe auf Rot gesetzt.

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findChildIndexAtPositionExample extends Sprite
    {        
        public function FlowGroupElement_findChildIndexAtPositionExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the index of the child containing relative offset 21; set color to red
            var index:int = textFlow.findChildIndexAtPosition(21);
            textFlow.getChildAt(index).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findLeaf

()

Methode

public function findLeaf(relativePosition:int):FlowLeafElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Sucht bei einer gegebenen relativen Textposition nach dem Blattelement, das die Position enthält.

Sucht in der Flusselementhierarchie nach dem FlowLeafElement. das die festgelegte Position enthält. Die festgelegte Position ist relativ zu diesem FlowElement-Objekt.

Parameter

relativePosition:int — die zu suchende relative Textindexposition

Rückgabewerte

FlowLeafElement — das Blattelement, das die relative Position enthält.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel werden zwei Absätze erstellt, das FlowLeafElement an der relativen Position 55 gesucht und die dazugehörige Farbe auf Rot gesetzt.

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findLeafExample extends Sprite
    {        
        public function FlowGroupElement_findLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the FlowLeafElement object containing relative offset 55; set color to red
            var leaf:SpanElement = textFlow.findLeaf(55) as SpanElement;
            leaf.color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildAt

()

Methode

public function getChildAt(index:int):FlowElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Gibt das untergeordnete FlowElement an der festgelegten Indexposition zurück.

Parameter

index:int — die Position, an der nach dem FlowElement-Objekt gesucht wird.

Rückgabewerte

FlowElement — das untergeordnete FlowElement-Objekt an der festgelegten Position.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird die getChildAt()-Methode verwendet, um auf einen Absatz im Textfluss zuzugreifen und die Farbe einer der Bereiche auf Rot zu setzen.

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getChildAtExample extends Sprite
    {        
        public function FlowGroupElement_getChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the paragraph at index position 1
            var para:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
            // find the span at index position 1 of the paragraph and color it red
            para.getChildAt(1).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildIndex

()

Methode

public function getChildIndex(child:FlowElement):int

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Sucht in untergeordneten Elementen nach dem festgelegten FlowElement-Objekt und gibt dessen Indexposition zurück.

Parameter

child:FlowElement — Das FlowElement-Objekt, nach dem die untergeordneten Elemente durchsucht werden.

Rückgabewerte

int — Die Indexposition des festgelegten untergeordneten Elements. Wenn child nicht gefunden wurde, wird 1 zurückgegeben.

getFirstLeaf

()

Methode

public function getFirstLeaf():FlowLeafElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Gibt das erste untergeordnete FlowLeafElement für diese Gruppe zurück.

Rückgabewerte

FlowLeafElement — das erste FlowLeafElement-Objekt.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel werden zwei Absätze erstellt, das erste FlowLeafElement-Objekt gesucht und die zugehörige Farbe auf Rot gesetzt.

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getFirstLeafExample extends Sprite
    {        
        public function FlowGroupElement_getFirstLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a </flow:span>"+
                        "<flow:span fontStyle=\"italic\">dark and stormy</flow:span>"+
                        "<flow:span> night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // get first FlowLeafElement object and set its color to red
            var leaf:SpanElement = textFlow.getFirstLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            // add composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getLastLeaf

()

Methode

public function getLastLeaf():FlowLeafElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Gibt das letzte untergeordnete FlowLeafElement für diese Gruppe zurück.

Rückgabewerte

FlowLeafElement — das letzte FlowLeafElement-Objekt.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel werden zwei Absätze erstellt, das letzte FlowLeafElement-Objekt gesucht und die zugehörige Farbe auf Rot gesetzt.

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getLastLeafExample extends Sprite
    {        
        public function FlowGroupElement_getLastLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            //find last leaf, set its color to red and display text
            var leaf:SpanElement = textFlow.getLastLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getText

()

Methode

override public function getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String

Parameter

	`relativeStart:int` (default = `0`)

	`relativeEnd:int` (default = `-1`)

	`paragraphSeparator:String` (default = " ")

Rückgabewerte

String

removeChild

()

Methode

public function removeChild(child:FlowElement):FlowElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Entfernt das angegebene untergeordnete FlowElement-Objekt aus der Gruppe.

Parameter

child:FlowElement — Das zu entfernende untergeordnete Element.

Rückgabewerte

FlowElement — Das entfernte untergeordnete FlowElement-Objekt.

Auslöser

ArgumentError — Das child wird nicht gefunden.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird der dritte Bereich im zweiten Absatz des Textflusses entfernt.

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildExample extends Sprite
    {        
        public function FlowGroupElement_removeChildExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            // get paragraph with ID = 'para2' and remove its child with name = 'span4'
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.removeChild(textFlow.getElementByID("span4"));
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

removeChildAt

()

Methode

public function removeChildAt(index:uint):FlowElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Entfernt das untergeordnete FlowElement-Objekt an der festgelegten Indexposition.

Parameter

index:uint — Position, an der das untergeordnete Element entfernt wird.

Rückgabewerte

FlowElement — Das untergeordnete FlowElement-Objekt, das von der festgelegten Position entfernt wurde.

Auslöser

RangeError — Der index ist außerhalb des gültigen Bereichs.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel wird die removeChildAt()-Methode aufgerufen, um den zweiten der drei Absätze zu entfernen.

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildAtExample extends Sprite
    {        
        public function FlowGroupElement_removeChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Mary had a little lamb. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow, import text, add composer and controller 
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // remove child at index position 1 (with first position = 0); display text
            textFlow.removeChildAt(1);
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

replaceChildren

()

Methode

public function replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Ersetzt untergeordnete Elemente in der Gruppe durch die festgelegten neuen Elemente. Verwenden Sie die beginChildIndex- und endChildIndex-Parameter, um den Vorgang folgenderweise zu bestimmen:

Übergeben Sie keine Ersatzelemente, um Elemente zu löschen.
Um Elemente einzufügen, übergeben Sie den gleichen Wert für beginChildIndex und endChildIndex. Die neuen Elemente werden vor der festgelegten Indexposition eingefügt.
Um Elemente anzuhängen, übergeben Sie numChildren für beginChildIndex und endChildIndex.

Andernfalls ersetzt diese Methode die festgelegten Elemente beginnend mit dem Element in beginChildIndex und endend in endChildIndex (wobei dieses nicht inbegriffen ist).

Parameter

	`beginChildIndex:int` — Der Indexwert für die Startposition des Ersetzungsbereichs im Array der untergeordneten Elemente.

	`endChildIndex:int` — Der Indexwert für die Endposition des Ersetzungsbereichs im Array der untergeordneten Elemente.

	`... rest` — Die Elemente, die den festgelegten Bereich mit Elementen ersetzen. Dies kann eine Folge sein, die Textflusselemente oder entsprechende Arrays bzw. Vektoren enthält.

Auslöser

RangeError — Der angegebene Wert für beginChildIndex oder endChildIndex liegt außerhalb des gültigen Bereichs.

Beispiel ( Verwendung dieses Beispiels )

In diesem Beispiel werden drei Bereiche im zweiten Absatz durch zwei neue ersetzt.

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_replaceChildrenExample extends Sprite
    {        
        public function FlowGroupElement_replaceChildrenExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
            
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // define two new SpanElement objects
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            span1.text = "Mary had a little lamb. ";
            span2.text = "And this little pig stayed home. ";
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,600));
            // get paragraph with ID = 'para2' and replace its children with span1 and span2
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.replaceChildren(0, 3, [span1, span2]);
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

splitAtIndex

()

Methode

public function splitAtIndex(childIndex:int):FlowGroupElement

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

Flash Player 10, AIR 1.5

Teilt dieses Objekt an der Position, die durch den childIndex-Parameter festgelegt wurde. Wenn dieses Gruppenelement ein übergeordnetes Element hat, wird eine oberflächliche Kopie dieses Objekts erstellt und seine untergeordneten Elemente werden durch die Elemente bis zur Indexposition ersetzt. Verschiebt Elemente nach childIndex in die Kopie.

Parameter

childIndex:int

Rückgabewerte

FlowGroupElement — das neue FlowGroupElement-Objekt.

Auslöser

RangeError — wenn childIndex größer als die Länge der untergeordneten Elemente ist.

Rechtliche Hinweise | Onlinedatenschutzerklärung

FlowGroupElement - AS3

Paketex

Sprachelemente

Anhänge

Paket flashx.textLayout.elements

mxmlChildren

numChildren