PrintJobOptions  - AS3

Specifica la risoluzione da utilizzare per le immagini bitmap, espressa in pixel per pollice. Il valore predefinito è Number.NaN e indica che viene utilizzata la risoluzione nativa della stampante.

L'impostazione della risoluzione vale sia per la stampa bitmap che vettoriale. Per la stampa bitmap, la risoluzione controlla la modalità di rasterizzazione dell'intera pagina. Per la stampa vettoriale, la risoluzione controlla la modalità di rasterizzazione di contenuto specifico, ad esempio le bitmap e le sfumature.

Specifica se il contenuto del lavoro di stampa viene stampato come immagine bitmap o vettoriale. Il valore predefinito è false, che corrisponde alla stampa vettoriale.

Se il contenuto da stampare include un'immagine bitmap, impostate printAsBitmap su true per mantenere gli effetti di colore e di trasparenza alfa. Se nel contenuto non sono presenti immagini bitmap, stampatelo in formato vettoriale con una qualità migliore (impostazione predefinita).

Ad esempio, per stampare il contenuto come immagine bitmap, utilizzate la sintassi seguente:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Nota: Adobe AIR non supporta la stampa vettoriale in Mac OS.

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Specifica che il runtime Flash sceglie il metodo di stampa più appropriato o che l'autore desidera selezionare esplicitamente la stampa vettoriale o bitmap.

Impostate la proprietà su uno dei seguenti valori definiti nella classe PrintMethod:

• PrintMethod.AUTO: specifica che la stampa vettoriale o bitmap viene scelta automaticamente, in base al contenuto da stampare. La stampa vettoriale viene utilizzata quando il contenuto può essere riprodotto fedelmente con tale metodo. In presenza di effetti di trasparenza o di altro tipo, verrà invece utilizzata la stampa bitmap.
• PrintMethod.VECTOR: specifica la stampa vettoriale. Questa impostazione equivale a impostare printAsBitmap su false.
• PrintMethod.BITMAP: specifica la stampa bitmap. Equivale a impostare printAsBitmap su true.

Se printMethod è impostato su uno dei valori supportati, printAsBitmap verrà ignorato.

Il valore predefinito è null; viene utilizzata la proprietà printAsBitmap.

Elementi API correlati

Crea un nuovo oggetto PrintJobOptions, Passate questo oggetto al parametro options del metodo PrintJob.addPage().

Elementi API correlati