PrintJobOptions

套件	flash.printing
類別	public class PrintJobOptions
繼承	PrintJobOptions Object

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9

PrintJobOptions 類別包含要與 PrintJob.addPage() 方法的 options 參數搭配使用的屬性。如需關於 addPage() 的詳細資訊，請參閱 PrintJob 類別。

相關 API 元素

PrintJob
PrintJob.addPage()

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		pixelsPerInch : Number = NaN 指定使用於點陣圖的解析度，以每英寸像素為單位。	PrintJobOptions
		printAsBitmap : Boolean = false 會指定列印工作中的內容會列印為點陣圖或向量。	PrintJobOptions
		printMethod : String 指定由 Flash 執行階段選擇最適當的列印方法，或是由作者明確選取向量或點陣列印方法。	PrintJobOptions

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		PrintJobOptions(printAsBitmap:Boolean = false) 會建立新的 PrintJobOptions 物件。	PrintJobOptions
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		valueOf():Object 會傳回指定之物件的基本值。	Object

屬性詳細資訊

pixelsPerInch

屬性

public var pixelsPerInch:Number = NaN

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

指定使用於點陣圖的解析度，以每英寸像素為單位。預設值為 Number.NaN，表示使用原生印表機解析度。

解析度設定同時適用於點陣圖及向量列印。針對點陣圖列印，解析度控制整個頁面的點陣化。針對向量列印，解析度控制特定內容 (例如點陣圖及漸層) 的點陣化。

printAsBitmap

屬性

public var printAsBitmap:Boolean = false

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9

會指定列印工作中的內容會列印為點陣圖或向量。預設值為 false，代表向量列印。

如果您要列印的內容含有點陣圖影像，請將 printAsBitmap 設定為 true，以包含所有 Alpha 透明度及顏色效果。如果內容不包含點陣圖影像，就以高品質向量格式 (預設選項) 列印內容。

例如，若要將您的內容列印為點陣圖，請使用下列語法：

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);

注意：在 Mac OS 中，Adobe AIR 不支援向量列印功能。

相關 API 元素

PrintJobOptions.printMethod

範例 ( 如何使用本範例 )

下列範例會先載入圖片，將它放在長方形框中，然後以點陣圖形式列印該圖片。

建構函式會使用 Loader 和 URLRequest 物件載入圖片 (image.jpg)。它也會檢查載入期間是否發生任何錯誤。這裡假設該檔案與 SWF 檔在相同目錄中。編譯 SWF 檔時，必須將「本機播放安全性」設定為「只存取本機檔案」。
載入圖片之後 (事件已完成)，會呼叫 completeHandler() 方法。
completeHandler() 方法會建立 BitmapData 物件，並將圖片 (點陣圖) 載入其中。在 Sprite 物件 (frame) 中繪製一個矩形，並使用 beginBitmapFill() 方法以該圖片 (a BitmapData 物件) 填滿此矩形。此外，也會使用 Matrix 物件縮放影像，以符合矩形的大小 (注意，這樣會導致影像扭曲。這個範例只是用它來確定影像符合大小)。填滿影像後，會呼叫 printPage() 方法。
printPage() 方法會建立新的列印工作實體，並開始列印程序，此程序會為使用者叫用列印對話方塊，並填入列印工作的屬性。 addPage() 方法包含列印工作的相關詳細資料。這裡將加了框的圖片 (Sprite 物件) 設定為以點陣圖形式列印，而不是以向量形式列印。 options 是 PrintJobOptions 類別的實體，而且其屬性 printAsBitmap 設定為 true，以便能夠以點陣圖形式列印 (預設值是 false)。

注意：這個範例只定義了有限的錯誤處理功能。

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

printMethod

屬性

printMethod:String

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

指定由 Flash 執行階段選擇最適當的列印方法，或是由作者明確選取向量或點陣列印方法。

將這個屬性設定為 PrintMethod 類別中所定義的以下其中一個值：

PrintMethod.AUTO：指定根據要列印的內容，自動選擇向量或點陣圖列印。當內容可以使用這個向量列印真實地重新產生時，就會使用這個方法。如果出現透明度或某些其他效果，就會用點陣列印取代。
PrintMethod.VECTOR: 指定向量列印。這個設定跟把 printAsBitmap 設定為 false 一樣。
PrintMethod.BITMAP: 指定點陣圖列印。這個設定跟把 printAsBitmap 設定為 true 一樣。

如果 printMethod 設定為這些支援的值其中之一，則會忽略 printAsBitmap。

預設值為 null; 使用printAsBitmap 屬性。

實作
public function get printMethod():String
public function set printMethod(value:String):void

擲回值

ArgumentError — printMethod 指定的不是 PrintMethod 類別定義的其中一個值。

建構函式詳細資料

()

建構函式

public function PrintJobOptions(printAsBitmap:Boolean = false)

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9

會建立新的 PrintJobOptions 物件。將此物件傳遞至 PrintJob.addPage() 方法的 options 參數。

參數

printAsBitmap:Boolean (default = false) — 如果為 true，這個物件便會列印為點陣圖。如果為 false，這個物件便會列印為向量。

如果您要列印的內容含有點陣圖影像，請將 printAsBitmap 屬性設定為 true 以包含所有 Alpha 透明度及顏色效果。如果您要列印的內容不包含點陣圖影像，省略此參數即可以高品質向量格式 (預設選項) 列印內容。

注意：在 Mac OS 中，Adobe AIR 不支援向量列印功能。

相關 API 元素

PrintJob.addPage()

法律聲明 | 線上隱私權政策

PrintJobOptions - AS3

套件x

語言元素

附錄

套件 flash.printing

pixelsPerInch

printAsBitmap

printMethod

PrintJobOptions