DataGridColumn

套件	fl.controls.dataGridClasses
類別	public class DataGridColumn
繼承	DataGridColumn Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

DataGridColumn 類別會說明 DataGrid 組件內的欄。每一欄都有一個可以在螢幕上顯示的 DataGridColumn 物件，即使某些欄目前已隱藏或者不在螢幕範圍內也是一樣。屬於 DataGrid 組件的資料提供者項目可以包含不顯示的屬性，這種屬性不需要 DataGridColumn。

您可以指定會顯示 DataGridColumn 之資料的組件類型。您可以指定的特性包括欄標題中顯示的文字，以及是否可以對此欄進行編輯、排序或調整大小。

相關 API 元素

公用屬性

	屬性		定義自
		cellRenderer : Object 用於顯示此欄中之項目的類別。	DataGridColumn
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		dataField : String 會識別與欄相關聯之資料提供者項目內的欄位或屬性名稱。	DataGridColumn
		editable : Boolean = true 會指出是否可以編輯欄中的項目。	DataGridColumn
		editorDataField : String = "text" 會識別項目編輯器的屬性名稱，此項目編輯器包含清單項目的新資料。	DataGridColumn
		headerRenderer : Object 用於顯示此欄之標題的類別。	DataGridColumn
		headerText : String 要顯示在欄標題中的欄名稱。	DataGridColumn
		imeMode : String 輸入法編輯器 (IME) 的模式。	DataGridColumn
		itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor 會指出當該欄為可編輯時，用於該欄之項目編輯器的實體類別。	DataGridColumn
		labelFunction : Function 函數，會決定此欄中顯示的文字。	DataGridColumn
		minWidth : Number 欄的最小寬度，以像素為單位。	DataGridColumn
		resizable : Boolean = true 會指出是否允許使用者變更欄的寬度。	DataGridColumn
		sortable : Boolean = true 會指出使用者是否按一下目前的欄標題，即可排序資料提供者。	DataGridColumn
		sortCompareFunction : Function 排序欄內的資料時會呼叫的回呼函數。	DataGridColumn
		sortDescending : Boolean = false 會指出要依照遞增或遞減順序排序 DataGridColumn。	DataGridColumn
		sortOptions : uint = 0 一個或多個已定義的常數，可由名稱或數字加以識別，並使用位元 OR (\|) 運算子來分隔。	DataGridColumn
		visible : Boolean 會指出某欄是否為可見的。	DataGridColumn
		width : Number 欄的寬度，以像素為單位。	DataGridColumn

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		DataGridColumn(columnName:String = null) 建立新的 DataGridColumn 實體。	DataGridColumn
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		itemToLabel(data:Object):String 傳回項目輸出器為指定資料物件顯示的字串。	DataGridColumn
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回 DataGridColumn 物件的字串形式。	DataGridColumn
		valueOf():Object 會傳回指定之物件的基本值。	Object

屬性詳細資訊

cellRenderer

屬性

cellRenderer:Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

用於顯示此欄中之項目的類別。此屬性的類型可以是 Class、Sprite 或 String。如果屬性類型為 String，則此字串值必須是完整類別名稱。

預設值為 null。

實作
public function get cellRenderer():Object
public function set cellRenderer(value:Object):void

相關 API 元素

DataGridColumn.headerRenderer

範例 ( 如何使用本範例 )

下列範例會為資料格欄指定自訂的儲存格輸出器：


import fl.controls.dataGridClasses.DataGridColumn;

var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.cellRenderer = "MyCustomCellRendererClass";
dg.addColumn(dgc);

dataField

屬性

public var dataField:String

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會識別與欄相關聯之資料提供者項目內的欄位或屬性名稱。

editable

屬性

public var editable:Boolean = true

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出是否可以編輯欄中的項目。值為 true 表示可以編輯欄項目；值為 false 則表示無法編輯這些項目。

如果將此屬性設定為 true，而且 DataGrid 的 editable 屬性也是 true，則欄中的項目是可編輯的，而且按一下某個項目，或使用 Tab 鍵和方向鍵瀏覽至該項目，即可個別進行編輯。

預設值為 true。

editorDataField

屬性

public var editorDataField:String = "text"

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會識別項目編輯器的屬性名稱，此項目編輯器包含清單項目的新資料。

例如，預設的 itemEditor 是 TextInput，因此 editorDataField 屬性的預設值為 "text"。這個值會指定 TextInput 組件的 text 屬性。

預設值為 "text"。

headerRenderer

屬性

headerRenderer:Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

用於顯示此欄之標題的類別。

此屬性的類型可以是 Class、Sprite 或 String。如果屬性類型為 String，則此字串值必須是完整類別名稱。

預設值為 null。

實作
public function get headerRenderer():Object
public function set headerRenderer(value:Object):void

headerText

屬性

headerText:String

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

要顯示在欄標題中的欄名稱。根據預設，DataGrid 組件會使用 dataField 屬性的值做為欄名稱。

實作
public function get headerText():String
public function set headerText(value:String):void

範例 ( 如何使用本範例 )

下列範例會建立新資料格，並指定每個一欄的標題文字：


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", sales:13453});
dp.addItem({name:"Person B", sales:23432});
dp.addItem({name:"Person C", sales:9454});

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Employee:";

var salesCol:DataGridColumn = new DataGridColumn("sales");
salesCol.headerText = "Sales:";
salesCol.labelFunction = currencyFormatter;
salesCol.sortOptions = Array.NUMERIC;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(salesCol);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(320, 240);
addChild(myDataGrid);

function currencyFormatter(item:Object):String {
    return "$" + item.sales.toFixed(0);
}

imeMode

屬性

imeMode:String

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

輸入法編輯器 (IME) 的模式。 IME 可讓使用者輸入中文、日文和韓文文字。 flash.system.IMEConversionMode 類別會定義用來做為此屬性之有效值的常數。

如果此屬性是 null，則 IME 的模式會設定為 DataGrid 組件的 imeMode 屬性值。

預設值為 null。

實作
public function get imeMode():String
public function set imeMode(value:String):void

相關 API 元素

flash.system.IMEConversionMode

itemEditor

屬性

public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出當該欄為可編輯時，用於該欄之項目編輯器的實體類別。此屬性的類型可以是 Class、Sprite 或 String。如果屬性類型為 String，則此字串值必須是完整類別名稱。

預設值為 "fl.controls.dataGridClasses.DataGridCellEditor"。

範例 ( 如何使用本範例 )

下列範例會為資料格欄指定自訂的項目編輯器：


import fl.controls.dataGridClasses.DataGridColumn;

var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.itemEditor = "MyCustomItemEditorClass";
dg.addColumn(dgc);

labelFunction

屬性

labelFunction:Function

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

函數，會決定此欄中顯示的文字。根據預設，此欄會在符合欄名稱的資料欄位中顯示文字。不過，您也可以使用一欄來顯示多個資料欄位的文字，或顯示格式不正確的內容。這可藉由使用 labelFunction 屬性指定回呼函數來完成。

如果 labelFunction 和 labelField 屬性都已定義，則會優先使用 labelFunction。

預設值為 null。

實作
public function get labelFunction():Function
public function set labelFunction(value:Function):void

範例 ( 如何使用本範例 )

下列範例會建立資料格，並為其中一個資料格欄定義自訂標籤函數：


import fl.controls.DataGrid;
import fl.controls.ScrollPolicy;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var i:uint;
var totalRows:uint = 16;
var dp:DataProvider = new DataProvider();
for (i = 0; i < totalRows; i++) {
    dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()});
}

var c1:DataGridColumn = new DataGridColumn("col1");
c1.sortOptions = Array.NUMERIC;
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortOptions = Array.NUMERIC;
var c3:DataGridColumn = new DataGridColumn("col3");
c3.sortOptions = Array.NUMERIC;
c3.labelFunction = currencyFormatter;

var dg:DataGrid = new DataGrid();
dg.setSize(200, 300);
dg.addColumn(c1);
dg.addColumn(c2);
dg.addColumn(c3);
dg.dataProvider = dp;
addChild(dg);

function getRandomNumber():Number {
    return Math.random() * 100;
}

function currencyFormatter(data:Object):String {
    var value:Number = Number(data.col3);
    return "$" + value.toFixed(2);
}

下列範例會建立新的 DataGridColumn 物件，並且指定 labelFunction 和 sortCompareFunction：

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var data:XML = <data>
        <item name="Employee A" isManager="1" />
        <item name="Employee B" isManager="0" />
        <item name="Employee C" isManager="1" />
    </data>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;

var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);

function nameLabelFunction(item:Object):String {
    var managerString:String = "";
    if (item.isManager == "1") {
        managerString = " (Manager)";
    }
    return item.name + managerString;
}

function isManager(itemA:Object, itemB:Object):int {
    if (itemA.isManager > itemB.isManager) {
        return -1;
    } else if (itemA.isManager < itemB.isManager) {
        return 1;
    } else {
        return 0;
    }
}

minWidth

屬性

minWidth:Number

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

欄的最小寬度，以像素為單位。

預設值為 20。

實作
public function get minWidth():Number
public function set minWidth(value:Number):void

相關 API 元素

DataGridColumn.width

範例 ( 如何使用本範例 )

下列範例會在欄的寬度變更時，顯示資料格中每一欄的寬度：


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var data:XML = <data>
        <row col1="item 1.A" col2="item 1.B" col3="item 1.C" />
        <row col1="item 2.A" col2="item 2.B" col3="item 2.C" />
        <row col1="item 3.A" col2="item 3.B" col3="item 3.C" />
    </data>;
    
var dp:DataProvider = new DataProvider(data);

var c1:DataGridColumn = new DataGridColumn("col1");
c1.minWidth = 100;
var c2:DataGridColumn = new DataGridColumn("col2");
var c3:DataGridColumn = new DataGridColumn("col3");

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.addColumn(c3);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(300, 200);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var column:DataGridColumn;
    for each (column in myDataGrid.columns) {
        trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth);
    }
    trace("---");
}

resizable

屬性

public var resizable:Boolean = true

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出是否允許使用者變更欄的寬度。值為 true 表示使用者可以變更欄寬度；值為 false 則表示使用者不可以變更欄寬度。

預設值為 true。

sortable

屬性

public var sortable:Boolean = true

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出使用者是否按一下目前的欄標題，即可排序資料提供者。值為 true 表示按一下欄標題即可排序該欄；值為 false 則表示無法藉由按下欄標題排序該欄。

預設值為 true。

範例 ( 如何使用本範例 )

下列範例會建立新的資料格，其中包含無法排序的欄：


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var data:XML = <dataProvider>
        <data col1="Person A" col2="11.383" />
        <data col1="Person B" col2="3.399" />
        <data col1="Person C" col2="25.624" />
    </dataProvider>

var dp:DataProvider = new DataProvider(data);

var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortable = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(160, 120);
addChild(myDataGrid);

下列範例會將資料格欄的 sortable 屬性設定為 false，建立包含一個無法排序欄的 DataGrid：


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var xmlDP:XML = <items>
        <item name="Person 1" bio="Person 1 bio" />    
        <item name="Person 2" bio="Person 2 bio" />
    </items>;

var dp:DataProvider = new DataProvider(xmlDP);

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";

var bioCol:DataGridColumn = new DataGridColumn("bio");
bioCol.headerText = "Bio:";
bioCol.sortable = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(bioCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 200;
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var myDG:DataGrid = event.currentTarget as DataGrid;
    trace("dataField:" + event.dataField);
    trace("columnIndex:" + event.columnIndex);
    trace("{DataGrid}.sortDescending:" + myDG.sortDescending);
    trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending);
    trace("");
}

sortCompareFunction

屬性

sortCompareFunction:Function

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

排序欄內的資料時會呼叫的回呼函數。如果未指定此屬性，則會視 sortOptions 屬性而定，依據字串或數字排序資料。如果已指定，則可以使用 sortCompareFunction 屬性，為目前的資料格欄建立自訂的排序方法。

預設值為 null。

實作
public function get sortCompareFunction():Function
public function set sortCompareFunction(value:Function):void

相關 API 元素

sortOptions

範例 ( 如何使用本範例 )

下列範例會建立新的 DataGridColumn 物件，並且指定 labelFunction 和 sortCompareFunction：

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var data:XML = <data>
        <item name="Employee A" isManager="1" />
        <item name="Employee B" isManager="0" />
        <item name="Employee C" isManager="1" />
    </data>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;

var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);

function nameLabelFunction(item:Object):String {
    var managerString:String = "";
    if (item.isManager == "1") {
        managerString = " (Manager)";
    }
    return item.name + managerString;
}

function isManager(itemA:Object, itemB:Object):int {
    if (itemA.isManager > itemB.isManager) {
        return -1;
    } else if (itemA.isManager < itemB.isManager) {
        return 1;
    } else {
        return 0;
    }
}

sortDescending

屬性

public var sortDescending:Boolean = false

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出要依照遞增或遞減順序排序 DataGridColumn。值為 true 表示依照遞減順序排序 DataGridColumn；值為 false 則表示依照遞增順序排序 DataGridColumn。

預設值為 false。

sortOptions

屬性

public var sortOptions:uint = 0

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

一個或多個已定義的常數，可由名稱或數字加以識別，並使用位元 OR (|) 運算子來分隔。這些常數會用於指定排序作業。

預設值為 0。

相關 API 元素

Array.sort()

範例 ( 如何使用本範例 )

下列範例會使用 sortOptions 屬性，以指定要依照數字順序排序資料格欄。


import fl.data.DataProvider;
import fl.controls.dataGridClasses.DataGridColumn;

var data:XML = <players>
        <player name="Player 1" score="1234" />
        <player name="Player 2" score="198" />
        <player name="Player 3" score="987" />
    </players>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
var scoreDGC:DataGridColumn = new DataGridColumn("score");
scoreDGC.sortOptions = Array.NUMERIC;

dg.addColumn(nameDGC);
dg.addColumn(scoreDGC);
dg.dataProvider = dp;

visible

屬性

visible:Boolean

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會指出某欄是否為可見的。值為 true 表示此欄是可見的；值為 false 則表示此欄是隱藏的。

預設值為 true。

實作
public function get visible():Boolean
public function set visible(value:Boolean):void

範例 ( 如何使用本範例 )

下列範例會建立包含兩欄的 DataGrid 組件實體。您可以透過按一下「舞台」上對應的 Button 實體，切換每一欄的 visible 屬性。


import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", average:0.297});
dp.addItem({name:"Person B", average:0.288});
dp.addItem({name:"Person C", average:0.310});

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";

var averageCol:DataGridColumn = new DataGridColumn("average");
averageCol.headerText = "Average:";
averageCol.labelFunction = numberFormatter;
averageCol.sortOptions = Array.NUMERIC;
averageCol.visible = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(averageCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 320;
myDataGrid.move(10, 10);
addChild(myDataGrid);

var nameButton:Button = new Button();
nameButton.label = "Toggle name";
nameButton.toggle = true;
nameButton.selected = nameCol.visible;
nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10);
nameButton.addEventListener(Event.CHANGE, changeHandler);
addChild(nameButton);

var averageButton:Button = new Button();
averageButton.label = "Toggle average";
averageButton.toggle = true;
averageButton.selected = averageCol.visible;
averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y);
averageButton.addEventListener(Event.CHANGE, changeHandler);
addChild(averageButton);

function numberFormatter(item:Object):String {
    return Number(item.average).toFixed(3);
}

function changeHandler(event:Event):void {
    var colIndex:int = -2;
    var col:DataGridColumn;
    switch (event.currentTarget) {
        case nameButton:
            colIndex = myDataGrid.getColumnIndex("name");
            break;
        case averageButton:
            colIndex = myDataGrid.getColumnIndex("average");
            break;
        default:
            return;
    }
    
    if (colIndex > -1) {
        col = myDataGrid.getColumnAt(colIndex);
        col.visible = !col.visible;
        myDataGrid.removeColumnAt(colIndex);
        myDataGrid.addColumnAt(col, colIndex);
    }
    myDataGrid.spaceColumnsEqually();
}

width

屬性

width:Number

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

欄的寬度，以像素為單位。

預設值為 100。

實作
public function get width():Number
public function set width(value:Number):void

相關 API 元素

DataGridColumn.minWidth

建構函式詳細資料

()

建構函式

public function DataGridColumn(columnName:String = null)

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

建立新的 DataGridColumn 實體。

參數

columnName:String (default = null) — 要顯示在欄標題中的欄名稱。如果未指定名稱，則會使用 dataField 值。

相關 API 元素

DataGridColumn.headerText

方法詳細資訊

itemToLabel

()

方法

public function itemToLabel(data:Object):String

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

傳回項目輸出器為指定資料物件顯示的字串。如果 DataGridColumn 或其 DataGrid 組件具有非 null 的 labelFunction 屬性，則會將函數套用到該資料物件。否則，此方法便會擷取 dataField 屬性指定的欄位內容，或者取得該資料物件的字串值。如果此方法無法將參數轉換為字串，則會傳回單一空白字元。

參數

data:Object — 要顯示的物件。

傳回值

String — 以指定之 data 物件為基礎的可顯示字串。

toString

()

方法

public function toString():String

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會傳回 DataGridColumn 物件的字串形式。

傳回值

String — "[object DataGridColumn]"

範例如何使用本範例

DataGridColumnExample.as

此範例將示範如何以程式的設計方式操作 DataGrid 的欄。

將 DataGrid 和 Button 組件加入元件庫。
將這個程式碼儲存成 DataGridColumnExample.as，並與您的 FLA 存放在相同的目錄中。
將 FLA 中的 DocumentClass 設定為 DataGridColumnExample。

package
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import fl.data.DataProvider;
    import fl.events.DataChangeEvent;
    import fl.controls.DataGrid;
    import fl.controls.Button;
    import fl.controls.dataGridClasses.DataGridColumn;
    
    public class DataGridColumnExample extends Sprite
    {
        private var dg:DataGrid;
        private var dp:DataProvider;
        private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ];
        
        
        public function DataGridColumnExample() {
            dp = new DataProvider();
            dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged);
        
            dg = new DataGrid();
            addChild(dg);
            dg.move(10,45);
            dg.setSize(450,300);
            dg.addColumn(new DataGridColumn("name"));
            dg.addColumn(new DataGridColumn("phone"));
            dg.addColumn(new DataGridColumn("email"));

            var firstColumn = dg.columns[0];
            firstColumn.resizable = false;
            var secondColumn = dg.columns[1];
            secondColumn.sortable = false;
            var thirdColumn = dg.columns[2];
            thirdColumn.sortable = false;
            
            var addContactBtn:Button = new Button();
            addContactBtn.label = "Add Contact";
            addContactBtn.move(10,10);
            addContactBtn.addEventListener(MouseEvent.CLICK, addContact);
            addChild(addContactBtn);            
        }
        
        private function getRandomPhone():String {
            return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit();    
        }
        private function randomDigit():String {
            return String(Math.round(Math.random()*10)%10);    
        }
        private function getRandomName():String {
            return names[Math.round(Math.random()*names.length)%names.length];    
        }
        private function addContact(e:MouseEvent):void {
            var randomName:String = getRandomName()
            dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } );
        }
        private function dataChanged(e:DataChangeEvent):void {
            var changedItems:Array = e.items;
            dg.addItem(changedItems[0]);
        }
    }
}

法律聲明 | 線上隱私權政策

DataGridColumn - AS3 Flash

類別 x

cellRenderer

dataField

editable

editorDataField

headerRenderer

headerText

imeMode

itemEditor

labelFunction

minWidth

resizable

sortable

sortCompareFunction

sortDescending

sortOptions

visible

width

DataGridColumn

itemToLabel

toString