GradientGlowFilter  - AS3

在 colors 陣列中，其對應顏色之 Alpha 透明度值的陣列。 陣列中每一個元素的有效值為 0 到 1。 例如，.25 則會將 Alpha 透明度值設定為 25%。

alphas 屬性無法藉由直接修改其值來變更。 相反地，您必須先取得 alphas 的參照，再對參照進行變更，然後將 alphas 設為該參照。

colors、alphas 和 ratios 屬性都彼此相關。 colors 陣列的第一個元素會對應到 alphas 陣列和 ratios 陣列的第一個元素，以下則依此類推。

相關 API 元素

角度，以度數為單位。 有效值為 0 到 360。 預設值為 45。

angle 值代表假設性光源照射物件的角度，可以決定相對於物件的特效呈現位置。 如果 distance 設為 0，則物件不會有偏移效果，因此 angle 屬性不會作用。

水平模糊化量。 有效值為 0 到 255。 值為 1 或更小的模糊化表示依照原始影像複製。 預設值為 4。 2 的冪次方數值 (如 2、4、8、16 和 32) 是經過最佳化的，以便在顯示時會比其他值更為快速。

垂直模糊化量。 有效值為 0 到 255。 值為 1 或更小的模糊化表示依照原始影像複製。 預設值為 4。 2 的冪次方數值 (如 2、4、8、16 和 32) 是經過最佳化的，以便在顯示時會比其他值更為快速。

用來定義漸層的顏色陣列。 例如，紅色是 0xFF0000、藍色是 0x0000FF，依此類推。

colors 屬性無法藉由直接修改其值來變更。 相反地，您必須先取得 colors 的參照，再對參照進行變更，然後將 colors 設為該參照。

colors、alphas 和 ratios 屬性都彼此相關。 colors 陣列的第一個元素會對應到 alphas 陣列和 ratios 陣列的第一個元素，以下則依此類推。

相關 API 元素

光暈的偏移距離。 預設值為 4。

指定物件是否具有去底色特效。 去底色特效可以讓物件的填色透明，並顯露出文件的背景顏色。 true 值會指定去底色特效，預設值為 false (無去底色特效)。

套用濾鏡的次數。 預設值為 BitmapFilterQuality.LOW (相當於套用一次濾鏡)。 BitmapFilterQuality.MEDIUM 值會套用兩次濾鏡，而 BitmapFilterQuality.HIGH 值會套用三次濾鏡。 設定值較低的濾鏡，其顯示速度較快。

對大部份應用程式而言，將 quality 值設為低、中或高就足夠了。 雖然您可以使用其他數值 (最高可至 15) 來達成不同的效果，但越高的值就代表越緩慢的顯示速度。 只要增加 blurX 和 blurY 屬性的值，通常就可以得到類似的效果和較快的顯示速度，而不需要增加 quality 的值。

相關 API 元素

在 colors 陣列中，其對應顏色的顏色分佈比例陣列。 有效值為 0 到 255。

ratios 屬性無法藉由直接修改其值來變更。 相反地，您必須先取得 ratios 的參照，再對參照進行變更，然後將 ratios 設為該參照。

colors、alphas 和 ratios 屬性都彼此相關。 colors 陣列的第一個元素會對應到 alphas 陣列和 ratios 陣列的第一個元素，以下則依此類推。

請將漸層光暈濾鏡想成是以各種顏色條紋相互摻合而成的漸層，從物件中心 (若 distance 值設為 0) 放射出來的光暈。 colors 陣列中的第一個顏色是光暈最外面的顏色。 最後一個顏色則是光暈最裡面的顏色。

ratios 陣列中的每一個值設定了顏色在漸層半徑上的位置，其中 0 代表漸層最外面的點，而 255 則代表漸層最裡面的點。 比例值的範圍是從第 0 到 255 個像素，數值必須遞增；例如 [0, 64, 128, 200, 255]。 其值從 0 到 128 的顏色會在光暈的外邊緣上出現。 其值從 129 到 255 的顏色則會在光暈的內部區域出現。 依顏色的比例值和濾鏡的 type 值而定，套用濾鏡的物件可能會使濾鏡顏色變得黯淡。

在下列程式碼和影像中，會將濾鏡套用到黑色圓形影片片段，並將其類型設定為 "full"。 為了方便說明，colors 陣列中第一個顏色 (粉紅色) 的 alpha 值為 1，這樣就可以在白色文件背景上顯示，而形成對比 (在實際狀況中，您可能並不希望以這種方式顯示第一個顏色)。 陣列中最後一個顏色 (黃色) 會讓套用這個濾鏡的黑色圓形變得黯淡：

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

若要在 type 值設為 "outer" 或 "full" 時，達到與文件背景渾然交融的效果，請將陣列中的第一個顏色設定成和文件背景相同的顏色，或是將第一個顏色的 Alpha 值設為 0。採用上述其中任一種技術，都可以讓濾鏡與背景融合。

如果您在程式碼兩處稍做變更，即使 ratios 和 colors 陣列沒變，光暈的效果也會截然不同。 將陣列中第一個顏色的 Alpha 值設為 0，讓濾鏡與文件的白色背景融合，另外將 type 屬性設定成 "outer" 或 "inner"。 再觀察其結果，如下列影像所示。

請記住，漸層中的顏色塗佈會根據 blurX、blurY、strength 和 quality 屬性的值，以及 ratios 值產生變化。

相關 API 元素

壓印強度或範圍。 數值越高，便壓印越多顏色，光暈與背景之間的對比越強烈。 有效值為 0 到 255。 值為 0 時表示未套用濾鏡。 預設值為 1。

濾鏡特效的位置。 可能的值為 flash.filters.BitmapFilterType 常數：

• BitmapFilterType.OUTER — 物件外緣上的光暈
• BitmapFilterType.INNER — 物件內緣上的光暈 (預設值)。
• BitmapFilterType.FULL — 物件上方的光暈

以指定的參數初始化濾鏡。

傳回此濾鏡物件的副本。

1. 匯入所需的類別。
2. 宣告用來定義方形和濾鏡的全域變數。
3. 建立建構函數，以進行下列動作：
   • 呼叫 draw() 方法，使用 Graphics 類別的方法 (透過 Sprite 的 graphics 屬性存取) 來繪製方形。
   • 建立名為 filter 的 BitmapFilter 物件，並為其指定 getBitmapFilter() 呼叫 (建立濾鏡) 的傳回值。
   • 建立名為 myFilters 的新陣列，並將 filter 加入此陣列。
   • 將 myFilters 指定給 GradientGlowFilterExample 物件的 filters 屬性。 這樣就會套用 myFilters 中找到的所有濾鏡，而在本範例中只有 filter。

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}