NetConnection  - AS3

指出要針對其叫用回呼方法的物件。 預設值為此 NetConnection 實體。 如果您將 client 屬性設定為其它物件，就會在該物件上叫用回呼方法。

指出應用程式是 (true) 否 (false) 透過持續的 RTMP 連線連到伺服器。透過 HTTP 進行連線時，這個屬性是 false，唯一的例外是連線到應用程式伺服器上的 Flash Remoting 服務時為 true。

用於和 Flash Media Server 成功建立連線的 Proxy 類型。可能值為："none"、"HTTP"、"HTTPS" 或 "CONNECT"。

如果連線未穿透或是原生 SSL 連線，則值為 "none"。

如果連線是透過 HTTP 來穿透，則值為 "HTTP"。

如果連線是透過 HTTPS 來穿透，則值為 "HTTPS"。

如果連線使用透過 Proxy 伺服器的 CONNECT 方法來穿透，則值為 "CONNECT"。

NetConnection 物件的預設物件編碼。將二進位資料寫入或讀取到物件時，defaultObjectEncoding 屬性會指示用來將資料序列化的 Action Message Format (AMF) 版本：ActionScript 3.0 格式 (ObjectEncoding.AMF3) 或 ActionScript 1.0 和 ActionScript 2.0 格式 (ObjectEncoding.AMF0)。

預設值是 ObjectEncoding.AMF3。 變更 NetConnection.defaultObjectEncoding 並不會影響現有的 NetConnection 實體，只會影響後續建立的實體。

若要個別設定物件的編碼 (而非設定整個應用程式的物件編碼)，請改為設定 NetConnection 物件的 objectEncoding 屬性。

如需詳細資訊，請參閱 objectEncoding 屬性的說明。

相關 API 元素

這個 Flash Player 或 Adobe AIR 實體所連線之目標 Flash Media Server 實體的識別名稱。這個屬性對 RTMFP 連線才有意義。只有在建立 RTMFP 連線之後，才會有這個屬性的值。

相關 API 元素

實際上由 Flash Media Server 選擇的值，這個連線的唯一值。這個值會對伺服器顯示為其 client.nearNonce 值。這個值僅針對 RTMFP、RTMPE 與 RTMPTE 連線定義。

等待 HTTP 回應的時間 (毫秒)。預設值為零。

• httpIdleTimeout 值為 Number。
• 使用 HTTP連線時，正值表示非作用中連線應該維持開啟的毫秒數。
• 值為零時表示應該使用平台的預設網路閒置逾時值。
• 負值將造成 RangeError。
• 如果超過 httpIdleTimeout 值，就會傳送 netStatus 事件。
• 此屬性只會影響以 HTTP 連線建立的 NetConnection 物件。以 RTMP、RTMFP 或其他 HTTP 通道建立的 NetConnection 物件不受此屬性的影響。

    //Set the timeout to 5 seconds
    connection = new NetConnection();
    connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
    connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
    connection.httpIdleTimeout = 5000;
    

Flash Player 或 Adobe AIR 的這個實體允許的傳入和傳出對等連線總數。預設值為 8。

這個值不會區別發行者和訂閱者連線。如果這個值在對等連線期間降低，新值只會影響新的傳入連線，不會捨棄現有連線。

這個 NetConnection 實體使用的 Flash Player 或 Adobe AIR 實體的識別名稱。這個屬性對 RTMFP 連線才有意義。

每個 NetConnection 實體都具有唯一的 nearID 屬性。Flash Player 或 Adobe AIR 實體或 NetConnection 實體不會有相同的識別名稱。

其它 Flash Player 或 Adobe AIR 實體會將這個識別名稱做為與這個用戶端進行 NetStream 新連線中的 peerID。隨後，這個識別名稱就是任何連線至這個實體的對等 NetStream 中的 farID。

相關 API 元素

實際上由這個 Flash Player 或 Adobe AIR 實體選擇的值，這個連線的唯一值。這個值會對伺服器顯示為其 client.farNonce 值。這個值僅針對 RTMFP、RTMPE 與 RTMPTE 連線定義。

這個 NetConnection 實體的物件編碼。

將二進位資料寫入或讀取到物件時，defaultObjectEncoding 屬性會指示用來將資料序列化的 Action Message Format (AMF) 版本：ActionScript 3.0 格式 (ObjectEncoding.AMF3) 或 ActionScript 1.0 和 ActionScript 2.0 格式 (ObjectEncoding.AMF0)。設定 objectEncoding 屬性，以設定 NetConnection 實體的 AMF 版本。

如果您的應用程式需要與 Flash Player 9 之前版本的伺服器通訊，請務必瞭解這個屬性。可能的情況有下列三種：

• 連線到支援 AMF3 的伺服器 (例如 Flex Data Services 2 或 Flash Media Server 3)。 defaultObjectEncoding 的預設值是 ObjectEncoding.AMF3。 在這個檔案中建立的所有 NetConnection 實體都會使用 AMF3 序列化，因此您不需要設定 objectEncoding 屬性。
• 連線到不支援 AMF3 的伺服器 (例如 Flash Media Server 2)。 在這種情況下，請將靜態的 NetConnection.defaultObjectEncoding 屬性設定為 ObjectEncoding.AMF0。 在此 SWF 檔中建立的所有 NetConnection 實體都會使用 AMF0 序列化， 所以您不需要設定 objectEncoding 屬性。
• 連線至使用不同編碼版本的多部伺服器。 請使用每個連線的 objectEncoding 屬性 (而非使用 defaultObjectEncoding)，針對每個連線設定物件編碼。 將它設定為 ObjectEncoding.AMF0 可連線到使用 AMF0 編碼的伺服器 (例如 Flash Media Server 2)，而將它設定為 ObjectEncoding.AMF3 可連線到使用 AMF3 編碼的伺服器 (例如 Flex Data Services 2)。

在 NetConnection 實體連線之後，其 objectEncoding 屬性會是唯讀的。

如果您使用錯誤的編碼來連線至伺服器，NetConnection 物件就會傳送 netStatus 事件。NetStatusEvent.info 屬性含有 code 屬性值為 NetConnection.Connect.Failed 的資訊物件，以及說明物件編碼不正確的說明。

相關 API 元素

用來建立連線的通訊協定。使用 Flash Media Server 時，這個屬性具有意義。可能值如下：

• "rtmp"：即時訊息通訊協定 (RTMP)
• "rtmpe"：加密的 RTMP
• "rtmpt"：HTTP 穿透技術 RTMP
• "rtmpte"：HTTP 穿透技術加密的 RTMP
• "rtmps"：HTTPS 式 RTMP
• "rtmfp"：即時媒體流量通訊協定 (RTMFP)

決定初始 Flash Media Server 連線嘗試失敗時，要嘗試哪些後援方法。 請先設定 proxyType 屬性，之後才能呼叫 NetConnection.connect() 方法。

可接受的值為 "none"、"HTTP"、"CONNECTOnly"、"CONNECT" 和 "best"。預設值為 "none"。

若要使用原生 SSL，請將屬性設定為 "best"。如果播放程式無法直接連線至伺服器 (透過預設連接埠 443 或是透過您指定的其他連接埠)，而且 Proxy 伺服器已就位，播放程式會嘗試使用 CONNECT 方法。如果該嘗試失敗，播放程式會透過 HTTPS 來穿透。

如果屬性設定為 "CONNECTOnly"，播放程式就會嘗試先使用 CONNECT 方法。如果該方法失敗，就沒有後援。

如果屬性設定為 "HTTP" 而且直接連線失敗，就會使用 HTTP 穿透技術。如果此屬性設定為 "CONNECT" 而且直接連線失敗，就會使用穿透技術的 CONNECT 方法。如果該方法失敗，連線將不會使用後援的 HTTP 穿透技術。

只有在使用 RTMP、RTMPS 或 RTMPT 時，才適用這個屬性。CONNECT 和 CONNECTOnly 方法只適用於透過 Proxy 伺服器連線至網路的使用者。

物件，其中保存所有與發佈中 NetStream 物件沒有關聯的對等訂閱者 NetStream 物件。與發佈 NetStream 物件相關聯的訂閱者 NetStream 物件是位於 NetStream.peerStreams 陣列。

相關 API 元素

傳遞到 NetConnection.connect() 方法的 URI。如果尚未呼叫 NetConnection.connect() 或未傳遞 URI，則這個屬性是 undefined。

指出是否使用原本的 Transport Layer Security (TLS) 而非 HTTPS 建立安全的連線。 這個屬性只有在 NetConnection 物件已連線時才有效。

建立 NetConnection 物件。 呼叫 connect() 方法以建立連線。

如果應用程式必須與 Flash Player 9 之前發行的伺服器進行通訊，您可能必須設定 NetConnection 物件的 objectEncoding 屬性。

下列程式碼會建立 NetConnection 物件。

     var nc:NetConnection = new NetConnection();
     

相關 API 元素

將內容標頭加入 Action Message Format (AMF) 封包結構。 此標頭未來會隨每個 AMF 封包一併傳送。 如果您使用相同名稱呼叫 NetConnection.addHeader()，新的標頭就會取代現有的標頭，而且新的標頭會在 NetConnection 物件持續期間保存。 您可以使用標頭名稱呼叫 NetConnection.addHeader()，藉由這種移除未定義之物件的方式移除此標頭。

參數

在 Flash Media Server 上或在執行 Flash Remoting 的應用程式伺服器上呼叫命令或方法。呼叫 NetConnection.call() 之前，您必須呼叫 NetConnection.connect() 以連線到伺服器。 您必須建立伺服器端函數，以傳遞給此方法。

您不可以連接到常用的保留連接埠。完整的封鎖連接埠清單，請參閱在「ActionScript 3.0 開發人員指南」中的「限制網路 API」。

參數

相關 API 元素

關閉於本機開啟或連到伺服器的連線，並傳送 code 屬性為 NetConnection.Connect.Closed 的 netStatus 事件。

這個方法會使連線上執行的所有 NetStream 物件離線。 尚未傳送的佇列資料將全部捨棄 (若只要結束本機或伺服器串流，但不要關閉連線，請使用 NetStream.close())。 如果關閉連線，之後想要建立新連線，您必須建立新的 NetConnection 物件，並重新呼叫 connect() 方法。

close() 方法也會使在這個連線上執行的所有遠端共享物件離線。 但是，您不需要重新建立共享物件以重新連線， 您只需要改用呼叫 SharedObject.connect() 的方式重新建立共享物件的連線即可。 同時，當您重新建立與共享物件的連線後，就會送出之前在您發出 NetConnection.close() 時已在共享物件中排入佇列的所有資料。

使用 Flash Media Server 時，最好的程式開發作法是在用戶端不再需要與伺服器連線時呼叫 close()。 呼叫 close() 是清除未儲存連線的最快方法。 您可以將伺服器設定為會自動關閉閒置連線，以做為備用的方法。 如需詳細資訊，請參閱「Flash Media Server 設定及管理指南」。

相關 API 元素

建立連至 Flash Media Server 上應用程式或連至 Flash Remoting 的雙向連線，或是為 RTMFP 對等式群組通訊建立雙向網路端點。為了報告其狀態或錯誤情況，對 NetConnection.connect() 的呼叫會傳送 netStatus 事件。

呼叫 NetConnection.connect() 以執行下列作業：

• 傳遞 "null"，以便從本機檔案系統或網站伺服器中播放視訊和 MP3 檔案。
• 傳遞 "http" URL，以連線至執行 Flash Remoting 的應用程式伺服器。使用 NetServices 類別可透過 NetConnection 物件對應用程式伺服器呼叫函數，並傳回結果。 如需詳細資訊，請參閱「Flash Remoting 文件」。
• 傳遞 "rtmp/e/s" URL，以連線至 Flash Media Server 應用程式。
• 傳遞 "rtmfp" URL，以便為 RTMFP 用戶端伺服器、對等式及 IP 多點傳送通訊，建立雙向網路端點。
• 傳遞 "rtmfp:" 字串，以便為 RTMFP IP 多點傳送通訊，建立無伺服器的雙向網路端點。

請考慮下列安全性模式：

• 根據預設，Flash Player 或 AIR 會拒絕安全執行程序之間的存取。但是網站可以使用 URL 原則檔案，啟用對資源的存取。
• 您的應用程式可以拒絕對伺服器上資源的存取。 在 Flash Media Server 應用程式中，請使用伺服器端 ActionScript 程式碼來拒絕存取。請參閱 Flash Media Server 文件。
• 如果呼叫的檔案是在具有檔案系統的本機安全執行程序中，就無法呼叫 NetConnection.connect()。
• 您不可以連接到常用的保留連接埠。完整的封鎖連接埠清單，請參閱在「ActionScript 3.0 開發人員指南」中的「限制網路 API」。
• 若要防止 SWF 檔案呼叫這個方法，請在包含 SWF 內容的 HTML 網頁中，設定 object 和 embed 標籤的 allowNetworking 參數。

但在 Adobe AIR 中，application 安全執行程序中的內容 (使用 AIR 應用程式所安裝的內容) 沒有這些安全性限制。

如需有關安全性的詳細資訊，請參閱「Adobe Flash Playe 開發人員中心」：安全性。

參數

相關 API 元素

會在以非同步方式 (亦即，從原生非同步程式碼) 擲回例外時傳送。

這個事件具有下列屬性：

會在發生輸入或輸出錯誤，因而導致網路作業失敗時傳送。

這個事件具有下列屬性：

在 NetConnection 物件回報其狀態或錯誤情況時傳送。 netStatus 事件含有 info 屬性，而此屬性是含有事件相關特定資訊 (例如，嘗試連線成功或失敗) 的資訊物件。

這個事件具有下列屬性：

相關 API 元素

當 NetConnection.call() 的呼叫嘗試連線至呼叫者安全執行程序以外的伺服器時傳送。

這個事件具有下列屬性：

相關 API 元素

在這個範例中，是將建立 Video 和 NetStream 物件的程式碼與呼叫 Video.attachNetStream() 和 NetStream.play() 方法置入處理常式函數中。 只有在嘗試連線至 NetConnection 物件成功後才會呼叫處理常式；也就是 netStatus 事件傳回的 info 物件中含有表示成功的 code 屬性。 建議您先等候連線成功，然後再呼叫 NetStream.play()。

package {
    import flash.display.Sprite;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.Event;

    public class NetConnectionExample extends Sprite {
        private var videoURL:String = "http://www.helpexamples.com/flash/video/cuepoints.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video = new Video();        

        public function NetConnectionExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Stream not found: " + videoURL);
                    break;
            }
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function connectStream():void {
            addChild(video);
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.client = new CustomClient();
            video.attachNetStream(stream);
            stream.play(videoURL);
        }
    }
}

class CustomClient {
    public function onMetaData(info:Object):void {
        trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
    }
    public function onCuePoint(info:Object):void {
        trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
    }
}