| 包 | flash.net |
| 类 | public final class URLLoaderDataFormat |
| 继承 | URLLoaderDataFormat  Object |
| 语言版本: | ActionScript 3.0 |
| 运行时版本: | AIR 1.0, Flash Player 9, Flash Lite 4 |
隐藏继承的公共属性
显示继承的公共属性
公共常量
| 常量 | 由以下参数定义 | ||
|---|---|---|---|
| BINARY : String = "binary" [静态]
指定以原始二进制数据形式接收下载的数据。 | URLLoaderDataFormat | ||
| TEXT : String = "text" [静态]
指定以文本形式接收已下载的数据。 | URLLoaderDataFormat | ||
| VARIABLES : String = "variables" [静态]
指定以 URL 编码变量形式接收下载的数据。 | URLLoaderDataFormat | ||
常量详细信息
BINARY | 常量 |
public static const BINARY:String = "binary"| 语言版本: | ActionScript 3.0 |
| 运行时版本: | AIR 1.0, Flash Player 9, Flash Lite 4 |
指定以原始二进制数据形式接收下载的数据。
TEXT | 常量 |
public static const TEXT:String = "text"| 语言版本: | ActionScript 3.0 |
| 运行时版本: | AIR 1.0, Flash Player 9, Flash Lite 4 |
指定以文本形式接收已下载的数据。
VARIABLES | 常量 |
public static const VARIABLES:String = "variables"| 语言版本: | ActionScript 3.0 |
| 运行时版本: | AIR 1.0, Flash Player 9, Flash Lite 4 |
指定以 URL 编码变量形式接收下载的数据。
示例 如何使用本示例
URLLoaderDataFormatExample.as
下例使用 URLLoaderDataFormatExample 类显示在运行时加载的文件的数据格式和状态信息。这是使用以下步骤完成的：
- 类构造函数创建一个名为
loader的 URLLoader 和一个名为request的 URLRequest 实例，后者为要加载的文件的位置和名称。 loader对象被传递给configureListeners()方法，该方法可为每个受支持的 URLLoader 事件添加侦听器：completeHandler()：侦听complete事件，在成功加载 TextFile.txt 后调度该事件。openHandler()：侦听open事件，开始下载 TextFile.txt（至播放器）时调度该事件。progressHandler()：侦听progress事件，在下载操作过程中收到数据时调度该事件。securityErrorHandler()：侦听securityError事件，如果访问文本文件时使用了错误的本地播放安全设置，则调度该事件。httpStatusHandler()：侦听httpStatusHandler事件，在此示例不调度该事件，因为 TextFile.txt 是本地文件。ioErrorHandler()：侦听ioError事件，仅当文件出现严重问题（如文件丢失）时才发生该事件。
- 随后
request对象被传递给loader.load()方法，该方法会使用DisplayObject对象将文本文件加载到内存中。
注意：
- 您需要编译 SWF 文件，将“本地播放安全性”设置为“只访问本地文件”。
- 该示例要求名为 TextFile.txt 的文件与 SWF 文件放在同一目录中。如果希望该示例识别二进制或 URL 编码数据文件，则需要用适当的数据格式来提供该文件，并将 TextFile.txt 更改为新文件的名称和位置。
package {
import flash.display.Sprite;
import flash.events.*;
import flash.net.*;
public class URLLoaderDataFormatExample extends Sprite {
private var source:String = "TextFile.txt";
private var dataFormat:String = URLLoaderDataFormat.TEXT;
private var loader:URLLoader;
public function URLLoaderDataFormatExample () {
loader = new URLLoader();
loader.dataFormat = dataFormat;
configureListeners(loader);
var request:URLRequest = new URLRequest(source);
try {
loader.load(request);
} catch (error:Error) {
trace("Error loading requested document: " + source);
}
}
private function configureListeners(dispatcher:URLLoader):void {
dispatcher.addEventListener(Event.COMPLETE, completeHandler);
dispatcher.addEventListener(Event.OPEN, openHandler);
dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
}
private function completeHandler(event:Event):void {
var loader:URLLoader = URLLoader(event.target);
switch(loader.dataFormat) {
case URLLoaderDataFormat.TEXT :
trace("completeHandler (text): " + loader.data);
break;
case URLLoaderDataFormat.BINARY :
trace("completeHandler (binary): " + loader.data);
break;
case URLLoaderDataFormat.VARIABLES :
trace("completeHandler (variables): " + loader.data);
break;
}
}
private function httpStatusHandler(event:Event):void {
trace("httpStatusHandler: " + event);
}
private function ioErrorHandler(event:IOErrorEvent):void {
trace("ioErrorHandler: " + event);
}
private function openHandler(event:Event):void {
trace("openHandler: " + event);
}
private function progressHandler(event:ProgressEvent):void {
trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
}
private function securityErrorHandler(event:SecurityErrorEvent):void {
trace("securityErrorHandler: " + event);
}
}
}
Tue Jun 12 2018, 11:04 AM Z