Camera  - AS3

Die von der Kamera erkannte Menge an Bewegung. Die zulässigen Werte liegen zwischen 0 (keine erfasste Bewegung) und 100 (sehr starke Bewegung). Anhand des Werts dieser Eigenschaft können Sie ermitteln, ob eine Einstellung für die setMotionLevel()-Methode übergeben werden muss.

Wenn die Kamera verfügbar ist, aufgrund eines nicht erfolgten Video.attachCamera()-Aufrufs noch nicht verwendet wird, wird diese Eigenschaft auf -1 gesetzt.

Beim Streaming ausschließlich unkomprimierter lokaler Videos wird diese Eigenschaft nur dann gesetzt, wenn der Ereignisprozedur eine Funktion zugewiesen wurde. Andernfalls ist diese Eigenschaft nicht definiert.

Verwandte API-Elemente

Die Bandbreite (in Byte), die für den momentan ausgehenden Videofeed maximal zur Verfügung steht. Der Wert 0 bedeutet, dass der Feed die zur Beibehaltung der gewünschten Bildqualität erforderliche Bandbreite für Videos nutzen kann.

Legen Sie diese Eigenschaft über die setQuality()-Methode fest.

Verwandte API-Elemente

Die Abtastrate in Bildern pro Sekunde, mit der die Kamera Daten erfasst. Diese Eigenschaft kann nicht eingestellt werden. Mit der setMode()-Methode können Sie jedoch die verwandte Eigenschaft fps festlegen, welche die maximale Bildrate angibt, mit der die Kamera Daten erfassen soll.

Verwandte API-Elemente

Die maximale Rate in Bildern pro Sekunde, mit der die Kamera Daten erfassen kann. Die höchstmögliche Rate richtet sich nach den Möglichkeiten der Kamera; diese Bildrate wird möglicherweise nicht erzielt.

• Über die setMode()-Methode können Sie den gewünschten Wert für diese Eigenschaft festlegen.
• Verwenden Sie die currentFPS-Eigenschaft, um festzustellen, mit welcher Abtastrate die Kamera derzeit Daten erfasst.

Verwandte API-Elemente

Die aktuelle Aufnahmebildhöhe in Pixel. Über die setMode()-Methode können Sie einen Wert für diese Eigenschaft festlegen.

Verwandte API-Elemente

Ein auf null basierender Index, der die Position der Kamera im Camera.names-Array angibt, das alle verfügbaren Kameras aufführt.

Verwandte API-Elemente

Die isSupported-Eigenschaft hat den Wert true, wenn die Camera-Klasse von der aktuellen Plattform unterstützt wird, andernfalls hat sie den Wert false.

Die Anzahl der Videobilder, die vollständig übertragen (sogenannte Schlüsselbilder) und nicht mit dem Algorithmus zur Videokomprimierung interpoliert werden. Der Standardwert ist 15, d. h., jedes fünfzehnte Bild ist ein Schlüsselbild. Der Wert 1 bedeutet, dass jedes Bild ein Schlüsselbild ist. Zulässige Werte sind Zahlen von 1 bis 300.

Verwandte API-Elemente

Gibt an, ob eine lokale Wiedergabe der Kameraaufnahmen wie bei der Live-Übertragung mit Flash Media Server komprimiert und dekomprimiert (true) oder nicht komprimiert (false) wird. Der Standardwert ist false.

Obwohl ein komprimierter Stream für Testzwecke nützlich ist, beispielsweise bei der Vorschau der Einstellungen für die Videoqualität, entsteht dadurch ein erheblicher Verarbeitungsaufwand. Die lokale Ansicht wird komprimiert und für die Übertragung bearbeitet wie in einer Live-Verbindung und dann für die lokale Anzeige dekomprimiert.

Um diesen Wert einzustellen, verwenden Sie Camera.setLoopback(). Wenn diese Eigenschaft auf „true“ gesetzt ist, können Sie den Komprimierungsgrad über Camera.setQuality() festlegen.

Verwandte API-Elemente

Die erforderliche Bewegungsstärke zum Auslösen des activity-Ereignisses. Die zulässigen Werte liegen zwischen 0 und 100. Der Standardwert ist 50.

Videos können unabhängig vom Wert der Eigenschaft motionLevel wiedergegeben werden. Weitere Informationen hierzu finden Sie unter setMotionLevel().

Verwandte API-Elemente

Die Zeit in Millisekunden zwischen dem Zeitpunkt, zu dem die Kamera keine Bewegung mehr erfasst, und dem Zeitpunkt, zu dem das activity-Ereignis aufgerufen wird. Der Standardwert ist 2000 (2 Sekunden).

Legen Sie diesen Wert über die setMotionLevel()-Methode fest.

Verwandte API-Elemente

Ein boolescher Wert, der angibt, ob der Benutzer im Flash Player-Dialogfeld „Zugriffsschutz“ den Zugriff auf die Kamera verweigert (true) oder gewährt (false) hat. Wenn sich dieser Wert ändert, wird das status-Ereignis ausgelöst.

Verwandte API-Elemente

Der Name der aktuellen Kamera, der von der Kamerahardware zurückgegeben wird.

Verwandte API-Elemente

Ein Array mit den Namen aller verfügbaren Kameras. Beim Zugriff auf dieses Array wird nicht das Datenschutz-Dialogfeld von Flash Player angezeigt. Dieses Array stellt den auf null basierenden Index jeder Kamera sowie die Anzahl der Kameras im System (mithilfe von names.length) bereit.

Für das Aufrufen der names-Eigenschaft ist eine umfassende Untersuchung der Hardware erforderlich. In den meisten Fällen können Sie die Standardkamera verwenden.

Verwandte API-Elemente

Bestimmen Sie, ob der Anwendung die Berechtigung zur Verwendung der Kamera erteilt wurde.

Verwandte API-Elemente

Gibt an, auf welcher Seite des Geräts sich die Kamera befindet.

Verwenden Sie die position-Eigenschaft, um zu bestimmen, ob sich die Kamera eines mobilen Geräts auf der Vorderseite oder auf der Rückseite des Geräts befindet. Die folgende Funktion überprüft jede verfügbare Kamera, bis eine Kamera an der gewünschten Position gefunden wird. Wenn es keine Kamera an der gewünschten Position gibt, wird die Standardkamera zurückgegeben.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

Bei mobilen Geräten ist die Kameraposition normalerweise entweder CameraPosition.FRONT oder CameraPosition.BACK. Wenn die Position der Kamera nicht ermittelt werden kann, wird die Position als CameraPosition.UNKNOWN gemeldet. Bei Desktopplattformen ist die Position immer CameraPosition.UNKNOWN.

Konstanten für die gültigen Werte dieser Eigenschaft sind in der CameraPosition-Klasse definiert

Verwandte API-Elemente

Die erforderliche Bildqualität, die sich aus dem Grad der Komprimierung jedes Videobilds ergibt. Die zulässigen Werte liegen zwischen 1 (niedrigste Qualität, maximale Komprimierung) und 100 (höchste Qualität, keine Komprimierung). Der Standardwert ist 0, d. h., die Bildqualität kann gegebenenfalls geändert werden, damit die Bandbreite nicht überschritten wird.

Legen Sie diese Eigenschaft über die setQuality()-Methode fest.

Verwandte API-Elemente

Die aktuelle Aufnahmebildbreite in Pixel. Über die setMode()-Methode können Sie den gewünschten Wert für diese Eigenschaft festlegen.

Verwandte API-Elemente

Füllt ein Byte-Array aus einem rechteckigen Bereich mit Pixeldaten

Schreibt eine vorzeichenlose Ganzzahl (ein nicht multiplizierter 32-Bit-Pixelwert) für jedes Pixel in das Byte-Array. Das Array wird an die erforderliche Anzahl von Bytes angepasst, um alle Pixel aufzunehmen.

Parameter

Verwandte API-Elemente

Füllt einen Vektor aus einem rechteckigen Bereich mit Pixeldaten.

Schreibt eine vorzeichenlose Ganzzahl (ein nicht multiplizierter 32-Bit-Pixelwert) für jedes Pixel in den Vektor. Der Vektor wird an die erforderliche Anzahl von Einträgen angepasst, um alle Pixel aufzunehmen.

Parameter

Verwandte API-Elemente

Kopiert das letzte Bild in eine Bitmap.

Mit dieser Methode wird der Inhalt des letzten Bilds in eine BitmapData-Instanz kopiert.

Parameter

Verwandte API-Elemente

Gibt eine Referenz auf ein Camera-Objekt zum Aufnehmen von Videos zurück. Um mit der Videoaufnahme zu beginnen, muss das Camera-Objekt mit einem Videoobjekt verknüpft werden (siehe Video.attachCamera() ). Wenn Sie Video an Flash Media Server übertragen möchten, rufen Sie NetStream.attachCamera() auf, um das Camera-Objekt mit einem NetStream-Objekt zu verknüpfen.

Mehrere Aufrufe der getCamera()-Methode verweisen auf denselben Kameratreiber. Wenn der Code Elemente wie firstCam:Camera = getCamera() und secondCam:Camera = getCamera() enthält, verweisen firstCam und secondCam somit auf dieselbe Kamera, bei der es sich um die Standardkamera des Benutzers handelt.

Bei mobilen Geräten, die sowohl über eine nach vorn als auch über eine nach hinten gerichtete Kamera verfügen, können Sie jeweils nur von einer Kamera Video erfassen.

Im Allgemeinen muss kein Wert für den name-Parameter übergeben werden. Verwenden Sie einfach getCamera(), um einen Verweis auf die Standardkamera zurückzugeben. Im Bedienfeld für die Kameraeinstellungen kann der Benutzer eine Standardkamera angeben (Informationen hierzu weiter unten in diesem Abschnitt).

Sie können ActionScript nicht verwenden, um die Berechtigungseinstellung „Zulassen“ oder „Verweigern“ für den Kamerazugriff festzulegen, Sie können jedoch das Adobe Flash Player Dialogfeld für die Kameraeinstellungen anzeigen, in dem der Benutzer den Kamerazugriff steuern kann. Wenn eine SWF-Datei mit der attachCamera()-Methode versucht, die von der getCamera()-Methode zurückgegebene Kamera mit einem Video- oder NetStream-Objekt zu verbinden, zeigt Flash Player ein Dialogfeld an, in dem der Benutzer den Zugriff auf die Kamera zulassen oder verweigern kann. (Achten Sie darauf, dass die Größe des Anwendungsfensters mindestens 215 x 138 Pixel beträgt. Dies ist die in Flash Player erforderliche Mindestgröße für die Anzeige des Dialogfelds.) Nachdem der Benutzer im Dialogfeld für die Kameraeinstellungen eine Option ausgewählt hat, wird in Flash Player ein Informationsobjekt im status-Ereignis zurückgegeben, das die Auswahl des Benutzers angibt. Mit Camera.muted wird angegeben, dass der Benutzer den Zugriff auf eine Kamera verweigert hat. Mit Camera.Unmuted wird angegeben, dass der Benutzer den Zugriff auf eine Kamera gewährt hat. Über die muted-Eigenschaft können Sie ohne Bearbeitung des status-Ereignisses feststellen, ob ein Benutzer den Zugriff auf eine Kamera verweigert oder gewährt hat.

In Flash Player kann der Benutzer permanente Zugriffsschutzeinstellungen für eine bestimmte Domäne festlegen, indem er während des Abspielens einer SWF-Datei mit der rechten Maustaste (Windows und Linux) bzw. bei gedrückter Ctrl-Taste (Mac OS) klickt, „Einstellungen“ auswählt, das Dialogfeld „Zugriffsschutz“ öffnet und „Speichern“ auswählt. Wenn ein Benutzer „Speichern“ auswählt, wird er in Flash Player nicht mehr dazu aufgefordert, den Zugriff von SWF-Dateien in der Domäne auf die Kamera zu gewähren oder zu verweigern.

Hinweis: Die attachCamera()-Methode ruft das Dialogfeld zum Zulassen oder Verweigern des Zugriffs auf die Kamera nicht auf, wenn der Benutzer den Zugriff verweigert hat, indem er in den Flash Player-Einstellungen die Einstellung „Speichern“ gewählt hat. In diesem Fall können Sie den Benutzer auffordern, die Einstellung „Zulassen“ oder „Verweigern“ zu ändern, indem Sie mit Security.showSettings(SecurityPanel.PRIVACY) das Bedienfeld „Zugriffsschutz“ von Flash Player für den Benutzer anzeigen.

Wenn getCamera() den Wert null zurückgibt, wird die Kamera entweder gerade in einer anderen Anwendung verwendet oder im System sind keine Kameras installiert. Mithilfe der names.length-Eigenschaft können Sie feststellen, ob Kameras installiert sind. Um das Kameraeinstellungsbedienfeld von Flash Player anzuzeigen, in dem der Benutzer die Kamera wählen kann, die von getCamera() referenziert werden soll, verwenden Sie Security.showSettings(SecurityPanel.CAMERA).

Der Suchlauf zum Überprüfen der Hardware auf installierte Kameras kann einige Zeit in Anspruch nehmen. Wenn die Laufzeitumgebung mindestens eine Kamera gefunden hat, wird der Suchlauf für diese Player-Instanz nicht noch einmal durchgeführt. Wenn die Laufzeitumgebung jedoch keine Kameras findet, wird der Suchlauf bei jedem Aufruf von getCamera durchgeführt. Diese Funktion ist besonders hilfreich, wenn eine Kamera zwar vorhanden, aber deaktiviert ist. Sofern Ihre SWF-Datei eine Schaltfläche „Wiederholen“ besitzt, mit der getCamera aufgerufen wird, kann Flash Player nach der Kamera suchen, ohne dass die SWF-Datei erneut gestartet werden muss.

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Fordert Kameraberechtigung für die Anwendung an.

Gibt die Videobilder an, die vollständig übertragen (sogenannte Schlüsselbilder) und nicht mit dem Algorithmus zur Videokomprimierung interpoliert werden. Diese Methode ist nur bei der Übertragung von Videos über Flash Media Server anwendbar.

Mit dem Algorithmus zur Videokomprimierung in Flash werden Videos so komprimiert, dass nur die ab dem letzten Bild eines Videos geänderten Bildbereiche übertragen werden. Diese Abschnitte werden als interpolierte Bilder bezeichnet. Bilder eines Videos können entsprechend dem Inhalt des vorherigen Bilds interpoliert werden. Bei einem Schlüsselbild handelt es sich jedoch um ein vollständiges Videobild, das nicht aus vorherigen Bildern interpoliert wurde.

Berücksichtigen Sie zum Festlegen eines Werts für den keyFrameInterval-Parameter die Bandbreitennutzung und den Zugriff auf die Videowiedergabe. Durch die Angabe eines höheren Werts für keyFrameInterval (weniger häufiges Senden von Schlüsselbildern) wird beispielsweise die Bandbreitennutzung verringert. Dadurch wird jedoch möglicherweise die erforderliche Zeit zum Positionieren des Abspielkopfes an einem bestimmten Punkt im Video erhöht. Unter Umständen muss eine höhere Anzahl Videobilder interpoliert werden, damit die Wiedergabe des Videos fortgesetzt werden kann.

Durch die Angabe eines niedrigen Werts für keyFrameInterval (häufiges Senden von Schlüsselbildern) wird dagegen die Bandbreitennutzung erhöht, da häufiger vollständige Videobilder übertragen werden. Gleichzeitig wird möglicherweise jedoch die erforderliche Zeit zum Suchen eines bestimmten Videobilds in einem aufgenommenen Video verringert.

Parameter

Verwandte API-Elemente

Gibt an, ob ein komprimierter Videostream für die lokale Wiedergabe der Kamera verwendet wird. Diese Methode kann nur bei der Übertragung von Videos mit Flash Media Server angewendet werden. Durch Setzen von compress auf true kann präziser angezeigt werden, wie ein Video bei der Wiedergabe in Echtzeit wiedergegeben wird.

Obwohl ein komprimierter Stream für Testzwecke nützlich ist, beispielsweise bei der Vorschau der Einstellungen für die Videoqualität, entsteht dadurch ein erheblicher Verarbeitungsaufwand. Die lokale Wiedergabe wird nicht einfach nur komprimiert, sie wird komprimiert, wie bei einer Live-Verbindung für die Übertragung bearbeitet und dann für die lokale Wiedergabe dekomprimiert.

Wenn Sie compress auf true setzen, können Sie die Stärke der Komprimierung über Camera.setQuality() festlegen.

Parameter

Verwandte API-Elemente

Legt als Kameraaufnahmemodus den systemeigenen Modus fest, mit dem die angegebenen Kriterien am besten erfüllt werden. Wenn die Kamera über keinen systemeigenen Modus verfügt, der mit allen übergebenen Parametern übereinstimmt, wird in der Laufzeitumgebung ein Aufnahmemodus ausgewählt, der dem gewünschten Modus am ehesten entspricht. Bei diesem Vorgang werden möglicherweise Teile des Videobilds abgeschnitten sowie Bilder übersprungen.

Standardmäßig überspringt die Laufzeitumgebung Bilder, sofern dies zum Beibehalten der gewünschten Bildgröße erforderlich ist. Um die Anzahl der übersprungenen Bilder zu minimieren, auch wenn dazu ggf. die Bildgröße reduziert werden muss, übergeben Sie den Wert false für den Parameter favorArea.

Bei Auswahl eines systemeigenen Modus wird in der Laufzeitumgebung versucht, das gewünschte Bildseitenverhältnis möglichst beizubehalten. Wenn Sie beispielsweise den Befehl myCam.setMode(400, 400, 30) ausgeben und die maximalen Werte der Kamera für Breite und Höhe 320 und 288 betragen, werden in der Laufzeitumgebung sowohl die Breite als auch die Höhe auf den Wert 288 gesetzt. So wird in der Laufzeitumgebung das gewünschte Bildseitenverhältnis von 1:1 beibehalten.

Wenn Sie überprüfen möchten, welche Werte diesen Eigenschaften zugewiesen wurden, nachdem in der Laufzeitumgebung der Modus ausgewählt wurde, der den gewünschten Werten am nächsten kommt, verwenden Sie die Eigenschaften width, height und fps.

Wenn Sie Flash Media Server verwenden, können Sie auch einzelne Bilder erfassen oder Zeitrafferaufnahmen erstellen. Weitere Informationen finden Sie unter NetStream.attachCamera().

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Gibt die erforderliche Bewegungsstärke zum Auslösen des activity-Ereignisses an. Gibt optional die Zeit in Millisekunden an, die ohne Aktivität vergehen muss, bevor in der Laufzeitumgebung keine Bewegung mehr festgestellt und das Ereignis ausgelöst wird.

Hinweis: Videos können unabhängig vom Wert des motionLevel-Parameters wiedergegeben werden. Dieser Parameter legt nur fest, wann und unter welchen Umständen das Ereignis ausgelöst wird, nicht jedoch, ob tatsächlich Videodaten aufgezeichnet oder wiedergegeben werden.

Wenn die Kamera überhaupt keine Bewegung erkennen soll, legen Sie für den motionLevel-Parameter den Wert 100 fest. Das activity-Ereignis wird dann nie ausgelöst. (Dieser Wert wird wahrscheinlich nur für Testzwecke verwendet, beispielsweise um vorübergehend alle Prozeduren zu deaktivieren, die bei diesem Ereignis normalerweise ausgelöst werden.)

Über die activityLevel-Eigenschaft können Sie feststellen, welche Bewegungsstärke derzeit mit der Kamera erkannt wird. Die Bewegungstoleranzwerte entsprechen direkt den Aktivitätswerten. Völliges Fehlen von Bewegung entspricht dem Aktivitätswert 0. Ständige Bewegung entspricht dem Aktivitätswert 100. Bei fehlender Bewegung ist der Aktivitätswert niedriger als die Bewegungstoleranz, bei Bewegung übersteigen die Aktivitätswerte häufig die Bewegungstoleranz.

Diese Methode ähnelt Microphone.setSilenceLevel(). Mit beiden Methoden wird angegeben, zu welchem Zeitpunkt das activity-Ereignis ausgelöst werden soll. Diese Methoden haben jedoch deutlich unterschiedliche Auswirkungen auf das Veröffentlichen von Streams:

• Microphone.setSilenceLevel() dient zur Optimierung der Bandbreite. Wenn ein Audiostream als lautlos eingestuft wird, werden keine Audiodaten gesendet. Stattdessen wird eine Meldung gesendet, um den Beginn der Inaktivität (Stille) anzuzeigen.
• Camera.setMotionLevel() ist dazu bestimmt, Bewegung festzustellen und hat keinen Einfluss auf die Bandbreitenauslastung. Auch wenn ein Videostream keine Bewegung feststellt, werden weiterhin Videodaten gesendet.

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Legt die maximale Bandbreite pro Sekunde oder die erforderliche Bildqualität des aktuell ausgehenden Videofeeds fest. Diese Methode ist in der Regel nur bei der Übertragung von Videos über Flash Media Server anwendbar.

Mit dieser Methode können Sie festlegen, ob die Ausnutzung der Bandbreite oder die Bildqualität des ausgehenden Videofeeds für die Anwendung Vorrang haben soll.

• Soll die Ausnutzung der Bandbreite Vorrang haben, geben Sie einen Wert für bandwidth an und belegen quality mit dem Wert 0. Die Laufzeitumgebung überträgt Video dann innerhalb der angegebenen Bandbreite mit der bestmöglichen Qualität. Die Bildqualität wird von der Laufzeitumgebung gegebenenfalls verringert, um eine Überschreitung der angegebenen Bandbreite zu verhindern. Allgemein gilt, dass bei stärkerer Bewegung die Qualität abnimmt.
• Soll die Qualität Vorrang haben, belegen Sie bandwidth mit dem Wert 0 und geben für quality einen numerischen Wert an. Die Laufzeitumgebung verwendet dann so viel Bandbreite, wie zum Beibehalten der angegebenen Qualität erforderlich ist. Die Framerate wird von der Laufzeitumgebung gegebenenfalls verringert, um die Bildqualität beizubehalten. Allgemein gilt, dass sich bei stärkerer Bewegung auch die Nutzung der Bandbreite erhöht.
• Übergeben Sie numerische Werte für beide Parameter, um anzugeben, dass Bandbreite und Bildqualität gleichermaßen wichtig sind. Die Laufzeitumgebung überträgt Video mit der angegebenen Qualität, ohne die angegebene Bandbreite zu überschreiten. Die Framerate wird von der Laufzeitumgebung gegebenenfalls verringert, um die Bildqualität ohne Überschreiten der angegebenen Bandbreite beizubehalten.

Parameter

Verwandte API-Elemente

Wird ausgelöst, wenn die Sitzung einer Kamera gestartet oder beendet wird. Rufen Sie Camera.setMotionLevel() auf, um festzulegen, wie viel Bewegung nötig ist, damit ein activity-Ereignis mit einem activating-Wert von true ausgelöst wird, oder um festzulegen, wie viel Zeit ohne Aktivität vergehen muss, bevor ein activity-Ereignis mit einem activating-Wert von false ausgelöst wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird abgesetzt, wenn die Anwendung die Berechtigung zur Verwendung der Kamera auf dem Gerät anfordert. Überprüfen Sie den Wert der Eigenschaft Status, um festzustellen, ob die Berechtigung gewährt oder verweigert wurde.

Verwandte API-Elemente

Wird ausgelöst, wenn der Status einer Kamera protokolliert wird. Vor dem Zugriff auf eine Kamera zeigt die Laufzeitumgebung ein Datenschutz-Dialogfeld an, in dem Benutzer den Zugriff auf die Kamera zulassen oder verweigern können. Wenn der Wert der code-Eigenschaft auf "Camera.Muted" gesetzt ist, hat der Benutzer den Zugriff der SWF-Datei auf die Kamera verweigert. Wenn der Wert der code-Eigenschaft auf "Camera.Unmuted" gesetzt ist, hat der Benutzer den Zugriff der SWF-Datei auf die Kamera gewährt.

Hinweis: Dieses Ereignis wird auf der AIR-Plattform nicht abgesetzt. Es wird nur in Flash Player verwendet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird abgesetzt, nachdem ein neuer Kamera-Frame von der Laufzeit verarbeitet wurde und zum Kopieren zur Verfügung steht.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Hinweis: Dieses Beispiel kann nur dann korrekt nachvollzogen werden, wenn eine Kamera mit dem Computer verbunden ist.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}