PrintJob  - AS3

Indica se un lavoro di stampa è attualmente attivo. Un lavoro di stampa è attivo (il valore della proprietà è true) in una delle due condizioni seguenti:

• È visualizzata una finestra di dialogo Imposta pagina o Stampa.
• Il metodo start() o start2() è stato chiamato e ha restituito true e il metodo send() o terminate() non è stato chiamato.

Se questa proprietà è true e chiamate il metodo showPageSetupDialog(), start() o start2(), il runtime genera un'eccezione.

Elementi API correlati

Il numero di copie che vengono stampate dal sistema operativo per le pagine aggiunte successivamente al lavoro di stampa. Questo valore è il numero di copie immesse dall'utente nella finestra di dialogo Stampa del sistema operativo. Se il numero di copie non è stato visualizzato nella finestra di dialogo Stampa oppure se la finestra non è stata mostrata all'utente, il valore è 1 (a meno che non sia stato modificato dal codice dell'applicazione).

Il numero di pagina della prima pagina dell'intervallo di pagine immesso dall'utente nella finestra di dialogo Stampa del sistema operativo. Questa proprietà è pari a zero se l'utente richiede la stampa di tutte le pagine o se l'intervallo di pagine non è stato visualizzato nella finestra di dialogo Stampa oppure se la finestra di dialogo Stampa non è stata mostrata all'utente.

Indica se la stampante attualmente selezionata con le impostazioni di stampa correnti esegue la stampa a colori (true) o in scala di grigi (false).

Se un valore di colore o scala di grigi non può essere determinato, il valore è true.

Indica se la classe PrintJob è supportata nella piattaforma corrente (true) o no (false).

Il nome o il titolo del lavoro di stampa. Il nome del lavoro di stampa viene solitamente utilizzato dal sistema operativo come titolo del lavoro nella coda di stampa o come nome predefinito di un lavoro stampato su file.

Se non avete chiamato start() o start2() e non avete impostato un valore per la proprietà, il valore di questa proprietà è null.

Per ciascun lavoro di stampa che eseguite con un'istanza PrintJob, impostate questa proprietà prima di chiamare il metodo start() o start2().

Il valore predefinito è null.

Il numero di pagina dell'ultima pagina dell'intervallo di pagine immesso dall'utente nella finestra di dialogo Stampa del sistema operativo. Questa proprietà è pari a zero se l'utente richiede la stampa di tutte le pagine o se l'intervallo di pagine non è stato visualizzato nella finestra di dialogo Stampa oppure se la finestra di dialogo Stampa non è stata mostrata all'utente.

La risoluzione fisica della stampante selezionata, in pixel per pollice. Il valore viene calcolato in base alle impostazioni di stampa correnti indicate dal sistema operativo.

Se non è possibile determinare la risoluzione, viene utilizzato un valore predefinito standard. Il valore predefinito è 600 ppi su Linux e 360 ppi su Mac OS. In Windows, la risoluzione della stampante è sempre disponibile, quindi non è necessario un valore predefinito.

L'orientamento dell'immagine per la stampa. I valori accettabili sono definiti come costanti nella classe PrintJobOrientation.

Nota: per AIR 2 e versioni successive, impostate questa proprietà prima dell'avvio di un lavoro di stampa per impostare l'orientamento predefinito nelle finestre di dialogo Imposta pagina e Stampa. Impostate la proprietà mentre è in corso un lavoro di stampa (dopo aver chiamato start() o start2()) per impostare l'orientamento per un intervallo di pagine all'interno del lavoro.

Elementi API correlati

L'altezza dell'area più grande che è possibile centrare nell'effettiva area stampabile della pagina, espressa in punti. Gli eventuali margini impostati dall'utente vengono ignorati. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Nota: per AIR 2 e versioni successive, questa proprietà è obsoleta. Utilizzate invece printableArea, che misura l'area stampabile in punti frazionari e descrive con precisione le aree stampabili a partire dal centro.

Altri esempi

Elementi API correlati

La larghezza dell'area più grande che è possibile centrare nell'effettiva area stampabile della pagina, espressa in punti. Gli eventuali margini impostati dall'utente vengono ignorati. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Nota: per AIR 2 e versioni successive, questa proprietà è obsoleta. Utilizzate invece printableArea, che misura l'area stampabile in punti frazionari e descrive con precisione le aree stampabili a partire dal centro.

Altri esempi

Elementi API correlati

I limiti del supporto utilizzato dalla stampante, in punti. Questo valore usa lo stesso sistema di coordinate delle successive chiamate addPage().

L'altezza totale del foglio, espressa in punti. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Nota: per AIR 2 e versioni successive, questa proprietà è obsoleta. Utilizzate invece paperArea, che misura le dimensioni del foglio in punti frazionari.

Elementi API correlati

La larghezza totale del foglio, espressa in punti. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Nota: per AIR 2 e versioni successive, questa proprietà è obsoleta. Utilizzate invece paperArea, che misura le dimensioni del foglio in punti frazionari.

Elementi API correlati

I limiti dell'area stampabile del supporto utilizzato dalla stampante, in punti. Questo valore usa lo stesso sistema di coordinate delle successive chiamate addPage().

Ottiene o imposta la stampante da utilizzare per il lavoro di stampa corrente. L'oggetto String passato alla funzione setter e restituito dalla funzione getter deve corrispondere a una delle stringhe nell'array restituito dal metodo printers(). Per indicare che deve essere usata la stampante predefinita, impostate il valore su null. Nei sistemi operativi in cui non è possibile determinare la stampante, il valore di questa proprietà è null.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

L'impostazione del valore di questa proprietà determina il tentativo di selezionare immediatamente la stampante. Se la selezione della stampante non riesce, il valore di questa proprietà viene riportato al valore precedente. Potete determinare se l'impostazione del valore della stampante ha esito positivo leggendo il valore dopo aver tentato di impostarlo e verificando che corrisponda al valore che è stato impostato.

La proprietà printer di un lavoro di stampa attivo non può essere modificata. Gli eventuali tentativi di modificarla dopo che la chiamata al metodo start() o start2() è riuscita e prima di chiamare send() o terminate() avranno esito negativo.

Fornisce un elenco delle stampanti disponibili come valori di nomi stringa. L'elenco non è precalcolato; viene generato quando chiamate la funzione. Se non sono disponibili stampanti o se il sistema operativo non supporta la stampa, il valore è null. Se il sistema operativo supporta la stampa ma non è in grado di restituire un elenco di stampanti, il valore è un vettore con un singolo elemento (la proprietà lenght è 1). In questo caso, l'unico elemento corrisponde al nome effettivo della stampante o a un nome predefinito, se non è possibile determinare il nome della stampante corrente.

Indica se l'ambiente runtime di Flash supporta una finestra di dialogo Imposta pagina separata. Se questa proprietà è true, potete chiamare il metodo showPageSetupDialog() per visualizzare la finestra di dialogo Imposta pagina del sistema operativo.

Elementi API correlati

Crea un oggetto PrintJob che può essere utilizzato per stampare una o più pagine. Dopo che avete creato l'oggetto PrintJob, dovete utilizzare (nella sequenza seguente) i metodi PrintJob.start(), PrintJob.addPage() e PrintJob.send() per inviare un lavoro di stampa alla stampante.

Ad esempio, potete sostituire il testo segnaposto [params] per le chiamate al metodo myPrintJob.addPage() con parametri personalizzati, come nel codice seguente:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

In AIR 2 e versioni successive, potete creare e utilizzare più istanze PrintJob. Le proprietà impostate sull'istanza PrintJob vengono conservate dopo il completamento della stampa. In questo modo potete riutilizzare un'istanza PrintJob e gestire le preferenze di stampa selezionate da un utente, offrendo allo stesso tempo preferenze di stampa diverse per altri contenuti all'interno dell'applicazione. Per i contenuti in Flash Player e AIR (versioni precedenti alla 2), non è possibile creare un secondo oggetto PrintJob mentre il primo è ancora attivo. Se si crea un secondo oggetto PrintJob (mediante una chiamata a new PrintJob()) mentre il primo oggetto PrintJob è ancora attivo, il secondo non viene creato. Per questo motivo, prima di creare un secondo PrintJob verificare la presenza del valore myPrintJob.

Elementi API correlati

Invia l'oggetto Sprite specificato come pagina singola allo spooler di stampa. Prima di utilizzare questo metodo, è necessario creare un oggetto PrintJob e quindi utilizzare start() o start2(). In seguito, dopo aver effettuato una o più chiamate a addPage() per un lavoro di stampa, utilizzate send() per inviare alla stampante le pagine elaborate dallo spooler. In altre parole, dopo aver creato l'oggetto PrintJob, utilizzate (nella sequenza seguente) i metodi start() o start2(), addPage() e quindi send() per inviare un lavoro di stampa alla stampante. È possibile chiamare addPage() più volte in seguito a una singola chiamata a PrintJob.start() per stampare più pagine di un lavoro di stampa.

Se addPage() provoca la generazione di un'eccezione da parte di Flash Player (ad esempio se non avete chiamato start() o se l'utente annulla il lavoro di stampa), tutte le successive chiamate a addPage() danno esito negativo. Tuttavia, se le precedenti chiamate a addPage() sono state effettuate correttamente, il comando send() conclusivo invia alla stampante le pagine inserite correttamente nello spool.

Se il lavoro di stampa impiega più di 15 secondi per completare un'operazione addPage(), Flash Player genera un'eccezione alla successiva chiamata a addPage().

Se passate un valore per il parametro printArea, le coordinate x e y del rettangolo printArea vengono mappate all'angolo superiore sinistro (coordinate 0, 0) dell'area stampabile della pagina. Le proprietà di sola lettura pageHeight e pageWidth descrivono l'area stampabile impostata da start(). Dal momento che la pagina stampata è allineata all'angolo superiore sinistro dell'area stampabile della pagina, se l'area definita in printArea è superiore all'area stampabile della pagina, la pagina stampata viene troncata sul lato destro e/o inferiore dell'area definita da printArea. In Flash Professional, se non passate un valore per printArea e lo stage è più grande dell'area stampabile, viene applicato lo stesso tipo di troncatura. In Flex or Flash Builder, se non passate un valore per printArea e lo schermo è più grande dell'area stampabile, viene applicato lo stesso tipo di troncatura.

Per modificare in scala un oggetto Sprite prima della stampa, impostatene le proprietà (vedete flash.display.DisplayObject.scaleX e flash.display.DisplayObject.scaleY) prima di chiamare questo metodo e impostarle di nuovo sui rispettivi valori originali dopo la stampa. La scala di un oggetto Sprite non ha alcuna relazione con printArea. In altre parole, se specificate un'area di stampa di 50 x 50 pixel, vengono stampati 2500 pixel. Se modificate in scala l'oggetto Sprite, vengono stampati gli stessi 2500 pixel ma l'oggetto viene stampato nelle dimensioni modificate in scala.

La funzione di stampa di Flash Player supporta le stampanti PostScript e non PostScript. Le stampanti non PostScript convertono la grafica vettoriale in bitmap.

Parametri

Altri esempi

Elementi API correlati

Imposta il formato carta. I valori accettabili per il parametro paperSize sono costanti nella classe PaperSize. Una chiamata di questo metodo ha un effetto sulle impostazioni di stampa analogo alla scelta di un formato carta nella finestra di dialogo Imposta pagina o Stampa.

Potete chiamare questo metodo in qualsiasi momento. Chiamatelo prima dell'avvio di un lavoro di stampa per impostare il formato carta predefinito nelle finestre di dialogo Imposta pagine e Stampa. Potete chiamarlo anche mentre è in corso un lavoro di stampa per impostare il formato carta per un intervallo di pagine all'interno di tale lavoro.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parametri

Elementi API correlati

Invia pagine in spooling alla stampante dopo chiamate con esito positivo ai metodi start() o start2() e addPage().

Questo metodo fallisce se la chiamata al metodo start() o start2() non riesce oppure se una chiamata al metodo addPage() genera un'eccezione. Per evitare un errore, verificate che il metodo start() o start2() restituisca true e rilevate le eventuali eccezioni addPage() prima di chiamare questo metodo. L'esempio seguente illustra come rilevare correttamente gli eventuali errori prima di chiamare questo metodo:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Altri esempi

Elementi API correlati

Visualizza la finestra di dialogo Imposta pagina del sistema operativo, se l'ambiente corrente la supporta. Utilizzate la proprietà supportsPageSetupDialog per determinare se Imposta pagina è supportata.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Elementi API correlati

Visualizza la finestra di dialogo di stampa del sistema operativo e avvia lo spooling. Questa finestra di dialogo consente all'utente di modificare le impostazioni di stampa. Quando il metodo PrintJob.start() restituisce un valore corretto (l'utente fa clic su OK nella finestra di dialogo di stampa), vengono specificate le seguenti proprietà, che rappresentano le impostazioni di stampa scelte dall'utente:

Nota: se l'utente esce dalla finestra di dialogo di stampa facendo clic su Annulla, le proprietà non vengono specificate.

Dopo che l'utente ha fatto clic su OK nella finestra di dialogo Stampa, Flash Player inizia l'esecuzione dello spooling sul sistema operativo di un lavoro di stampa. Poiché iniziano ad essere visualizzate le informazioni sull'avanzamento della stampa, è necessario eseguire le chiamate a PrintJob.addPage() e PrintJob.send() il più presto possibile per inviare le pagine allo spooler. Per formattare la pagina stampata, è possibile utilizzare le proprietà di sola lettura relative all'altezza, alla larghezza e all'orientamento che vengono completate da questo metodo.

Verificate che il metodo restituisca true (quando l'utente fa clic su OK nella finestra di stampa del sistema operativo) prima di qualsiasi chiamata successiva a PrintJob.addPage() e PrintJob.send():

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Per l'istanza PrintJob specificata, se uno dei seguenti intervalli dura più di 15 secondi, la chiamata successiva a PrintJob.start() restituisce false:

• PrintJob.start() e il primo PrintJob.addPage()
• Un PrintJob.addPage() e il successivo PrintJob.addPage()
• L'ultimo PrintJob.addPage() e PrintJob.send()

Altri esempi

Elementi API correlati

Visualizza facoltativamente la finestra di dialogo Stampa del sistema operativo, avvia lo spooling ed eventualmente modifica i valori delle proprietà di sola lettura di PrintJob.

Il parametro uiOptions consente al chiamante di controllare quali opzioni vengono visualizzate nella finestra di dialogo Stampa. Fate riferimento alla classe PrintUIOptions. Questo parametro viene ignorato se showPrintDialog è false.

Anche quando showPrintDialog è true, il comportamento di questo metodo può differire rispetto al metodo start(). In alcuni sistemi operativi, start() visualizza la finestra di dialogo Imposta pagina, seguita dalla finestra di dialogo Stampa. Al contrario, start2() non visualizza mai la finestra di dialogo Imposta pagina.

Nell'esempio seguente, le impostazioni di pagina min e max della finestra di dialogo Stampa vengono impostate prima che la finestra venga visualizzata all'utente:

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parametri

Elementi API correlati

Indica che il lavoro di stampa deve essere terminato senza essere inviato. Utilizzate questo metodo quando un lavoro di stampa è già stato avviato da una chiamata a start() o start2(), ma non è opportuno inviare alcuna pagina alla stampante. In genere, terminate() viene usato solo per risolvere i problemi causati da errori.

Dopo avere chiamato questo metodo, potete riutilizzare un'istanza PrintJob. Se possibile, le impostazioni di stampa del lavoro vengono mantenute per un uso successivo.

1. Dichiarate due variabili del tipo Sprite denominate sheet1 e sheet2.
2. Chiamate init(), che assegna una nuova istanza Sprite sia a sheet1 e sheet2 e quindi chiama createSheet() utilizzando argomenti diversi.
3. createSheet() consente di eseguire le seguenti operazioni:
   1. L'oggetto Sprite passato viene utilizzato per disegnare un rettangolo con uno sfondo grigio chiaro, un bordo nero di un pixel e una larghezza di 100 pixel e un'altezza di 200 pixel con x = 0, y = 0.
   2. Viene creato un nuovo oggetto TextField denominato txt con le stesse dimensioni di Sprite, la proprietà wordWrap impostata su true e la proprietà di testo impostata sul parametro String passato come argomento a createSheet().
   3. Se l'argomento Object passato non è null, creare una nuova istanza Sprite denominata img che viene utilizzata per disegnare un rettangolo con le proprietà di coordinate e dimensioni dell'argomento Object passato. Il rettangolo bianco viene aggiunto all'elenco di visualizzazione dell'oggetto Sprite utilizzando addChild().
   4. L'oggetto TextField txt viene aggiunto all'elenco di visualizzazione dell'oggetto Sprite utilizzando addChild().
4. Nella funzione di costruzione viene chiamato il metodo di stampa attivato (non impostato come commento). Poiché i metodi sono molto simili, printOnePerPage() è descritto di seguito.
5. printOnePerPage() consente di eseguire le seguenti operazioni:
   1. Dichiarate un nuovo oggetto PrintJob denominato pj e pagesToPrint come uint.
   2. Aprite la finestra di dialogo relativa alla stampa nativa del sistema operativo e attendete che l'utente faccia clic su OK.
   3. Verificate l'orientamento e, se è selezionato Landscape (orizzontale), generate un errore e uscite.
   4. Impostate l'altezza e la larghezza della pagina per sheet1 e sheet2.
   5. Inviate sheet1 e sheet2 allo spooler di stampa utilizzando addPage().
   6. Se il numero di pagine da stampare è > 0, stampate tutte le pagine elaborate dallo spooler.
6. Viene chiamato il metodo draw(), che ridimensiona le due proprietà Sprite per adattarle allo stage e riposiziona sheet2 in modo che si trovi immediatamente a destra di sheet1.

Nota: la funzione di costruzione è impostata in modo che sia possibile selezionare uno dei tre metodi di stampa (un foglio per pagina, due fogli per pagina o stampa nella metà superiore della pagina), in base alle preferenze. Questo esempio non funzionerà correttamente, a meno che non vengano disattivati due metodi di stampa specifici utilizzando commenti nel codice. L'esempio è impostato in modo che venga chiamato printOnePerPage().

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}