NetGroup

套件	flash.net
類別	public class NetGroup
繼承	NetGroup EventDispatcher Object

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

NetGroup 類別的實體代表 RTMFP 群組的成員資格。使用此類別可執行下列動作：

監控服務品質。info 屬性包含 NetGroupInfo 物件，而該物件的屬性會提供 QoS 統計資料給此群組。
發表。呼叫 post() 以便對群組的所有成員廣播 ActionScript 訊息。
直接路由。呼叫 sendToNearest()、sendToNeighbor() 和 sendToAllNeighbors()，以傳送簡短資料訊息給對等式群組的特定成員。來源與目標不需要具有直接的連線。
物件複寫。呼叫 addHaveObjects()、removeHaveObjects()、addWantObjects()、removeWantObjects()、writeRequestedObject() 及 denyRequestedObject()，將較大的資料分割成片段，並將它複寫到端對端群組中的所有群組。

在用戶端 NetGroup 類別中，NetConnection 會傳送下列事件：

NetGroup.Connect.Success
NetGroup.Connect.Failed
NetGroup.Connect.Rejected

事件物件的 info.group 屬性包含事件來源的參照 (NetGroup)。NetGroup 會傳送所有其他事件。在伺服器端 NetGroup 類別中，NetGroup 會傳送所有事件。

如需有關透過對等協助網路使用群組的詳細資訊，請參閱 Social Media Experiences with Flash Media and RTMFP (作者也是 Tom Krcha)。

如需有關對等協助網路技術的詳細資訊，請參閱 P2P on the Flash Platform with RTMFP (作者為 Adobe 電腦科學家 Matthew Kaufman)。

檢視範例

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		estimatedMemberCount : Number [唯讀] 根據本機鄰近節點的密度，並假設群組位址平均分佈，指定群組成員的估計數目。	NetGroup
		info : NetGroupInfo [唯讀] 傳回 NetGroupInfo 物件，其屬性提供與此 NetGroup 的 RTMFP 對等式資料傳輸有關的服務品質統計資料。	NetGroup
		localCoverageFrom : String [唯讀] 指定此節點「最接近」且負責的群組位址範圍開始位置。	NetGroup
		localCoverageTo : String [唯讀] 指定此節點「最接近」且負責的群組位址範圍結束位置。	NetGroup
		neighborCount : Number [唯讀] 指定此節點直接連接的群組成員數目。	NetGroup
		receiveMode : String 將此節點的路由接收模式指定為 NetGroupReceiveMode enum 類別中的其中一個值。	NetGroup
		replicationStrategy : String 指定物件複寫取得策略。	NetGroup

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		NetGroup(connection:NetConnection, groupspec:String) 在指定的 NetConnection 物件上建構 NetGroup，並且將其加入到 groupspec 指定的群組。	NetGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void 會在 EventDispatcher 物件註冊事件偵聽程式，以便讓偵聽程式收到事件的通知。	EventDispatcher
		addHaveObjects(startIndex:Number, endIndex:Number):void 將 startIndex 至 endIndex 的物件新增到物件集，此節點會向滿足要求的鄰近節點 (做為物件) 通告此物件集。	NetGroup
		addMemberHint(peerID:String):Boolean 手動加入指定 peerID 為群組成員的記錄。	NetGroup
		addNeighbor(peerID:String):Boolean 立即直接連線到指定的 peerID，以手動加入鄰近節點，而且這個 peerID 必須已經在這個群組中。	NetGroup
		addWantObjects(startIndex:Number, endIndex:Number):void 將 startIndex 到 endIndex 之間的物件新增到要擷取的物件集。	NetGroup
		close():void 中斷群組的連線，並關閉這個 NetGroup。	NetGroup
		convertPeerIDToGroupAddress(peerID:String):String 將 peerID 轉換為適合搭配 sendToNearest() 方法使用的群組位址。	NetGroup
		denyRequestedObject(requestID:int):void 對於之前利用 addHaveObjects() 宣告的物件，拒絕在 NetStatusEvent NetGroup.Replication.Request 接收的要求。	NetGroup
		dispatchEvent(event:Event):Boolean 會將事件傳送到事件流程。	EventDispatcher
		hasEventListener(type:String):Boolean 會檢查 EventDispatcher 物件是否有對特定的事件類型註冊偵聽程式。	EventDispatcher
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		post(message:Object):String 傳送訊息到群組的所有成員。	NetGroup
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void 會從 EventDispatcher 物件移除偵聽程式。	EventDispatcher
		removeHaveObjects(startIndex:Number, endIndex:Number):void 將 startIndex 至 endIndex 的物件從物件集移除，此節點會向滿足要求的鄰近節點 (做為物件) 通告此物件集。	NetGroup
		removeWantObjects(startIndex:Number, endIndex:Number):void 將 startIndex 到 endIndex 之間的物件從要擷取的物件集中移除。	NetGroup
		sendToAllNeighbors(message:Object):String 傳送訊息到所有的鄰近節點。	NetGroup
		sendToNearest(message:Object, groupAddress:String):String 傳送訊息到距離指定群組位址最近的鄰近節點 (或本機節點)。	NetGroup
		sendToNeighbor(message:Object, sendMode:String):String 傳送訊息到 sendMode 參數指定的鄰近節點。	NetGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		valueOf():Object 會傳回指定之物件的基本值。	Object
		willTrigger(type:String):Boolean 檢查此 EventDispatcher 物件是否已註冊事件偵聽程式，或者此物件的任何祖系已為特定事件類型註冊事件偵聽程式。	EventDispatcher
		writeRequestedObject(requestID:int, object:Object):void 對於之前利用 addHaveObjects() 方法宣告的物件，滿足 NetStatusEvent NetGroup.Replication.Request 接收的要求。	NetGroup

事件

按一下以瞭解事件的詳細資訊

隱藏繼承事件

顯示繼承事件

	摘要	定義自
activate	[廣播事件] 當 Flash Player 或 AIR 應用程式取得作業系統焦點並成為作用中時傳送。	EventDispatcher
deactivate	[廣播事件] 當 Flash Player 或 AIR 應用程式失去作業系統焦點並成為非作用中時傳送。	EventDispatcher
netStatus	在 NetGroup 物件回報其狀態或錯誤情況時傳送。	NetGroup

屬性詳細資訊

estimatedMemberCount

屬性

estimatedMemberCount:Number [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

根據本機鄰近節點的密度，並假設群組位址平均分佈，指定群組成員的估計數目。

實作
public function get estimatedMemberCount():Number

相關 API 元素

neighborCount

info

屬性

info:NetGroupInfo [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

傳回 NetGroupInfo 物件，其屬性提供與此 NetGroup 的 RTMFP 對等式資料傳輸有關的服務品質統計資料。

實作
public function get info():NetGroupInfo

相關 API 元素

flash.net.NetGroupInfo

localCoverageFrom

屬性

localCoverageFrom:String [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

指定此節點「最接近」且負責的群組位址範圍開始位置。指定的範圍沿著群組位址環 mod 2²⁵⁶ 增加方向。

實作
public function get localCoverageFrom():String

localCoverageTo

屬性

localCoverageTo:String [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

指定此節點「最接近」且負責的群組位址範圍結束位置。指定的範圍沿著群組位址環 mod 2²⁵⁶ 增加方向。

實作
public function get localCoverageTo():String

neighborCount

屬性

neighborCount:Number [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

指定此節點直接連接的群組成員數目。

實作
public function get neighborCount():Number

receiveMode

屬性

receiveMode:String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將此節點的路由接收模式指定為 NetGroupReceiveMode enum 類別中的其中一個值。

實作
public function get receiveMode():String
public function set receiveMode(value:String):void

replicationStrategy

屬性

replicationStrategy:String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

指定物件複寫取得策略。該值是 NetGroupReplicationStrategy 類別的其中一個列舉值。

實作
public function get replicationStrategy():String
public function set replicationStrategy(value:String):void

相關 API 元素

flash.net.NetGroupReplicationStrategy

建構函式詳細資料

()

建構函式

public function NetGroup(connection:NetConnection, groupspec:String)

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

在指定的 NetConnection 物件上建構 NetGroup，並且將其加入到 groupspec 指定的群組。

在大部份的情況下，groupspec 可以在本機系統上使用網路上行。當使用 groupspec 建構 NetStream 或 NetGroup 物件時，Flash Player 會顯示「私用」對話方塊。此對話方塊會詢問 Flash Player 是否可以使用該連線來與使用者的對等共用資料。如果使用者按一下「允許此網域」，下次使用者連線至此應用程式時，不會顯示該對話方塊。如果使用者不允許對等協助網路，則會停用在群組中的所有對等功能 (發表、直接路由、物件複寫以及多點傳送)。如果權限允許，會連同 info 物件之 code 屬性中的 NetGroup.Connect.Success 傳送 NetStatusEvent 到 NetConnection 的事件偵聽程式。如果拒絕權限，code 屬性是 NetGroup.Connect.Rejected。在接收到 NetGroup.Connect.Success 事件之前，如果您嘗試呼叫任何 NetGroup 物件的方法，便會擲出例外。

注意：當用戶端訂閱原生 IP 多點傳送串流時，不會顯示安全性對話方塊。

參數

	`connection:NetConnection` — NetConnection 物件。

	`groupspec:String` — 指定要加入之 RTMFP 對等式群組的字串，包含它的名稱、功能、限制及這個成員的授權。 new NetGroup(myConnection, myGroupSpecifier.groupspecWithAuthorizations());

擲回值

	`ArgumentError` — NetConnection 實體尚未連線。

	`Error` — groupspec 是無效的。

方法詳細資訊

addHaveObjects

()

方法

public function addHaveObjects(startIndex:Number, endIndex:Number):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將 startIndex 至 endIndex 的物件新增到物件集，此節點會向滿足要求的鄰近節點 (做為物件) 通告此物件集。依預設值，Have 集是空的。索引必須是介於 0 到 9007199254740992 之間的整數。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

這個方法會連同 info 物件 code 屬性中的 "NetGroup.Replication.Request" 傳送 NetStatusEvent 到 NetGroup 的事件偵聽程式。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`startIndex:Number` — 增加到 Have 集的物件索引範圍開頭。

	`endIndex:Number` — 增加到 Have 集的物件索引範圍結尾。

擲回值

RangeError — 傳送到這個方法的數字小於 0 或大於 9007199254740992。

addMemberHint

()

方法

public function addMemberHint(peerID:String):Boolean

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

手動加入指定 peerID 為群組成員的記錄。只有拓撲需要時，才會馬上嘗試連線。

參數

peerID:String — 加到可能鄰近節點集的 peerID。

傳回值

Boolean — 成功為 TRUE ，失敗為 FALSE。

相關 API 元素

addNeighbor()

addNeighbor

()

方法

public function addNeighbor(peerID:String):Boolean

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

立即直接連線到指定的 peerID，以手動加入鄰近節點，而且這個 peerID 必須已經在這個群組中。如果拓撲不需要的話，稍後可能會捨棄這個直接連線。

參數

peerID:String — 要馬上連線的 peerID。

傳回值

Boolean — 成功為 TRUE ，失敗為 FALSE。

相關 API 元素

addMemberHint()

addWantObjects

()

方法

public function addWantObjects(startIndex:Number, endIndex:Number):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將 startIndex 到 endIndex 之間的物件新增到要擷取的物件集。索引必須是介於 0 到 9007199254740992 之間的整數。依預設值，Want 集是空的。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

這個方法會連同 info.code 屬性中的 NetGroup.Replication.Fetch.SendNotify 傳送 NetStatusEvent 到 NetGroup 的事件偵聽程式。這個事件後面會接著 NetGroup.Replication.Fetch.Failed 或 NetGroup.Replication.Fetch.Result 事件。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`startIndex:Number` — 增加到 Want 集的物件索引範圍開頭。

	`endIndex:Number` — 增加到 Want 集的物件索引範圍結尾。

擲回值

RangeError — 傳送到這個方法的數字小於 0 或大於 9007199254740992。

close

()

方法

public function close():void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

中斷群組的連線，並關閉這個 NetGroup。在呼叫這個方法後，這個 NetGroup 將無法使用。

convertPeerIDToGroupAddress

()

方法

public function convertPeerIDToGroupAddress(peerID:String):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將 peerID 轉換為適合搭配 sendToNearest() 方法使用的群組位址。

參數

peerID:String — 要轉換的 peerID。

傳回值

String — peerID 的群組位址。

denyRequestedObject

()

方法

public function denyRequestedObject(requestID:int):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

對於之前利用 addHaveObjects() 宣告的物件，拒絕在 NetStatusEvent NetGroup.Replication.Request 接收的要求。要求者可能會再度要求這個物件，除非或直到這個要求從 Have 集撤銷。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

requestID:int — 在 NetGroup.Replication.Request 事件中指定的要求識別名稱。

post

()

方法

public function post(message:Object):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

傳送訊息到群組的所有成員。若要呼叫此方法，GroupSpecifier.postingEnabled 屬性在傳遞給 NetGroup 建構函式的 groupspec 中必須為 true。如需詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Post messages to a group"。

所有的訊息必須是唯一的，與稍早發表訊息相同的訊息不會傳遞。使用序列號讓訊息變成唯一。

未排序訊息傳遞。不保證訊息傳遞。

使用 AMF 序列化訊息。此訊息可以是下列其中一種類型：Object、int、Number 或 String。訊息不能是 MovieClip。

這個方法會連同 info.code 屬性中的 "NetGroup.Posting.Notify" 傳送 NetStatusEvent 到 NetGroup 的事件偵聽程式。"NetGroup.Posting.Notify" 事件會同時傳送到用戶端與伺服器上的 NetGroup。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

message:Object — 傳送到群組所有其他成員的訊息。

傳回值

String — 如果發表的話，傳回訊息的 messageID，如果發生錯誤時傳回 null。messageID 是訊息序列化原始位元組 SHA256 的十六進位。

範例 ( 如何使用本範例 )

這是一個使用對等網路的簡易文字聊天應用程式。應用程式透過 RTMFP 連線至 Flash Media Server。伺服器會保留用戶端應用程式的指紋以及在用戶端連線後管理對等群組。不過，在用戶端 (對等) 之間傳送的所有資料 -- 資料不會傳回伺服器。

當您執行這個應用程式時，您可以在文字輸入欄位輸入任何群組名稱。GroupSpecifier 類別使用這個名稱 (以及您設定的任何 GroupSpecifier 屬性) 來建立一個字串，且永遠是群組的特有名稱。若要將其他用戶端連線至這個群組，用戶端必須使用相同的群組名稱。例如，如果用戶端 A 使用 "firstmesh"群組名稱，另一個用戶端想與用戶端 A 通訊時就必須也使用 "firstmesh" 這個群組名稱。如果用戶端 B 使用 "kite" 群組名稱，它一定會連線成功，不過它會建立一個新的群組名稱而且無法與用戶端 A 或 "firstmesh" 群組中的任何人通訊。

若要執行此範例，請將一個 Button、Label、TextInput 以及 TextArea 組件新增至 Flash Pro 的 Library 中。




package  {

    import flash.display.Sprite;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;
    import flash.events.NetStatusEvent;
    import fl.events.ComponentEvent;
    import fl.controls.Label;
    import fl.controls.Button;
    import fl.controls.TextInput;
    import fl.controls.TextArea;
    import flash.text.TextFieldAutoSize;
    import flash.net.*;

    public class NetGroupPostExample extends Sprite{

        private var connectButton:Button;
        private var disconnectButton:Button;
        private var groupNameText:TextInput;
        private var userNameText:TextInput;
        private var chatText:TextInput;
        private var statusLog:TextArea;
        private var groupLabel:Label;
        private var userLabel:Label;

        private var netConnection:NetConnection = null;
        private var netGroup:NetGroup = null;
        private var sequenceNumber:uint = 0;
        private var connected:Boolean = false;
        private var joinedGroup:Boolean = false;

        private const SERVER:String = "rtmfp://fms.example.com/someapp";

        public function NetGroupPostExample() {
            DoUI();
        }

        // Writes messages to the TextArea.
        private function StatusMessage(msg:Object):void{
            statusLog.text += msg;
            statusLog.verticalScrollPosition = statusLog.textHeight;
            statusLog.validateNow();
        }

        // Handles all NetStatusEvents for the NetConnection and the NetGroup.
        // This code includes cases it doesn't handle so you can see the cases
        // and their info objects for learning purposes.
        private function NetStatusHandler(e:NetStatusEvent):void{
            StatusMessage(e.info.code + "\n");
            switch(e.info.code){
                case "NetConnection.Connect.Success":
                    connectButton.enabled = false;
                    disconnectButton.enabled = true;
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                    OnDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;

                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }
        // Creates a NetConnection to Flash Media Server if the app isn't already connected
        // and if there's a group name in the TextInput field.
        private function DoConnect(e:MouseEvent):void{
            if(!connected && (groupNameText.length > 0)){
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                // To connect to Flash Media Server, pass the server name.
                netConnection.connect(SERVER);
            }
            else
            {
                StatusMessage("Enter a group name");
            }
        }

        // Called in the "NetConnection.Connect.Success" case in the NetStatusEvent handler.
        private function OnConnect():void{

            StatusMessage("Connected\n");
            connected = true;

            // Create a GroupSpecifier object to pass to the NetGroup constructor.
            // The GroupSpecifier determines the properties of the group
            var groupSpecifier:GroupSpecifier;
            groupSpecifier = new GroupSpecifier("aslrexample/" + groupNameText.text);
            groupSpecifier.postingEnabled = true;
            groupSpecifier.serverChannelEnabled = true;

            netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
            netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

            StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");

        }

        private function OnNetGroupConnect():void{
            joinedGroup = true;
        }

        private function DoDisconnect(e:MouseEvent):void{
            if(netConnection){
                netConnection.close();
            }
        }

        private function OnDisconnect():void{
            StatusMessage("Disconnected\n");
            netConnection = null;
            netGroup = null;
            connected = false;
            joinedGroup = false;
            connectButton.enabled = true;
            disconnectButton.enabled = false;
        }

        private function ClearChatText():void{
            chatText.text = "";
        }

        // Called when you the chatText field has focus and you press Enter.
        private function DoPost(e:ComponentEvent):void{
            if(joinedGroup){
                var message:Object = new Object;
                message.user = userNameText.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);
                StatusMessage("==> " + chatText.text + "\n");
            } else {
                StatusMessage("Click Connect before sending a chat message");
            }
            ClearChatText();
        }

        private function OnPosting(message:Object):void{
            StatusMessage("<" + message.user + "> " + message.text + "\n");
        }

        private function DoUI():void {

            groupLabel = new Label();
            groupLabel.move(20, 10);
            groupLabel.autoSize = TextFieldAutoSize.LEFT
            groupLabel.text = "Group name:"
            addChild(groupLabel);

            groupNameText = new TextInput();
            groupNameText.move(90, 10);
            groupNameText.text = "channel" + (int(Math.random() * 899) + 101);
            addChild(groupNameText);

            connectButton = new Button();
            connectButton.addEventListener(MouseEvent.CLICK, DoConnect);
            connectButton.move(205, 10);
            connectButton.label = "Connect";
            addChild(connectButton);

            disconnectButton = new Button();
            disconnectButton.addEventListener(MouseEvent.CLICK, DoDisconnect);
            disconnectButton.move(310, 10);
            disconnectButton.label = "Disconnect";
            disconnectButton.enabled = false;
            addChild(disconnectButton);

            statusLog = new TextArea();
            statusLog.move(30, 38);
            statusLog.width = 360;
            statusLog.height = 215;
            statusLog.editable = false;
            addChild(statusLog);

            userLabel = new Label();
            userLabel.move(20, 270);
            userLabel.autoSize = TextFieldAutoSize.LEFT
            userLabel.text = "User name:"
            addChild(userLabel);

            userNameText = new TextInput();
            userNameText.move(80, 270);
            userNameText.text = "user " + int(Math.random() * 65536);
            addChild(userNameText);

            chatText = new TextInput();
            chatText.addEventListener(ComponentEvent.ENTER, DoPost);
            chatText.move(185, 270);
            chatText.maxChars = 255;
            chatText.width = 215;
            addChild(chatText);

        }

        public function onPlayStatus(info:Object):void {}
        public function onMetaData(info:Object):void {}
        public function onCuePoint(info:Object):void {}
        public function onTextData(info:Object):void {}

    }

}

removeHaveObjects

()

方法

public function removeHaveObjects(startIndex:Number, endIndex:Number):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將 startIndex 至 endIndex 的物件從物件集移除，此節點會向滿足要求的鄰近節點 (做為物件) 通告此物件集。索引必須是介於 0 到 9007199254740992 之間的整數。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`startIndex:Number` — 在 Have 集中移除物件索引範圍開頭。

	`endIndex:Number` — 在 Have 集中移除物件索引範圍結尾。

擲回值

RangeError — 傳送到這個方法的數字小於 0 或大於 9007199254740992。

相關 API 元素

addHaveObjects()

removeWantObjects

()

方法

public function removeWantObjects(startIndex:Number, endIndex:Number):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

將 startIndex 到 endIndex 之間的物件從要擷取的物件集中移除。索引必須是介於 0 到 9007199254740992 之間的整數。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`startIndex:Number` — 在 Want 集中移除物件索引範圍開頭。

	`endIndex:Number` — 在 Want 集中移除物件索引範圍結尾。

擲回值

RangeError — 傳送到這個方法的數字小於 0 或大於 9007199254740992。

相關 API 元素

addWantObjects()

sendToAllNeighbors

()

方法

public function sendToAllNeighbors(message:Object):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

傳送訊息到所有的鄰近節點。如果至少選取了一個鄰近節點的話，傳回 NetGroupSendResult.SENT。

如需傳遞訊息的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Route messages directly to a peer"。

當節點接收到訊息時，NetStatusEvent 會連同 info 物件 code 屬性中的 NetGroup.SendTo.Notify 傳送到 NetGroup 的事件偵聽程式。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

message:Object — 要傳送的訊息。

傳回值

String — 指出傳送成功或失敗之 NetGroupSendResult 列舉類別的屬性。

sendToNearest

()

方法

public function sendToNearest(message:Object, groupAddress:String):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

傳送訊息到距離指定群組位址最近的鄰近節點 (或本機節點)。從整個環形考量鄰近節點。如果訊息成功地傳送至其目的地，傳回 NetGroupSendResult.SENT。

如需傳遞訊息的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Route messages directly to a peer"。

當節點接收到訊息時，NetStatusEvent 會連同 info 物件 code 屬性中的 NetGroup.SendTo.Notify 傳送到 NetGroup 的事件偵聽程式。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`message:Object` — 要傳送的訊息。

	`groupAddress:String` — 要路由訊息的群組位址。

傳回值

String — 指出傳送成功或失敗之 NetGroupSendResult 列舉類別的屬性。

sendToNeighbor

()

方法

public function sendToNeighbor(message:Object, sendMode:String):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

傳送訊息到 sendMode 參數指定的鄰近節點。如果訊息成功地傳送到要求的目的地，傳回 NetGroupSendResult.SENT。

如需傳遞訊息的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Route messages directly to a peer"。

當節點接收到訊息時，NetStatusEvent 會連同 info 物件 code 屬性中的 NetGroup.SendTo.Notify 傳送到 NetGroup 的事件偵聽程式。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`message:Object` — 要傳送的訊息。

	`sendMode:String` — 指定傳送訊息到鄰近節點之 NetGroupSendMode 列舉類別的屬性。

傳回值

String — 指出傳送成功或失敗之 NetGroupSendResult 列舉類別的屬性。

writeRequestedObject

()

方法

public function writeRequestedObject(requestID:int, object:Object):void

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 10.1, AIR 2

對於之前利用 addHaveObjects() 方法宣告的物件，滿足 NetStatusEvent NetGroup.Replication.Request 接收的要求。object 可以是下列其中一種：Object、int、Number 與 String。object 無法是 MovieClip。

如需物件複寫的詳細資訊，請參閱 Flash Media Server Developer's Guide 中的 "Replicate an object within a group"。

注意：呼叫此方法之前，請先測試 NetGroup.Neighbor.Connect 事件。

參數

	`requestID:int` — 在 `NetGroup.Replication.Request` 事件中指定的要求識別名稱。

	`object:Object` — 對應於在 `NetGroup.Replication.Request` 事件中指定索引的物件。

事件詳細資訊

netStatus

事件

事件物件類型: flash.events.NetStatusEvent
屬性 NetStatusEvent.type = flash.events.NetStatusEvent.NET_STATUS

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 10.1

在 NetGroup 物件回報其狀態或錯誤情況時傳送。netStatus 事件包含 info 屬性。info 屬性是含有事件資訊的物件，例如，連線嘗試成功或失敗。

定義 type 屬性值 (netStatus 事件物件)。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`info`	物件，其中包含描述該物件狀態或錯誤情況的屬性。
`target`	回報其狀態的 NetConnection 或 NetStream 物件。

相關 API 元素

flash.events.NetStatusEvent.info

範例如何使用本範例

NetGroupExample.as

這是一個使用對等網路的簡易視訊聊天應用程式。應用程式透過 RTMFP 連線至 Flash Media Server。伺服器會保留用戶端應用程式的指紋以及在用戶端連線後管理對等群組。不過，在用戶端 (對等) 之間傳送的所有資料 -- 資料不會傳回伺服器。



<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="100%" height="100%" applicationComplete="OnApplicationComplete()">
    <mx:Script>
        <![CDATA[
            private var netConnection:NetConnection = null;
            private var netStream:NetStream = null;
            private var netGroup:NetGroup = null;
            private var video:Video = null;
            private var sequenceNumber:uint = 0;
            private var resizeTimer:Timer = null;

            private const SERVER:String = "rtmfp://fms.example.com/someapp";

            [Bindable] private var connected:Boolean = false;
            [Bindable] private var joinedGroup:Boolean = false;

            private function OnApplicationComplete():void
            {
                userName.text = "user " + int(Math.random() * 65536);

                groupName.text = "channel" + (int(Math.random() * 899) + 101);

                resizeTimer = new Timer(2000.0);
                resizeTimer.addEventListener(TimerEvent.TIMER, DoResizeVideo);
                resizeTimer.start();
            }

            private function StatusMessage(msg:Object):void
            {
                statusLog.text += msg;
                statusLog.verticalScrollPosition = statusLog.textHeight;
                statusLog.validateNow();
            }

            private function NetStatusHandler(e:NetStatusEvent):void
            {
                StatusMessage(e.info.code);
                switch(e.info.code)
                {
                case "NetConnection.Connect.Success":
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                case "NetConnection.Connect.Failed":
                case "NetConnection.Connect.Rejected":
                case "NetConnection.Connect.AppShutdown":
                case "NetConnection.Connect.InvalidApp":
                    OnDisconnect();
                    break;

                case "NetStream.Connect.Success": // e.info.stream
                    OnNetStreamConnect();
                    break;

                case "NetStream.Connect.Rejected": // e.info.stream
                case "NetStream.Connect.Failed": // e.info.stream
                    DoDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    DoDisconnect();
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;


                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    DoResizeVideo();
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }

            private function DoConnect():void
            {
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                netConnection.connect(SERVER);
            }

            private function OnConnect():void
            {
                var groupSpecifier:GroupSpecifier;

                StatusMessage("Connected\n");
                connected = true;

                groupSpecifier = new GroupSpecifier("max2009lab/" + groupName.text);
                groupSpecifier.multicastEnabled = true;
                groupSpecifier.postingEnabled = true;
                groupSpecifier.serverChannelEnabled = true;

                netStream = new NetStream(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netStream.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");
            }

            private function OnNetStreamConnect():void
            {
                netStream.client = this;

                var mic:Microphone = Microphone.getMicrophone();
                if(mic)
                {
                    mic.codec = SoundCodec.SPEEX;
                    mic.setSilenceLevel(0);

                    netStream.attachAudio(mic);

                    StatusMessage("got microphone\n");
                }

                var camera:Camera = Camera.getCamera();
                if(camera)
                {
                    camera.setMode(320, 240, 10);
                    camera.setQuality(30000, 0);
                    camera.setKeyFrameInterval(15);

                    videoDisplay.attachCamera(camera);
                    videoDisplay.maintainAspectRatio = true;

                    netStream.attachCamera(camera);

                    StatusMessage("got camera\n");
                }

                netStream.publish("stream");
            }

            private function OnNetGroupConnect():void
            {
                joinedGroup = true;
            }

            private function DoDisconnect():void
            {
                if(netConnection)
                    netConnection.close();
                videoDisplay.attachCamera(null);
            }

            private function OnDisconnect():void
            {
                StatusMessage("Disconnected\n");
                netConnection = null;
                netStream = null;
                netGroup = null;
                connected = false;
                joinedGroup = false;
            }

            private function ClearChatText():void
            {
                chatText.text = "";
            }

            private function DoPost():void
            {
                var message:Object = new Object;

                message.user = userName.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);

                StatusMessage("==> " + chatText.text + "\n");

                chatText.callLater(ClearChatText);
            }

            private function OnPosting(message:Object):void
            {
                StatusMessage("<" + message.user + "> " + message.text + "\n");
            }

            private function DoResizeVideo(ignored:* = null):void
            {
                if(video)
                {
                    if( (0 == video.videoHeight)
                     || (0 == video.videoWidth)
                    )
                    {
                        video.height = videoDisplay.height;
                        video.width = videoDisplay.width;
                        video.x = 0;
                        video.y = 0;
                    }
                    else
                    {
                        var videoAspect:Number = Number(video.videoWidth) / Number(video.videoHeight);
                        var displayAspect:Number = Number(videoDisplay.width) / Number(videoDisplay.height);
                        var adjustFactor:Number;

                        if(videoAspect >= displayAspect) // video is wider than display
                        {
                            adjustFactor = Number(video.videoWidth) / Number(videoDisplay.width);
                            video.width = videoDisplay.width;
                            video.height = int(Number(video.videoHeight) / adjustFactor);
                            video.x = 0;
                            video.y = int((videoDisplay.height - video.height) / 2);
                        }
                        else
                        {
                            adjustFactor = Number(video.videoHeight) / Number(videoDisplay.height);
                            video.height = videoDisplay.height;
                            video.width = int(Number(video.videoWidth) / adjustFactor);
                            video.x = int((videoDisplay.width - video.width) / 2);
                            video.y = 0;
                        }
                    }
                }
            }

            public function onPlayStatus(info:Object):void {}
            public function onMetaData(info:Object):void {}
            public function onCuePoint(info:Object):void {}
            public function onTextData(info:Object):void {}

            public function ValidateConnectAllowed(isConnected:Boolean, groupNameText:String):Boolean
            {
                return (!isConnected) && (groupNameText.length > 0);
            }
        ]]>
    </mx:Script>

    <mx:VBox top="10" right="10" left="10" bottom="10" verticalGap="6">
        <mx:HBox width="100%">
            <mx:Text text="Group:"/>
            <mx:TextInput id="groupName" width="100%" text="default" enabled="{!connected}"/>
            <mx:Button label="Connect" click="DoConnect()" enabled="{ValidateConnectAllowed(connected, groupName.text)}" />
            <mx:Button label="Disconnect" click="DoDisconnect()" enabled="{connected}" />
        </mx:HBox>
        <mx:VideoDisplay id="videoDisplay" width="320" height="240" resize="DoResizeVideo()"/>
        <mx:TextArea id="statusLog" width="100%" height="100%"/>
        <mx:HBox width="100%">
            <mx:TextInput id="userName" width="160" />
            <mx:TextInput id="chatText" width="100%" enabled="{joinedGroup}" enter="DoPost()"/>
        </mx:HBox>
    </mx:VBox>

</mx:Application>

法律聲明 | 線上隱私權政策

NetGroup - AS3

類別 x

estimatedMemberCount

info

localCoverageFrom

localCoverageTo

neighborCount

receiveMode

replicationStrategy

NetGroup

addHaveObjects

addMemberHint

addNeighbor

addWantObjects

close

convertPeerIDToGroupAddress

denyRequestedObject

post

removeHaveObjects

removeWantObjects

sendToAllNeighbors

sendToNearest

sendToNeighbor

writeRequestedObject

netStatus