Date  - AS3

Der von einem Date-Objekt gemäß der Ortszeit angegebenen Tag des Monats (eine Ganzzahl von 1 bis 31). Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Gibt den Tag des Monats (eine Ganzzahl von 1 bis 31) eines Date-Objekts gemäß der Weltzeit (UTC) zurück.

Verwandte API-Elemente

Der von dem Date-Objekt gemäß der Ortszeit angegebenen Wochentag (0 für Sonntag, 1 für Montag usw.). Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Der Wochentag (0 für Sonntag, 1 für Montag usw.) dieses Date-Objekts gemäß Weltzeit (UTC).

Verwandte API-Elemente

Die vollständige Jahreszahl (eine vierstellige Zahl, z. B. 2000) eines Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Die vierstellige Jahreszahl des Date-Objekts gemäß Weltzeit (UTC).

Verwandte API-Elemente

Die Stunde (eine Ganzzahl von 0 bis 23) des day-Teils eines Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Die Stunde (eine Ganzzahl von 0 bis 23) des Date-Objekts gemäß der Weltzeit (UTC).

Verwandte API-Elemente

Der milliseconds-Teil (eine Ganzzahl von 0 bis 999) des Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Der milliseconds-Teil (eine Ganzzahl von 0 bis 999) eines Date-Objekts gemäß Weltzeit (UTC).

Verwandte API-Elemente

Der minutes-Teil (eine Ganzzahl von 0 bis 59) des Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Der minutes-Teil (eine Ganzzahl von 0 bis 59) eines Date-Objekts gemäß Weltzeit (UTC).

Verwandte API-Elemente

Der month-Teil (0 für Januar, 1 für Februar usw.) dieses Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Gibt den month-Teil (von 0 für Januar bis 11 für Dezember) eines Date-Objekts gemäß der Weltzeit (UTC) zurück.

Verwandte API-Elemente

Der seconds-Teil (eine Ganzzahl von 0 bis 59) des Date-Objekts gemäß der Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

Der seconds-Teil (eine Ganzzahl von 0 bis 59) eines Date-Objekts gemäß Weltzeit (UTC).

Verwandte API-Elemente

Die Anzahl der Millisekunden Gibt seit dem 1. Januar 1970, 0.00 Uhr, Weltzeit (UTC) für ein Date-Objekt. Mit dieser Methode können Sie beim Vergleich von mindestens zwei Date-Objekten einen bestimmten Zeitpunkt angeben.

Verwandte API-Elemente

Gibt die Differenz zwischen der Weltzeit (UTC) und der Ortszeit des Computers in Minuten zurück. Dieser Wert gibt die Anzahl von Minuten an, die Sie zur Ortszeit des Computers hinzufügen müssen, damit sie gleich der Weltzeit ist. Ist die Ortszeit des Computers später als die Weltzeit, wird ein negativer Wert zurückgegeben.

Verwandte API-Elemente

Erstellt ein neues Date-Objekt mit dem angegebenen Datum und der angegebenen Uhrzeit.

Dem Date()-Konstruktor können bis zu sieben Parameter (year, month, ..., millisecond) übergeben werden, um ein Datum und die Uhrzeit bis hin zu den Millisekunden anzugeben. Das Datum, das das neu erstellte Date-Objekt enthält, hängt von der übergebenen Zahl, dem Datentyp und den Argumenten ab.

• Wenn Sie keine Argumente übergeben, werden dem Date-Objekt das aktuelle Datum und die aktuelle Uhrzeit zugewiesen.
• Wenn Sie ein Argument des Datentyps Number übergeben, wird dem Date-Objekt ein Zeitwert zugewiesen, der der Anzahl an Millisekunden entspricht, die seit dem 1. Januar 1970 0:00:000 GMT verstrichen sind, wie es im lone-Argument angegeben ist.
• Wenn Sie ein Argument des Datentyps String übergeben, enthält der String ein gültiges Datum und das Date-Objekt enthält einen auf diesem Datum basierenden Zeitwert.
• Wenn Sie zwei oder mehrere Argumente übergeben, wird dem Date-Objekt ein Zeitwert zugewiesen, der auf den übergebenen Argumentwerten basiert, die das Jahr, den Monat, den Tag, die Stunde, die Minute, die Sekunde und die Millisekunde des Datums repräsentieren.

Wenn Sie an den Date-Klassenkonstruktor einen String übergeben, kann das Datum eine Vielzahl von Formaten annehmen, muss aber mindestens, den Monat, den Tag und das Jahr enthalten. So wäre Feb 1 2005 beispielsweise ein zulässiger Datumswert, Feb 2005 aber nicht. Die folgende Liste zeigt einige zulässige Formate auf:

• Wochentag Monat Tag Stunde:Minute:Sekunde GMT Jahr (z. B. „Tue Feb 1 00:00:00 GMT-0800 2005“, was dem toString()-Format entspricht)
• Wochentag Monat Tag Jahr Stunde:Minute:Sekunde AM/PM (z. B. „Tue Feb 1 2005 12:00:00 AM“, was dem toLocaleString()-Format entspricht)
• Wochentag Monat Tag Jahr (z. B. „Tue Feb 1 2005“, was dem toDateString()-Format entspricht)
• Monat/Tag/Jahr (z. B. „02/01/2005“)
• Monat/Jahr (z. B. „02/2005“)

Verwandte API-Elemente

Gibt den von einem Date-Objekt gemäß der Ortszeit angegebenen Tag des Monats (eine Ganzzahl von 1 bis 31) zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Verwandte API-Elemente

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Gibt den von dem Date-Objekt gemäß der Ortszeit angegebenen Wochentag zurück (0 für Sonntag, 1 für Montag usw.). Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Gibt die vollständige Jahreszahl (eine vierstellige Zahl, z. B. 2000) eines Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Gibt die Stunde (eine Ganzzahl von 0 bis 23) des day-Teils eines Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

Gibt den milliseconds-Teil (eine Ganzzahl von 0 bis 999) des Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var now:Date = new Date();
trace(now.getMilliseconds());

Gibt den minutes-Teil (eine Ganzzahl von 0 bis 59) des Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Gibt den Monat (0 für Januar, 1 für Februar usw.) dieses Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Gibt den seconds-Teil (eine Ganzzahl von 0 bis 59) des Date-Objekts gemäß der Ortszeit zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

var now:Date = new Date();
trace(now.getSeconds());

Gibt für ein Date-Objekt die Anzahl der Millisekunden zurück, die seit dem 1. Januar 1970, 0.00 Uhr, Weltzeit, vergangen sind. Mit dieser Methode können Sie beim Vergleich von mindestens zwei Date-Objekten einen bestimmten Zeitpunkt angeben.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }
 

Gibt die Differenz zwischen der Weltzeit (UTC) und der Ortszeit des Computers in Minuten zurück.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Gibt den Tag des Monats (eine Ganzzahl von 1 bis 31) eines Date-Objekts gemäß der Weltzeit (UTC) zurück.

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Gibt den Wochentag (0 für Sonntag, 1 für Montag usw.) dieses Date -Objekts gemäß Weltzeit (UTC) zurück.

Verwandte API-Elemente

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Gibt die vierstellige Jahreszahl des Date-Objekts gemäß Weltzeit (UTC) zurück.

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Gibt die Stunde (eine Ganzzahl von 0 bis 23) des Date-Objekts gemäß der Weltzeit (UTC) zurück.

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Gibt den milliseconds-Teil (eine Ganzzahl von 0 bis 999) eines Date-Objekts gemäß Weltzeit (UTC) zurück.

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Gibt den minutes-Teil (eine Ganzzahl von 0 bis 59) eines Date-Objekts gemäß Weltzeit (UTC) zurück.

var now:Date = new Date();
trace(now.getUTCMinutes());

Gibt den month-Teil (von 0 für Januar bis 11 für Dezember) eines Date-Objekts gemäß der Weltzeit (UTC) zurück.

Verwandte API-Elemente

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Gibt den seconds-Teil (eine Ganzzahl von 0 bis 59) eines Date-Objekts gemäß Weltzeit (UTC) zurück.

var now:Date = new Date();
trace(now.getUTCSeconds());

Konvertiert einen String, der ein Datum repräsentiert, in eine Zahl, die der Anzahl der seit dem 1. Januar 1970 vergangenen Millisekunden gemäß Weltzeit (UTC) entspricht.

Parameter

     Day Mon DD HH:MM:SS TZD YYYY
     

     Wed Apr 12 15:30:17 GMT-0700 2006
     

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

Verwandte API-Elemente

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Stellt den Tag des Monats gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Stellt das Jahr gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Angabe der Parameter month und day setzt diese auf Ortszeit. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Bei Aufruf dieser Methode werden die anderen Felder des Date-Objekts nicht geändert. Die Methoden Date.getUTCDay() und Date.getDay() können jedoch einen neuen Wert zurückgeben, wenn sich der Wochentag aufgrund des Aufrufs dieser Methode ändert.

Parameter

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Stellt die Stunde gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Stellt die Millisekunde gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Stellt die Minute gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Stellt den Monat und optional den Tag des Monats gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Stellt die Sekunde gemäß Ortszeit ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Die Ortszeit wird durch das Betriebssystem festgelegt, auf dem die Flash-Laufzeitumgebungen ausgeführt werden.

Parameter

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Legt das Datum in Millisekunden seit dem 1. Januar 1970, 0.00 Uhr fest und gibt den neuen Zeitpunkt in Millisekunden zurück.

Parameter

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Stellt den Tag des Monats gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Bei Aufruf dieser Methode werden die anderen Felder des Date -Objekts nicht geändert. Die Methoden Date.getUTCDay() und Date.getDay() können jedoch einen neuen Wert zurückgeben, wenn sich der Wochentag aufgrund des Aufrufs dieser Methode ändert.

Parameter

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Stellt das Jahr gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück.

Optional können mit dieser Methode auch der Monat und der Tag des Monats eingestellt werden. Bei Aufruf dieser Methode werden die anderen Felder des Objekts nicht geändert. Die Methoden Date.getUTCDay() und Date.getDay() können jedoch einen neuen Wert zurückgeben, wenn sich der Wochentag aufgrund des Aufrufs dieser Methode ändert.

Parameter

Verwandte API-Elemente

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Stellt die Stunde gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Optional können auch die Minute, Sekunde und Millisekunde angegeben werden.

Parameter

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Stellt die Millisekunde gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück.

Parameter

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Stellt die Minute gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Optional können Sie auch die Sekunde und Millisekunde angeben.

Parameter

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Stellt den Monat, und optional auch den Tag des Monats, gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück. Bei Aufruf dieser Methode werden die anderen Felder des Objekts nicht geändert. Die Methoden Date.getUTCDay() und Date.getDay() können jedoch einen neuen Wert zurückgeben, wenn sich der Wochentag aufgrund des Aufrufs dieser Methode ändert.

Parameter

Verwandte API-Elemente

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Stellt die Sekunde, und optional auch die Millisekunde, gemäß Weltzeit (UTC) ein, und gibt den neuen Zeitpunkt in Millisekunden zurück.

Parameter

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Gibt eine Stringdarstellung nur des Wochentags und des Tags des Monats zurück ohne Angabe zu Uhrzeit und Zeitzone. Vergleichen Sie dies mit den folgenden Methoden:

• Date.toTimeString(), die nur die Zeit und die Zeitzone zurückgibt.
• Date.toString(), die nicht nur den Wochentag und den Tag des Monats zurückgibt, sondern auch die Uhrzeit und die Zeitzone.

Verwandte API-Elemente

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Stellt eine überschreibbare Methode zum Anpassen der JSON-Kodierung von Werten in einem Date-Objekt bereit.

Die JSON.stringify()-Methode sucht bei jedem Objekt, das untersucht wird, nach einer toJSON()-Methode. Wenn die toJSON()-Methode gefunden wird, ruft JSON.stringify() diese für jeden gefundenen Wert auf und übergibt dabei den Schlüssel, der diesem Wert zugeordnet ist.

Date stellt eine Standardimplementierung von toJSON() bereit, die die Ausgabe von Date.toString() zurückgibt. Clients, die Date-Objekte in einem anderen Format für JSON exportieren möchten, können eigene Implementierungen verwenden. Dazu können Sie die toJSON()-Methode für den Klassenprototyp neu definieren.

Die toJSON()-Methode kann einen Wert eines beliebigen Typs zurückgeben. Wenn sie ein Objekt zurückgibt, führt stringify() eine Rekursion in dieses Objekt aus. Wenn toJSON() einen String zurückgibt, führt stringify() keine Rekursion aus und setzt die Untersuchung fort.

Parameter

Verwandte API-Elemente

Gibt eine Stringdarstellung nur des Wochentags und des Tags des Monats zurück ohne Angabe zu Uhrzeit und Zeitzone. Diese Methode gibt denselben Wert zurück wie Date.toDateString. Vergleichen Sie dies mit den folgenden Methoden:

• Date.toTimeString(), die nur die Zeit und die Zeitzone zurückgibt.
• Date.toString(), die nicht nur den Wochentag und den Tag des Monats zurückgibt, sondern auch die Uhrzeit und die Zeitzone.

Verwandte API-Elemente

Gibt eine Stringdarstellung des Wochentags, des Tags des Monats, der Uhrzeit gemäß der Ortszeit zurück. Vergleichen Sie dies mit der Methode Date.toString(), die dieselben Informationen (plus die Zeitzone) zurückgibt, wobei am Ende des Strings zudem das Jahr erscheint.

Gibt eine Stringdarstellung nur der Uhrzeit zurück ohne Angabe zu Wochentag, Tag des Monats, Jahr oder Zeitzone. Vergleichen Sie dies mit der Methode Date.toTimeString(), die nur die Uhrzeit und die Zeitzone zurückgibt.

Verwandte API-Elemente

Gibt eine Stringdarstellung des Wochentags, des Tags des Monats, der Uhrzeit und der Zeitzone zurück. Das Datum für die Ausgabe hat das folgende Format:

     Day Mon Date HH:MM:SS TZD YYYY
     

Beispiel:

     Wed Apr 12 15:30:17 GMT-0700 2006
     

var now:Date = new Date();
trace(now);

Gibt eine Stringdarstellung nur der Uhrzeit und der Zeitzone zurück ohne Angabe zu Wochentag und Tag des Monats. Vergleichen Sie dies mit der Methode Date.toDateString(), die nur den Wochentag und den Tag des Monats zurückgibt.

Verwandte API-Elemente

Gibt eine Stringdarstellung des Wochentags, des Tags des Monats und der Uhrzeit gemäß der Weltzeit (UTC) zurück. Das Datum „1. Februar 2005“ wird beispielsweise als Tue Feb 1 00:00:00 2005 UTC zurückgegeben.

Verwandte API-Elemente

Gibt die Anzahl von Millisekunden zurück, die zwischen dem 1. Januar 1970, 0.00 Uhr Weltzeit, und der in den Parametern angegebenen Zeit vergangen sind. Diese Methode verwendet Weltzeit, während der Konstruktor Date Ortszeit verwendet.

Diese Methode ist nützlich, wenn Sie ein UTC-Datum an den Date-Klassenkonstruktor übergeben. Da der Date-Klassenkonstruktor den Zeitabstand in Millisekunden als Argument akzeptiert, können Sie mithilfe der Methode Date.UTC() Ihr UTC-Datum in den entsprechenden Zeitabstand in Millisekunden konvertieren und diesen Zeitabstand dann als Argument an den Date-Klassenkonstruktor senden.

Parameter

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Gibt für ein Date-Objekt die Anzahl der Millisekunden zurück, die seit dem 1. Januar 1970, 0.00 Uhr, Weltzeit, vergangen sind.