NetStatusEvent  - AS3

Ein Objekt mit Eigenschaften, die den Status oder die Fehlerbedingung des Objekts beschreiben.

Das Informationsobjekt kann eine code-Eigenschaft besitzen, in der eine Zeichenfolge enthalten ist, die ein bestimmtes Ereignis oder eine level-Eigenschaft darstellt, die wiederum eine "status" oder "error" lautende Zeichenfolge enthält.

Das Informationsobjekt kann auch etwas anderes sein. Die Eigenschaften code und level funktionieren bei einigen Implementierungen möglicherweise nicht korrekt, und einige Server senden andere Objekte.

P2P-Verbindungen senden Meldungen an eine NetConnection mit einem stream-Parameter im Informationsobjekt, der angibt, zu welchem NetStream die Meldung gehört.

Beispielsweise senden die Flex Data Services sogenannte Message-Objekte, die zu Fehlermeldungen führen, wenn Sie versuchen, auf eine der Eigenschaften code oder level zuzugreifen.

In der folgenden Tabelle sind die möglichen Stringwerte der Eigenschaften code und level aufgeführt.

Falls wiederholt Pufferfehler angezeigt werden, sollten Sie versuchen, den Puffer mit der Eigenschaft NetStream.bufferTime zu ändern.

Verwandte API-Elemente

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Erstellt ein Ereignisobjekt, das Informationen über netStatus-Ereignisse enthält. Ereignisobjekte werden Ereignis-Listenern als Parameter übergeben.

Verwandte API-Elemente

Erstellt eine Kopie des NetStatusEvent-Objekts und stellt den Wert jeder Eigenschaft so ein, dass er dem Wert des Originals entspricht.

Gibt eine Zeichenfolge zurück, die alle Eigenschaften des NetStatusEvent-Objekts enthält. Der String liegt im folgenden Format vor:

[NetStatusEvent type=Wert bubbles=Wert cancelable=Wert info=Wert]

Definiert den Wert der Eigenschaft type eines netStatus-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Bei diesem Beispiel wird die netStatusHandler-Methode als Listener für das NetStatusEvent-Ereignis NetConnection.netStatus registriert. Sobald der Status (Erfolg/Fehler) des NetConnection.connect()-Versuchs feststeht, wird diese Methode vom netStatus-Ereignis ausgelöst. Wenn der Versuch, eine Verbindung zum NetConnection-Objekt herzustellen, erfolgreich ist (wenn also die Eigenschaft info des vom netStatus-Ereignis ausgelösten NetStatusEvent-Objekts die code-Eigenschaft für Erfolg aufweist), werden die Video- und NetStream-Objekte erstellt und die Methoden Video.attachNetStream() und NetStream.play() aufgerufen.

Hinweis: Zur Ausführung dieses Beispiels benötigen Sie eine FLV-Datei, deren Name und Speicherort mit der an videoURL übergebenen Variablen übereinstimmt. In diesem Fall ist das eine FLV-Datei mit dem Namen „Video.flv“, die in dem Ordner abgelegt ist, in dem sich die SWF-Datei befindet.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }